364350_es-ES

liliconcom

Secuencia de comandos del ancho del conmutador de columnas en Graph Builder

Estoy escribiendo varias imágenes con conmutadores de columnas y descubro que tienen un tamaño predeterminado más grande de lo que esperaría.Tomé el ejemplo JSL de otra publicación similar Scripting-column-switcher-using-variable pero traté de cambiar el ancho del conmutador de columnas.Agregué un filtro de datos local porque sé que se pueden manipular los tamaños de esos objetos con "Display ()".Puede notar que agregué esto al conmutador de columnas a continuación.

¿Se puede lograr esto?

Lo pregunto porque los usuarios no pueden cambiar este ancho una vez publicado en JMP Live.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
col_list3 = dt << get column names( Numeric );

For( i = N Items( col_list3 ), i > 0, i--,
 If( !Contains( col_list3[i], "PN" ),
  Remove From( col_list3, i )
 )
);

Graph Builder(
 Size( 534, 572 ),
 Show Control Panel( 0 ),
 Variables( X( :PNP1 ), Y( :NPN1 ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :lot_id ),
   Display( :lot_id, Size( 178, 221 ), Height( 221 ) )
  )
 ),
 Column Switcher(
  :NPN1,
  {:NPN1, :PNP2, :NPN2, :PNP3, :PNP4, :NPN3, :NPN4, :NPN5, :PNP5, :NPN6, :PNP6,
  :PNP7, :NPN7, :PNP8, :PNP9, :NPN8, :NPN9, :NPN10, :PNM1, :NPN11, :PNP10},
  Display( Width( 100 ) )
 )
);

GráficosScriptingRe: Secuencia de comandos del ancho del conmutador de columnas en Graph Builder

Agregaría el conmutador de columnas de una manera un poco diferente para que pueda obtener una referencia y luego usar << Establecer tamaño para esa referencia:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
col_list3 = dt << get column names( Numeric );

For( i = N Items( col_list3 ), i > 0, i--,
 If( !Contains( col_list3[i], "PN" ),
  Remove From( col_list3, i )
 )
);

gb = dt << Graph Builder(
 Size( 534, 572 ),
 Show Control Panel( 0 ),
 Variables( X( :PNP1 ), Y( :NPN1 ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :lot_id ),
   Display( :lot_id, Size( 178, 221 ), Height( 221 ) )
  )
 ),
);

colswitcher = gb << Column Switcher(
 :NPN1,
 {:NPN1, :PNP2, :NPN2, :PNP3, :PNP4, :NPN3, :NPN4, :NPN5, :PNP5, :NPN6, :PNP6,
 :PNP7, :NPN7, :PNP8, :PNP9, :NPN8, :NPN9, :NPN10, :PNM1, :NPN11, :PNP10}
);

colswitcher << set size(300,300);

También puede verificar desde clic derecho -> Editar -> Mostrar propiedades cómo hacer referencia al conmutador de columnas de esa manera.

Re: Secuencia de comandos del ancho del conmutador de columnas en Graph Builder

Eso hizo el truco.Comenzando a comprender finalmente cómo funciona JSL.