365199_es-ES

liliconcom

Convertir fecha / hora (hasta milisegundos) en una variable

Hola,

Estoy tratando de convertir una fecha / hora en milisegundos para insertarla en una declaración SQL que estoy usando en mi script JSL. El método típico que utilizo para hacerlo generalmente crea la variable (fecha) con comillas simples alrededor. Sin embargo, cuando intento el mismo método para mi fecha / hora, que incluye milisegundos, agrega dos comillas simples a cada extremo de la variable. ¿Podría alguien ayudarme a resolver potencialmente mi problema y / o ayudarme a orientarme en una dirección diferente para el resultado que estoy buscando?

 

dt1 = Current Data Table ();

dt1 << New Column ("Year", Formula(Year(Today())));  
dt1 << New Column ("Month", Formula(Month(Today()))); 
dt1 << New Column ("Day", Formula (Day(Today()))); 

dt1 << New Column ("UpdateDate", Formula (Char( :Year ) || "-" || Char( :Month ) || "-" || Char( :Day ) || "-" ||
"12.20.00.000000"));

dt2 = dt1 << Summary (
 Group (:UpdateDate), 
 Link to Original Data Table (0)
); 

dt2 = current data table (); 

dt2 << Delete Columns ("N Rows"); 

date_id = dt3:UpdateDate << Get Values; 
date_ids = "'"||date_id||"'"; 

El resultado que me gustaría sería así -> Formato: Formato HTML Versión: 1.0 StartHTML: 165 EndHTML: 420 StartFragment: 314 EndFragment: 388 StartSelection: 314 EndSelection: 314

'2021-3-4-09.20.00.000000'

 

¡Se agradece cualquier ayuda!

 

ScriptingRe: Convertir fecha / hora (hasta milisegundos) en una variable

Hola @Manchar ,

 

No estoy exactamente seguro de qué parte de su secuencia de comandos no se comportaba correctamente, ya que no se ejecutó de fábrica.Hice algunos cambios, ¿puedes ver si esto es lo que necesitas?

 

Names default to here(1);

dt1 = New Table( "Date test",
 Add Rows( 1 ),
 New Column( "Column 1", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [] ) )
);

dt1 << New Column ("Year", Formula(Year(Today())));  
dt1 << New Column ("Month", Formula(Month(Today()))); 
dt1 << New Column ("Day", Formula (Day(Today()))); 

//Original UpdateDate column
dt1 << New Column ("UpdateDate", Character, "Nominal", Formula (Char( :Year ) || "-" || Char( :Month ) || "-" || Char( :Day ) || "-" ||
"12.20.00.000000"));

//Option 1 - adjusting your script
dt2 = dt1 << Summary (
 Group (:UpdateDate), 
 Link to Original Data Table (0)
); 

dt2 << Delete Columns ("N Rows"); 

//Get the UpdateDate and add single quotes to each line
date_id = dt2:UpdateDate << Get Values; 
date_ids = list();
write("List of date_ids:");
for(i=1, i<= n items(date_id), i++,
 date_ids[i] = "'" || date_id[i]  || "'"; 
 write( "\!n" || date_ids[i] );
);

//Option 2 - include quotes in original column formula and then use associative array to find unique values
dt1 << New Column ("UpdateDateQuoted", Character, "Nominal", Formula ("'" || Char( :Year ) || "-" || Char( :Month ) || "-" || Char( :Day ) || "-" ||
"12.20.00.000000'"));

date_ids_2 = associative array(dt1:UpdateDateQuoted) << get keys;
write("\!n\!nDateID from associative array:\!n" || date_ids_2[1];)