368066_es-ES

liliconcom

recodificación por lotes de muchas columnas

Hola,

 

He estado intentando recodificar muchas columnas que contienen una cadena específica en su nombre de columna usando la función recodificar. Creo que estoy bastante cerca, pero el guión se atasca con las evaluaciones de la columna. Entonces me estoy perdiendo algo crucial en alguna parte. Cualquier orientación sería muy apreciada.

 

Mejor,

 

Sébastien

 

Names default to here(1);
Clear log();

New Table( "Subject_Demographics",
 Add Rows( 48 ),
 New Column( "Unique Subject Identifier",
  Character,
  "Nominal",
  Set Selected,
  Set Values(
   {"8396882-P0101", "8396882-P0101", "8396882-P0102", "8396882-P0102",
   "8396882-P0103", "8396882-P0103", "8396882-P0104", "8396882-P0104",
   "8396882-P0201", "8396882-P0201", "8396882-P0202", "8396882-P0202",
   "8396882-P0203", "8396882-P0203", "8396882-P0204", "8396882-P0204",
   "8396882-P0301", "8396882-P0301", "8396882-P0302", "8396882-P0302",
   "8396882-P0303", "8396882-P0303", "8396882-P0304", "8396882-P0304",
   "8396882-P0401", "8396882-P0401", "8396882-P0402", "8396882-P0402",
   "8396882-P0403", "8396882-P0403", "8396882-P0404", "8396882-P0404",
   "8396882-P0501", "8396882-P0501", "8396882-P0502", "8396882-P0502",
   "8396882-P0503", "8396882-P0503", "8396882-P0504", "8396882-P0504",
   "8396882-P0601", "8396882-P0601", "8396882-P0602", "8396882-P0602",
   "8396882-P0603", "8396882-P0603", "8396882-P0604", "8396882-P0604"}
  )
 ),
 New Column( "Alertness - Recoded",
  Character,
  "Nominal",
  Set Selected,
  Set Values(
   {"", "", "", "", "", "", "", "", "", "", "Abnormal Finding",
   "Abnormal Finding", "", "", "", "", "", "", "", "", "", "", "", "", "",
   "", "Abnormal Finding", "Abnormal Finding", "Abnormal Finding",
   "Abnormal Finding", "Abnormal Finding", "Abnormal Finding", "", "", "",
   "", "Abnormal Finding", "Abnormal Finding", "", "", "", "", "", "", "",
   "", "", ""}
  )
 ),
 New Column( "Xyx Reflex - Recoded",
  Character,
  "Nominal",
  Set Selected,
  Set Values(
   {"Abnormal Finding", "Abnormal Finding", "Abnormal Finding",
   "Abnormal Finding", "Normal", "Normal", "", "", "", "", "Normal",
   "Normal", "Normal", "Normal", "Normal", "Normal", "Normal", "Normal",
   "Normal", "Normal", "Normal", "Normal", "Normal", "Normal", "Normal",
   "Normal", "Abnormal Finding", "Abnormal Finding", "Normal", "Normal",
   "Normal", "Normal", "", "", "", "", "Abnormal Finding",
   "Abnormal Finding", "Normal", "Normal", "Normal", "Normal", "Normal",
   "Normal", "Normal", "Normal", "Normal", "Normal"}
  )
 ),
 New Column( "Ataxia - Recoded",
  Character,
  "Nominal",
  Set Selected,
  Set Values(
   {"Abnormal Finding", "Abnormal Finding", "Abnormal Finding",
   "Abnormal Finding", "Abnormal Finding", "Abnormal Finding",
   "Abnormal Finding", "Abnormal Finding", "", "", "Abnormal Finding",
   "Abnormal Finding", "", "", "", "", "", "", "", "", "", "", "", "",
   "Abnormal Finding", "Abnormal Finding", "Abnormal Finding",
   "Abnormal Finding", "", "", "Abnormal Finding", "Abnormal Finding", "",
   "", "", "", "Abnormal Finding", "Abnormal Finding", "", "", "", "", "",
   "", "", "", "Abnormal Finding", "Abnormal Finding"}
  )
 )
);


subject_incidence = Data Table( "Subject_Demographics" );
a = "Recoded";
col = subject_incidence << get column names( string );
show(col);
nc = N Items( col );
For( i = 1, i <= nc, i++,
 If( Contains( col[i], a ),  
  subject_incidence << Begin Data Update;
  subject_incidence << Recode Column(
   column(subject_incidence, col[i]),
   {Map Value( _rcOrig, {"", "Not Reported"}, Unmatched( _rcNow ) )},
   Target Column( column(subject_incidence, col[i] ))
  );
  subject_incidence << End Data Update
 )
);

ScriptingRe: recodificación por lotes de muchas columnas

Creo que el código puede ser un poco más simple que @ih .

Su código con solo un cambio para usar una función Como Column() en lugar de solo una función Column() permite que el código se ejecute correctamente

subject_incidence = Data Table( "Subject_Demographics" );
a = "Recoded";
col = subject_incidence << get column names( string );
show(col);
nc = N Items( col );
For( i = 1, i <= nc, i++,
	If( Contains( col[i], a ), 	
		subject_incidence << Begin Data Update;
		subject_incidence << Recode Column(
			as column(subject_incidence, col[i]),
			{Map Value( _rcOrig, {"", "Not Reported"}, Unmatched( _rcNow ) )},
			Target Column( column(subject_incidence, col[i] ))
		);
		subject_incidence << End Data Update
	)
);

Aquí también hay un enfoque diferente para resolver su problema usando Obtener filas donde() para encontrar las filas que no tienen valor y cambiando el valor de esas filas a No reportado.

subject_incidence = Data Table( "Subject_Demographics" );
a = "Recoded";
col = subject_incidence << get column names( string );
Show( col );
nc = N Items( col );
For( i = 1, i <= nc, i++,
	If( Contains( col[i], a ),
		Try(
			Column( subject_incidence, col[i] )[subject_incidence <<
			get rows where( as Column( subject_incidence, col[i] ) == "" )] = "Not Reported"
		)
	)
);