366991_de-DE

liliconcom

GraphBuilder > FrameBox << Grafikskript hinzufügen (V-Linie (x,y1,y2)): x, y1 und y2 dynamisch zuweisen?

Hallo JMP-Community,

Jetzt bin ich an der Reihe, von einem scheinbar trivialen Projekt überrascht zu werden.

Ich versuche, V-Linien dynamisch zu einem Graph Builder-Diagramm hinzuzufügen, und erhalte mit dem folgenden Testskript ziemlich unerwartete Ergebnisse:

Names Default to Here (1);

dt = New Table ("TEST", 
 New Column ("X", Set Values ([1,2,3,4,5])),
 New Column ("Y", Set Values ([3,2,5,8,6]))
  
);

gb = dt << Graph Builder(
   Fit to Window( "Off" ),
   Level Frame Color( "Medium Dark Gray" ),
   Level Spacing Color( "Medium Dark Gray" ),
   Level Underline( 1 ),
   Page Level Underline( 0 ),
   Spacing Borders( 1 ),
   Variables( X( :X ), Y( :Y ) ),
   Elements( Points( X, Y, Legend( 5 ) ) )
   );

gbr = gb << report;


Ypos1 = 2;
Ypos2 = 6;

For (i = 1, i<=5, i++,
  
    Xpos = i;
    
    gbr [Framebox (1)] << Add graphics Script (
 
     Pen color (Green);
     V Line (1,4,6); 
     Pen color (Red);
     V Line (Xpos, Ypos1, Ypos2);
     Pen color (blue);
     V Line (i, 6,8);
 
    )
); 

Ich bekomme die grüne V-Linie richtig platziert, eine rote V-Linie bei X = 5 und keine blaue Linie.

Ich habe erfolglos versucht, Eval Expr (Expr()) für den gesamten Ausdruck und innerhalb des Grafikskripts hinzuzufügen, daher bin ich mir sicher, dass mir zu dieser späten Stunde eine einfache Lösung entgeht.

Jede Hilfe wäre sehr dankbar.

Danke,

TS

Qualitäts- und VerfahrenstechnikErgebnisse teilen und kommunizierenBetreff: GraphBuilder > FrameBox << Grafikskript hinzufügen (V-Linie (x, y1, y2)): x, y1 und y2 dynamisch zuweisen?

For (i = 1, i<=5, i++,
  
    Xpos = i;
    
    Eval(EvalExpr(gbr [Framebox (1)] << Add graphics Script (
 
     Pen color (Green);
     V Line (1,4,6); 
     Pen color (Red);
     V Line (expr(Xpos), expr(Ypos1), expr(Ypos2));
     Pen color (blue);
     V Line (expr(i), 6,8);
 
    )))
); 

 

 

Betreff: GraphBuilder > FrameBox << Grafikskript hinzufügen (V-Linie (x, y1, y2)): x, y1 und y2 dynamisch zuweisen?

Ich scheine in der Lage zu sein, blaue Linien mit eval(evalexpr(:

Eval(EvalExpr(gbr [Framebox (1)] << Add graphics Script (

 Pen color (Green);
 V Line (1,4,6); 
 Pen color (Red);
 V Line (Xpos, Ypos1, Ypos2);
 Pen color (Blue);
 V Line (Expr(i), 6,8);

)))

 

Verwendung von JMP15.2.1