364350_fr-FR

liliconcom

Script de la largeur du sélecteur de colonne dans Graph Builder

Je scénarise plusieurs visuels avec des sélecteurs de colonne et je constate qu'ils sont par défaut d'une taille plus grande que ce à quoi je m'attendais.J'ai pris l'exemple JSL d'un autre article similaire Scripting-column-switcher-using-variable mais a essayé de changer la largeur du sélecteur de colonne.J'ai ajouté un filtre de données local car je sais que l'on peut manipuler les tailles de ces objets avec "Display ()".Vous remarquerez peut-être que j'ai ajouté ceci au sélecteur de colonne ci-dessous.

Cela peut-il être accompli?

Je demande car les utilisateurs ne sont pas en mesure de modifier cette largeur une fois publiée sur JMP Live.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
col_list3 = dt << get column names( Numeric );

For( i = N Items( col_list3 ), i > 0, i--,
 If( !Contains( col_list3[i], "PN" ),
  Remove From( col_list3, i )
 )
);

Graph Builder(
 Size( 534, 572 ),
 Show Control Panel( 0 ),
 Variables( X( :PNP1 ), Y( :NPN1 ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :lot_id ),
   Display( :lot_id, Size( 178, 221 ), Height( 221 ) )
  )
 ),
 Column Switcher(
  :NPN1,
  {:NPN1, :PNP2, :NPN2, :PNP3, :PNP4, :NPN3, :NPN4, :NPN5, :PNP5, :NPN6, :PNP6,
  :PNP7, :NPN7, :PNP8, :PNP9, :NPN8, :NPN9, :NPN10, :PNM1, :NPN11, :PNP10},
  Display( Width( 100 ) )
 )
);

GraphiqueScriptingRe: Scripting de la largeur du sélecteur de colonne dans Graph Builder

J'ajouterais le sélecteur de colonne d'une manière un peu différente afin que vous puissiez obtenir une référence, puis utiliser << Définir la taille à cette référence:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
col_list3 = dt << get column names( Numeric );

For( i = N Items( col_list3 ), i > 0, i--,
 If( !Contains( col_list3[i], "PN" ),
  Remove From( col_list3, i )
 )
);

gb = dt << Graph Builder(
 Size( 534, 572 ),
 Show Control Panel( 0 ),
 Variables( X( :PNP1 ), Y( :NPN1 ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :lot_id ),
   Display( :lot_id, Size( 178, 221 ), Height( 221 ) )
  )
 ),
);

colswitcher = gb << Column Switcher(
 :NPN1,
 {:NPN1, :PNP2, :NPN2, :PNP3, :PNP4, :NPN3, :NPN4, :NPN5, :PNP5, :NPN6, :PNP6,
 :PNP7, :NPN7, :PNP8, :PNP9, :NPN8, :NPN9, :NPN10, :PNM1, :NPN11, :PNP10}
);

colswitcher << set size(300,300);

Vous pouvez également vérifier à partir du clic droit -> Modifier -> Afficher les propriétés comment référencer le sélecteur de colonne de cette façon.

Re: Scripting de la largeur du sélecteur de colonne dans Graph Builder

Cela a fait l'affaire.Commencer à comprendre enfin comment fonctionne JSL.