366077_de-DE

liliconcom

Entfernen Sie Wrap-Variablen im Graph Builder mit JSL und fügen Sie sie hinzu

Wenn ich im Graph Builder über die Skriptfunktion „Kostümdiagramm“ im Fenster manuell eine Linie hinzufüge und sie dann mit einer nominalen Variablen umschließe oder gruppiere, wird in den gestapelten Fenstern dieselbe Kostümlinie kopiert.

 

Klicken Sie mit der rechten Maustaste in die Diagrammfenster -> Anpassen -> klicken Sie auf die Schaltfläche „+“ (fügen Sie den Eintrag „Skript“ hinzu) und fügen Sie das Linienskript hinzu (z. B. mit der Option „Beispiele“ -> „Linie ziehen“).

 

Aber wenn ich das Skript dann in der Datentabelle speichere, hat jedes Fenster jetzt einen Eintrag zum Hinzufügen des Kostümdiagramms und kann sehr lang werden. Ich müsste eine komplizierte for-Schleife programmieren, um den Diagrammcode zu jedem Fenster hinzuzufügen.

 

Ich möchte in JSL die gleichen Schritte wie von Hand ausführen:

- Diagramm erstellen

- Kostümlinie festlegen

- Fügen Sie die Wrap-Spalte hinzu

 

 

MassenanpassungBetreff: Wrap-Variablen im Graph Builder mit JSL entfernen und hinzufügen

Codeausschnitt zum Hinzufügen und Entfernen einer Wrap-Variablen. Dies ergab sich aus dem Unsession-JSL-Scripting des Online Discovery Summit 2021.

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

//make initial graph
gb = Graph Builder(
 Variables( X( :height ), Y( :weight ) ),
 Elements( Points( X, Y ), Smoother( X, Y ) )
);

//get a reference to the grab builder box
gbb = Report( gb )[Graph Builder Box( 1 )];

Wait( 1 );

//add a wrap variable to demonstrate adding
gbb << Add Variable( {:age, Role( "Wrap" )} );

Wait( 1 );

//remove wrap variable
gbb << Remove Variable(  {:age, Role( "Wrap" )});

Wait( 1 );

//add graphics script
gbb[frame box( 1 )] << Add Graphics Script(
 2,
 Description( "" ),
 If( Is Empty( g_x4 ),
  g_x4 = [52.92, 68.48, 70.56];
  g_y4 = [119.69, 139.30, 124.01];
 );
 Drag Line( g_x4, g_y4 );
);

//add wrap variable   
gbb << Add Variable( {:age, Role( "Wrap" )} );

Drehbuch von @julianisch Vielen Dank.

 

Betreff: Wrap-Variablen im Graph Builder mit JSL entfernen und hinzufügen

Im folgenden Beispiel wird die Nachricht <

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA\Big Class.jmp" );

gb = dt << Graph Builder(
 Size( 534, 456 ),
 Show Control Panel( 0 ),
 Variables( X( :height ), Y( :weight ) ),
 Elements( Points( X, Y, Legend( 2 ) ), Smoother( X, Y, Legend( 4 ) ) )
);

Report( gb )[FrameBox( 1 )] << Add Graphics Script(
 If( Is Empty( g_x1 ),
  g_x1 = [50.53, 66.28, 64.49];
  g_y1 = [102.99, 45.69, 106.10];
 );
 Drag Line( g_x1, g_y1 );
);

Report( gb )[Graph Builder Box( 1 )] << Add Variable( {:age, Role( "Wrap" )} );

Ich hoffe das hilft.