367340_it-IT

liliconcom

Come faccio a eliminare le colonne in una tabella di dati i cui nomi contengono "UL" o "LL" o "UCL" o "LCL" o "USL" o "LSL" e la colonna che contiene solo "." (Non vuoto)

Ho a disposizione un set di dati di grandi dimensioni e desidero eliminare tutte le colonne il cui nome contiene "UL" o "LL" o "UCL" o "LCL" o "USL" o "LSL" e l'intera colonna contiene solo "." ma non vuoto tranne il nome della colonna. (le immagini sono mostrate sotto) Non sapevo come farlo dopo aver cercato su Google e letto il manuale di JMP. Grazie per l'aiuto su questo.

 

 

 

 

ScriptingOggetto: come si eliminano le colonne in una tabella dati i cui nomi contengono "UL" o "LL" o "UCL" o "LCL" o "USL" o "LSL" e la colonna che contiene solo "." (Non vuoto)

Qualcosa del genere potrebbe farlo:

 

Names Default To Here(1);

dt = New Table("Untitled 390",
 Add Rows(9),
 Compress File When Saved(1),
 New Column("a",
  Numeric,
  "Continuous",
  Format("Best", 12),
  Set Values([., ., ., ., ., ., ., ., .])
 ),
 New Column("a+LCL",
  Numeric,
  "Continuous",
  Format("Best", 12),
  Set Values([1, ., ., ., ., ., ., ., .])
 ),
 New Column("b+LCL",
  Numeric,
  "Continuous",
  Format("Best", 12),
  Set Values([., ., ., ., ., ., ., ., .])
 )
);

wait(1);

colNames = dt << Get Column Names("String");
colContainsList = {"UL", "LL", "UCL", "LCL", "USL", "LSL"};

For(i = 1, i <= N Items(colNames), i++,
 For(k = 1, k <= N Items(colContainsList), k++,
  If(Contains(colNames[i], colContainsList[k]),
   Summarize(dt, uniqValues = By(colNames[i]));
   If(N Items(uniqValues) == 1 & uniqValues[1] == ".",
    dt << Delete Columns(colNames[i]);
   );
   break();
  );
 );
);

Sei sicuro di voler controllare se il nome della colonna contiene una di queste stringhe o se il nome della colonna finisce con esse?