368066_it-IT

liliconcom

ricodifica in batch di molte colonne

Ciao,

 

Ho provato a ricodificare molte colonne che contengono una stringa specifica nel nome della colonna utilizzando la funzione recode. Penso di essere abbastanza vicino, ma lo script si sta bloccando con le valutazioni delle colonne. Quindi mi manca qualcosa di cruciale da qualche parte. Qualsiasi suggerimento sarebbe davvero apprezzato.

 

Migliore,

 

Sebastien

 

Names default to here(1);
Clear log();

New Table( "Subject_Demographics",
 Add Rows( 48 ),
 New Column( "Unique Subject Identifier",
  Character,
  "Nominal",
  Set Selected,
  Set Values(
   {"8396882-P0101", "8396882-P0101", "8396882-P0102", "8396882-P0102",
   "8396882-P0103", "8396882-P0103", "8396882-P0104", "8396882-P0104",
   "8396882-P0201", "8396882-P0201", "8396882-P0202", "8396882-P0202",
   "8396882-P0203", "8396882-P0203", "8396882-P0204", "8396882-P0204",
   "8396882-P0301", "8396882-P0301", "8396882-P0302", "8396882-P0302",
   "8396882-P0303", "8396882-P0303", "8396882-P0304", "8396882-P0304",
   "8396882-P0401", "8396882-P0401", "8396882-P0402", "8396882-P0402",
   "8396882-P0403", "8396882-P0403", "8396882-P0404", "8396882-P0404",
   "8396882-P0501", "8396882-P0501", "8396882-P0502", "8396882-P0502",
   "8396882-P0503", "8396882-P0503", "8396882-P0504", "8396882-P0504",
   "8396882-P0601", "8396882-P0601", "8396882-P0602", "8396882-P0602",
   "8396882-P0603", "8396882-P0603", "8396882-P0604", "8396882-P0604"}
  )
 ),
 New Column( "Alertness - Recoded",
  Character,
  "Nominal",
  Set Selected,
  Set Values(
   {"", "", "", "", "", "", "", "", "", "", "Abnormal Finding",
   "Abnormal Finding", "", "", "", "", "", "", "", "", "", "", "", "", "",
   "", "Abnormal Finding", "Abnormal Finding", "Abnormal Finding",
   "Abnormal Finding", "Abnormal Finding", "Abnormal Finding", "", "", "",
   "", "Abnormal Finding", "Abnormal Finding", "", "", "", "", "", "", "",
   "", "", ""}
  )
 ),
 New Column( "Xyx Reflex - Recoded",
  Character,
  "Nominal",
  Set Selected,
  Set Values(
   {"Abnormal Finding", "Abnormal Finding", "Abnormal Finding",
   "Abnormal Finding", "Normal", "Normal", "", "", "", "", "Normal",
   "Normal", "Normal", "Normal", "Normal", "Normal", "Normal", "Normal",
   "Normal", "Normal", "Normal", "Normal", "Normal", "Normal", "Normal",
   "Normal", "Abnormal Finding", "Abnormal Finding", "Normal", "Normal",
   "Normal", "Normal", "", "", "", "", "Abnormal Finding",
   "Abnormal Finding", "Normal", "Normal", "Normal", "Normal", "Normal",
   "Normal", "Normal", "Normal", "Normal", "Normal"}
  )
 ),
 New Column( "Ataxia - Recoded",
  Character,
  "Nominal",
  Set Selected,
  Set Values(
   {"Abnormal Finding", "Abnormal Finding", "Abnormal Finding",
   "Abnormal Finding", "Abnormal Finding", "Abnormal Finding",
   "Abnormal Finding", "Abnormal Finding", "", "", "Abnormal Finding",
   "Abnormal Finding", "", "", "", "", "", "", "", "", "", "", "", "",
   "Abnormal Finding", "Abnormal Finding", "Abnormal Finding",
   "Abnormal Finding", "", "", "Abnormal Finding", "Abnormal Finding", "",
   "", "", "", "Abnormal Finding", "Abnormal Finding", "", "", "", "", "",
   "", "", "", "Abnormal Finding", "Abnormal Finding"}
  )
 )
);


subject_incidence = Data Table( "Subject_Demographics" );
a = "Recoded";
col = subject_incidence << get column names( string );
show(col);
nc = N Items( col );
For( i = 1, i <= nc, i++,
 If( Contains( col[i], a ),  
  subject_incidence << Begin Data Update;
  subject_incidence << Recode Column(
   column(subject_incidence, col[i]),
   {Map Value( _rcOrig, {"", "Not Reported"}, Unmatched( _rcNow ) )},
   Target Column( column(subject_incidence, col[i] ))
  );
  subject_incidence << End Data Update
 )
);

ScriptingRe: ricodifica batch di molte colonne

Credo che il codice possa essere un po' più semplice di @ih

Il codice con la semplice modifica dell'utilizzo di una funzione As Column() anziché semplicemente di una funzione Column() consente al codice di essere eseguito correttamente

subject_incidence = Data Table( "Subject_Demographics" );
a = "Recoded";
col = subject_incidence << get column names( string );
show(col);
nc = N Items( col );
For( i = 1, i <= nc, i++,
	If( Contains( col[i], a ), 	
		subject_incidence << Begin Data Update;
		subject_incidence << Recode Column(
			as column(subject_incidence, col[i]),
			{Map Value( _rcOrig, {"", "Not Reported"}, Unmatched( _rcNow ) )},
			Target Column( column(subject_incidence, col[i] ))
		);
		subject_incidence << End Data Update
	)
);

Ecco anche un approccio diverso per risolvere il problema utilizzando Get Rows Where() per trovare le righe che non hanno valore e modificando il valore di tali righe su Not Reported

subject_incidence = Data Table( "Subject_Demographics" );
a = "Recoded";
col = subject_incidence << get column names( string );
Show( col );
nc = N Items( col );
For( i = 1, i <= nc, i++,
	If( Contains( col[i], a ),
		Try(
			Column( subject_incidence, col[i] )[subject_incidence <<
			get rows where( as Column( subject_incidence, col[i] ) == "" )] = "Not Reported"
		)
	)
);