364350_zh-TW

liliconcom

在圖形生成器中編寫列切換器寬度的腳本

我正在使用列切換器編寫幾個視覺效果腳本，發現它們默認的尺寸比我預期的要大。我從另一個類似的帖子中獲取了示例 JSL使用變量編寫列切換器腳本但試圖改變列切換器的寬度。我添加了一個本地數據過濾器，因為我知道可以使用“Display()”來操縱這些對象的大小。您可能會注意到我將其添加到下面的列切換器中。

這能實現嗎？

我之所以這麼問，是因為一旦發佈到 JMP Live，用戶就無法更改此寬度。

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
col_list3 = dt << get column names( Numeric );

For( i = N Items( col_list3 ), i > 0, i--,
 If( !Contains( col_list3[i], "PN" ),
  Remove From( col_list3, i )
 )
);

Graph Builder(
 Size( 534, 572 ),
 Show Control Panel( 0 ),
 Variables( X( :PNP1 ), Y( :NPN1 ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :lot_id ),
   Display( :lot_id, Size( 178, 221 ), Height( 221 ) )
  )
 ),
 Column Switcher(
  :NPN1,
  {:NPN1, :PNP2, :NPN2, :PNP3, :PNP4, :NPN3, :NPN4, :NPN5, :PNP5, :NPN6, :PNP6,
  :PNP7, :NPN7, :PNP8, :PNP9, :NPN8, :NPN9, :NPN10, :PNM1, :NPN11, :PNP10},
  Display( Width( 100 ) )
 )
);

自動化和腳本編寫內容組織數據探索和可視化大規模定制回复：在圖形生成器中編寫列切換器寬度的腳本

例如，有幾種了解如何影響事物的好方法（使用 gb 作為示例參考）：

 

 

gb << Show Properties;
gb << Show Tree STructure;
gb  << Get Xml; //use with XPath

另外，檢查 JMP 腳本指南並使用腳本索引也會有很大幫助。

 

在 JMP 社區中還可以找到一些有關元素/顯示操作的優秀主題。 幾個例子：

 

在 JSL 中增強您的用戶界面 ( US 2018 113 )

使用 XPath 瀏覽報告

 

回复：在圖形生成器中編寫列切換器寬度的腳本

這就成功了。我終於開始了解 JSL 的工作原理了。

回复：在圖形生成器中編寫列切換器寬度的腳本

我會以稍微不同的方式添加列切換器，以便您可以獲得參考，然後使用 << Set Size 到該參考：

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
col_list3 = dt << get column names( Numeric );

For( i = N Items( col_list3 ), i > 0, i--,
 If( !Contains( col_list3[i], "PN" ),
  Remove From( col_list3, i )
 )
);

gb = dt << Graph Builder(
 Size( 534, 572 ),
 Show Control Panel( 0 ),
 Variables( X( :PNP1 ), Y( :NPN1 ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :lot_id ),
   Display( :lot_id, Size( 178, 221 ), Height( 221 ) )
  )
 ),
);

colswitcher = gb << Column Switcher(
 :NPN1,
 {:NPN1, :PNP2, :NPN2, :PNP3, :PNP4, :NPN3, :NPN4, :NPN5, :PNP5, :NPN6, :PNP6,
 :PNP7, :NPN7, :PNP8, :PNP9, :NPN8, :NPN9, :NPN10, :PNM1, :NPN11, :PNP10}
);

colswitcher << set size(300,300);

您還可以從右鍵單擊 -> 編輯 -> 顯示屬性檢查如何以這種方式引用列切換器。