362839_es-ES

liliconcom

Convertir un panel filtrable en un informe / lista "por"

Tengo una solicitud bastante fea de un usuario que espero tenga una respuesta más simple de lo que estoy pensando.

 

Tengo un panel de análisis exploratorio que genera unas pocas docenas de gráficos basados en algunas opciones de un filtro.Principalmente objetos de creación de gráficos, pero también ejecuta una selección de procesos.Lo que les gustaría es que la ventana de gráficos se repitiera una y otra vez para cada posible objeto del filtro.Entonces, si pudieras explorar 20 objetos, querrían 20 iteraciones una tras otra.Más o menos de la misma manera que el objeto "Página" funcionaría para el generador de gráficos.

 

Mi respuesta inicial fue que solo hicieran una captura de pantalla de cada paso en el filtro, pero no les encantó esa respuesta.

 

Estoy pensando que la única forma de hacer esto es simplemente ejecutar un bucle for masivo y simplemente construir iterativamente el JRN a partir de eso.¿Solo me preguntaba si había algunos ejemplos de esto que la gente había visto en alguna parte?O una forma más sencilla de hacer esto que me falta.

 

ScriptingRe: Convertir un panel de control filtrable en un informe/lista "por"

Un filtro de datos local podría ser útil. Si lo es, este método es bastante fácil de implementar una vez que tengas el script para el panel de control general. Simplemente puedes crear varias pestañas, cada una con el panel de control para un valor de filtro determinado. Aquí tienes un ejemplo con análisis bivariados.

Si tiene varias columnas de filtrado, puede concatenarlas para producir una sola columna, cuyos valores podrá recorrer posteriormente utilizando el filtro de datos local.

Puede maximizar el espacio disponible en el panel de control cerrando el cuadro de esquema del Filtro de datos locales y ocultar completamente este cuadro de esquema, si lo desea, cambiando el título del cuadro de esquema de "Filtro de datos locales" a "", y cerrándolo.

Salud,

Brady

Names Default To Here(1);

dt = open ("$Sample_Data\Car Physical Data.jmp");

bivExpr = expr(
	 Bivariate(
		Y( :Horsepower ),
		X( :Displacement ),
		Fit Line( {Line Color( {212, 73, 88} )} ),
		Local Data Filter(
			Show Histograms and Bars( 0 ),
			Add Filter(
				columns( :Type ),
				Where( :Type == _TYPE_ ),
				Display( :Type, N Items( 5 ) )
			)
		)
	);
);

nw = new window("Tabbed analyses",
	tb = tabbox()
);

summarize(dt, typeList = by(:type));

for(i=1, i<=nitems(typeList), i++,
	
	tb << append( 
		typeList[i], 
		vlistbox(eval(substitute(nameexpr(bivExpr), expr(_TYPE_), typeList[i])))
	)
);