369071_ko-KR

liliconcom

Re: Character Date 열에 x 일 수 추가(dd-Mon-YYYY)이것은 훌륭합니다. 정확히 제가 하려고 했던 것입니다. 그리고 아주 간단합니다! 도와 주셔서 감사합니다. 날짜 형식으로 남겨두겠습니다.Re: Character Date 열에 x 일 수 추가(dd-Mon-YYYY)

Target Date 값을 문자 열로 유지해야 하는 실질적인 이유가 없는 한 JMP Date 열로 변환하는 것이 좋습니다.

Names Default To Here( 1 );
dt = Current Data Table();

dt << new column( "Target Date", format( "ddmonyyyy") );

for each row(
 if( :"Time (Months)"n <= 3,
  :Target Date = 
   Informat( :Available Date, "ddmonyyyy" ) + In Days( 4 ),
  :Target Date = 
   Informat( :Available Date, "ddmonyyyy" ) + In Days( 7 )
 )
);

아래의 수정으로 위의 출력을 문자로 변환하는 것은 매우 쉽습니다.

Names Default To Here( 1 );
dt = Current Data Table();

dt << new column( "Target Date", character );

for each row(
 if( :"Time (Months)"n <= 3,
  :Target Date = format(
   Informat( :Available Date, "ddmonyyyy" ) + In Days( 4 ),
   "ddmonyyyy"
  ),
  :Target Date = format(
   Informat( :Available Date, "ddmonyyyy" ) + In Days( 7 ),
   "ddmonyyyy"
  )
 )
);

출력 형식이 입력 데이터 형식과 정확히 일치해야 하는 경우 다음을 수행합니다.

Names Default To Here( 1 );
dt = Current Data Table();

dt << new column( "Target Date", character );

monthList = {"JAN", "FEB", "MAR", "APR", "MAY", "JUN", "JUL", "AUG", "SEP",
"OCT", "NOV", "DEC"};
for each row(
 if( :"Time (Months)"n <= 3,
  temp = Informat( :Available Date, "ddmonyyyy" ) + In Days( 4 ),
  temp = Informat( :Available Date, "ddmonyyyy" ) + In Days( 7 )
 );
 :Target Date = Substr( "0", Length( Char( Day( temp ) ) ) ) ||
 Char( Day( temp ) ) || "-" || monthList[Month( temp )] || "-" ||
 Char( Year( temp ) );
);

For Each Row가 아닌 수식을 사용하려는 경우 위 출력에 대한 수식이 됩니다.

monthList = {"JAN", "FEB", "MAR", "APR", "MAY", "JUN", "JUL", "AUG", "SEP", "OCT", "NOV", "DEC"};
If( :"Time (Months)"n <= 3,
 temp = Informat( :Available Date, "ddmonyyyy" ) + In Days( 4 ),
 temp = Informat( :Available Date, "ddmonyyyy" ) + In Days( 7 )
);
Substr( "0", Length( Char( Day( temp ) ) ) ) || Char( Day( temp ) ) || "-" || monthList[Month( temp )] || "-" ||
Char( Year( temp ) );

Re: Character Date 열에 x 일 수 추가(dd-Mon-YYYY)

첨부된 표는 목표 날짜를 얻기 위해 사용 가능한 날짜 열에 4일을 더합니다.단계: 사용 가능한 날짜의 데이터 유형을 적절한 날짜 형식을 사용하여 숫자/연속형으로 변경합니다. 그런 다음 날짜 증분 기능을 사용하여 사용 가능한 날짜에 4일을 추가하고 마지막으로 사용 가능한 날짜 열에서 사용한 것과 일치하도록 결과 대상 날짜 열의 형식을 변경합니다.

 

한 가지 추가 참고 사항 - 귀하의 예에서는 일주일을 추가한 것으로 보입니다(4일이 아닌 7일).

문자 날짜 열에 x일 수 추가(dd-Mon-YYYY)

Access 데이터베이스에서 주기적으로 데이터를 가져오는 JSL 스크립트가 있습니다.

 

액세스 데이터베이스에는 dd-Mon-YYYY가 포함된 "Available Date" 날짜 열이 포함되어 있습니다(예: 2018년 4월 12일) 형식입니다. 내가 하려는 것은 JMP에서 각 행의 "사용 가능한 날짜"에 있는 날짜에 x일 수를 추가하는 새 열 "목표 날짜"를 만드는 것입니다.

 

예를 들어: 아래 이미지에서 목표 날짜는 사용 가능 날짜 + 4일과 같습니다. 사용 가능한 날짜를 기준으로 목표 날짜를 자동으로 계산하려고 합니다. 일 수는 "시간(월)" 열을 기준으로 합니다.

 

이것은 내가 지금까지 시도한 것인데 분명히 작동하지 않습니다. "사용 가능한 날짜" 열을 숫자 데이터 유형으로 변환한 다음 일 수를 추가하고 다시 문자로 변환해야 한다고 생각합니까?

dt << New Column("Target Date", "Character", "Nominal");

dt << For Each Row(
 IF (:"Time (Months)" <= 3, :"Target Date" = :"Available Date" + 4 ),
 IF (:"Time (Months)" > 3, :"Target Date" = :"Available Date" + 7 )
);

자동화 및 스크립팅데이터 접근