366077_fr-FR

liliconcom

Supprimer et ajouter des variables d'habillage dans le générateur de graphiques avec JSL

Lorsque j'ajoute manuellement une ligne dans le générateur de graphiques via la fonction de script de costume graphique dans la fenêtre, puis que j'emballe ou que je la regroupe avec une variable nominale, les fenêtres empilées auront la même ligne de costume copiée.

 

Faites un clic droit dans la fenêtre graphique -> Personnaliser -> cliquez sur le bouton «+» (ajoutez l'entrée «Script») et ajoutez le script de ligne (par exemple avec l'option Échantillons -> «Faire glisser la ligne»).

 

Mais si j'enregistre ensuite le script dans la table de données, chaque fenêtre a maintenant une entrée pour ajouter le graphique de costume et peut devenir très longue. J'aurais besoin de programmer une boucle for compliquée pour ajouter le code graphique à chaque fenêtre.

 

Je veux faire les mêmes étapes en JSL qu'à la main:

- créer un graphique

- définir la ligne de costume

- ajouter la colonne wrap

 

 

GraphiqueScriptingRe: supprimer et ajouter des variables d'enroulement dans le générateur de graphiques avec JSL

L'exemple suivant utilise le message << Ajouter un script graphique () pour ajouter la ligne de déplacement.  

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA\Big Class.jmp" );

gb = dt << Graph Builder(
 Size( 534, 456 ),
 Show Control Panel( 0 ),
 Variables( X( :height ), Y( :weight ) ),
 Elements( Points( X, Y, Legend( 2 ) ), Smoother( X, Y, Legend( 4 ) ) )
);

Report( gb )[FrameBox( 1 )] << Add Graphics Script(
 If( Is Empty( g_x1 ),
  g_x1 = [50.53, 66.28, 64.49];
  g_y1 = [102.99, 45.69, 106.10];
 );
 Drag Line( g_x1, g_y1 );
);

Report( gb )[Graph Builder Box( 1 )] << Add Variable( {:age, Role( "Wrap" )} );

J'espère que cela aide.

Re: supprimer et ajouter des variables d'enroulement dans le générateur de graphiques avec JSL

Extrait de code pour ajouter et supprimer une variable d'habillage. Cela provient du script JSL de session du sommet de découverte en ligne 2021.

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

//make initial graph
gb = Graph Builder(
 Variables( X( :height ), Y( :weight ) ),
 Elements( Points( X, Y ), Smoother( X, Y ) )
);

//get a reference to the grab builder box
gbb = Report( gb )[Graph Builder Box( 1 )];

Wait( 1 );

//add a wrap variable to demonstrate adding
gbb << Add Variable( {:age, Role( "Wrap" )} );

Wait( 1 );

//remove wrap variable
gbb << Remove Variable(  {:age, Role( "Wrap" )});

Wait( 1 );

//add graphics script
gbb[frame box( 1 )] << Add Graphics Script(
 2,
 Description( "" ),
 If( Is Empty( g_x4 ),
  g_x4 = [52.92, 68.48, 70.56];
  g_y4 = [119.69, 139.30, 124.01];
 );
 Drag Line( g_x4, g_y4 );
);

//add wrap variable   
gbb << Add Variable( {:age, Role( "Wrap" )} );

Script par @julien Merci beaucoup.