367340_de-DE

liliconcom

Wie lösche ich Spalten in einer Datentabelle, deren Namen "UL" oder "LL" oder "UCL" oder "LCL" oder "USL" oder "LSL" enthalten und deren Spalte nur "enthält". (Nicht leer)

Ich habe einen großen Datensatz zur Hand und möchte alle Spalten löschen, deren Name "UL" oder "LL" oder "UCL" oder "LCL" oder "USL" oder "LSL" enthält, und die gesamte Spalte enthält nur "." aber nicht leer außer dem Spaltennamen. (Bilder werden unten gezeigt) Ich wusste nicht, wie das geht, nachdem ich Google durchsucht und das JMP-Handbuch gelesen hatte. Vielen Dank für Ihre Hilfe.

 

 

 

 

SkriptingBetreff: Wie lösche ich Spalten in einer Datentabelle, deren Namen "UL" oder "LL" oder "UCL" oder "LCL" oder "USL" oder "LSL" enthalten und deren Spalte nur "enthält". (Nicht leer)

So etwas könnte es tun:

 

Names Default To Here(1);

dt = New Table("Untitled 390",
 Add Rows(9),
 Compress File When Saved(1),
 New Column("a",
  Numeric,
  "Continuous",
  Format("Best", 12),
  Set Values([., ., ., ., ., ., ., ., .])
 ),
 New Column("a+LCL",
  Numeric,
  "Continuous",
  Format("Best", 12),
  Set Values([1, ., ., ., ., ., ., ., .])
 ),
 New Column("b+LCL",
  Numeric,
  "Continuous",
  Format("Best", 12),
  Set Values([., ., ., ., ., ., ., ., .])
 )
);

wait(1);

colNames = dt << Get Column Names("String");
colContainsList = {"UL", "LL", "UCL", "LCL", "USL", "LSL"};

For(i = 1, i <= N Items(colNames), i++,
 For(k = 1, k <= N Items(colContainsList), k++,
  If(Contains(colNames[i], colContainsList[k]),
   Summarize(dt, uniqValues = By(colNames[i]));
   If(N Items(uniqValues) == 1 & uniqValues[1] == ".",
    dt << Delete Columns(colNames[i]);
   );
   break();
  );
 );
);

Möchten Sie wirklich überprüfen, ob der Spaltenname eine dieser Zeichenfolgen enthält oder ob der Spaltenname darauf endet?