368066_ja-JP

liliconcom

多くの列のバッチ記録

こんにちは、

 

recode関数を使用して、列名に特定の文字列を含む多くの列を再コード化しようとしています。 私はかなり近いと思いますが、スクリプトは列の評価で立ち往生しています。 だから私はどこかで重要な何かが欠けています。 任意のガイダンスをいただければ幸いです。

 

ベスト、

 

セバスチャン

 

Names default to here(1);
Clear log();

New Table( "Subject_Demographics",
 Add Rows( 48 ),
 New Column( "Unique Subject Identifier",
  Character,
  "Nominal",
  Set Selected,
  Set Values(
   {"8396882-P0101", "8396882-P0101", "8396882-P0102", "8396882-P0102",
   "8396882-P0103", "8396882-P0103", "8396882-P0104", "8396882-P0104",
   "8396882-P0201", "8396882-P0201", "8396882-P0202", "8396882-P0202",
   "8396882-P0203", "8396882-P0203", "8396882-P0204", "8396882-P0204",
   "8396882-P0301", "8396882-P0301", "8396882-P0302", "8396882-P0302",
   "8396882-P0303", "8396882-P0303", "8396882-P0304", "8396882-P0304",
   "8396882-P0401", "8396882-P0401", "8396882-P0402", "8396882-P0402",
   "8396882-P0403", "8396882-P0403", "8396882-P0404", "8396882-P0404",
   "8396882-P0501", "8396882-P0501", "8396882-P0502", "8396882-P0502",
   "8396882-P0503", "8396882-P0503", "8396882-P0504", "8396882-P0504",
   "8396882-P0601", "8396882-P0601", "8396882-P0602", "8396882-P0602",
   "8396882-P0603", "8396882-P0603", "8396882-P0604", "8396882-P0604"}
  )
 ),
 New Column( "Alertness - Recoded",
  Character,
  "Nominal",
  Set Selected,
  Set Values(
   {"", "", "", "", "", "", "", "", "", "", "Abnormal Finding",
   "Abnormal Finding", "", "", "", "", "", "", "", "", "", "", "", "", "",
   "", "Abnormal Finding", "Abnormal Finding", "Abnormal Finding",
   "Abnormal Finding", "Abnormal Finding", "Abnormal Finding", "", "", "",
   "", "Abnormal Finding", "Abnormal Finding", "", "", "", "", "", "", "",
   "", "", ""}
  )
 ),
 New Column( "Xyx Reflex - Recoded",
  Character,
  "Nominal",
  Set Selected,
  Set Values(
   {"Abnormal Finding", "Abnormal Finding", "Abnormal Finding",
   "Abnormal Finding", "Normal", "Normal", "", "", "", "", "Normal",
   "Normal", "Normal", "Normal", "Normal", "Normal", "Normal", "Normal",
   "Normal", "Normal", "Normal", "Normal", "Normal", "Normal", "Normal",
   "Normal", "Abnormal Finding", "Abnormal Finding", "Normal", "Normal",
   "Normal", "Normal", "", "", "", "", "Abnormal Finding",
   "Abnormal Finding", "Normal", "Normal", "Normal", "Normal", "Normal",
   "Normal", "Normal", "Normal", "Normal", "Normal"}
  )
 ),
 New Column( "Ataxia - Recoded",
  Character,
  "Nominal",
  Set Selected,
  Set Values(
   {"Abnormal Finding", "Abnormal Finding", "Abnormal Finding",
   "Abnormal Finding", "Abnormal Finding", "Abnormal Finding",
   "Abnormal Finding", "Abnormal Finding", "", "", "Abnormal Finding",
   "Abnormal Finding", "", "", "", "", "", "", "", "", "", "", "", "",
   "Abnormal Finding", "Abnormal Finding", "Abnormal Finding",
   "Abnormal Finding", "", "", "Abnormal Finding", "Abnormal Finding", "",
   "", "", "", "Abnormal Finding", "Abnormal Finding", "", "", "", "", "",
   "", "", "", "Abnormal Finding", "Abnormal Finding"}
  )
 )
);


subject_incidence = Data Table( "Subject_Demographics" );
a = "Recoded";
col = subject_incidence << get column names( string );
show(col);
nc = N Items( col );
For( i = 1, i <= nc, i++,
 If( Contains( col[i], a ),  
  subject_incidence << Begin Data Update;
  subject_incidence << Recode Column(
   column(subject_incidence, col[i]),
   {Map Value( _rcOrig, {"", "Not Reported"}, Unmatched( _rcNow ) )},
   Target Column( column(subject_incidence, col[i] ))
  );
  subject_incidence << End Data Update
 )
);

スクリプティングRe: 多数の列のバッチ記録

コードは@ihよりも少し単純になると思います

単に Column() 関数ではなく As Column() 関数を使用するようにコードを変更するだけで、コードが正しく実行されるようになります。

subject_incidence = Data Table( "Subject_Demographics" );
a = "Recoded";
col = subject_incidence << get column names( string );
show(col);
nc = N Items( col );
For( i = 1, i <= nc, i++,
	If( Contains( col[i], a ), 	
		subject_incidence << Begin Data Update;
		subject_incidence << Recode Column(
			as column(subject_incidence, col[i]),
			{Map Value( _rcOrig, {"", "Not Reported"}, Unmatched( _rcNow ) )},
			Target Column( column(subject_incidence, col[i] ))
		);
		subject_incidence << End Data Update
	)
);

ここでは、Get Rows Where() を使用して値のない行を見つけ、それらの行の値を Not Reported に変更することで、問題を解決する別のアプローチも示します。

subject_incidence = Data Table( "Subject_Demographics" );
a = "Recoded";
col = subject_incidence << get column names( string );
Show( col );
nc = N Items( col );
For( i = 1, i <= nc, i++,
	If( Contains( col[i], a ),
		Try(
			Column( subject_incidence, col[i] )[subject_incidence <<
			get rows where( as Column( subject_incidence, col[i] ) == "" )] = "Not Reported"
		)
	)
);