364350_zh-CN

liliconcom

在图形生成器中编写列切换器宽度的脚本

我正在使用列切换器编写几个视觉效果脚本，发现它们默认的尺寸比我预期的要大。我从另一个类似的帖子中获取了示例 JSL使用变量编写列切换器脚本但试图改变列切换器的宽度。我添加了一个本地数据过滤器，因为我知道可以使用“Display()”来操纵这些对象的大小。您可能会注意到我将其添加到下面的列切换器中。

这能实现吗？

我之所以这么问，是因为一旦发布到 JMP Live，用户就无法更改此宽度。

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
col_list3 = dt << get column names( Numeric );

For( i = N Items( col_list3 ), i > 0, i--,
 If( !Contains( col_list3[i], "PN" ),
  Remove From( col_list3, i )
 )
);

Graph Builder(
 Size( 534, 572 ),
 Show Control Panel( 0 ),
 Variables( X( :PNP1 ), Y( :NPN1 ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :lot_id ),
   Display( :lot_id, Size( 178, 221 ), Height( 221 ) )
  )
 ),
 Column Switcher(
  :NPN1,
  {:NPN1, :PNP2, :NPN2, :PNP3, :PNP4, :NPN3, :NPN4, :NPN5, :PNP5, :NPN6, :PNP6,
  :PNP7, :NPN7, :PNP8, :PNP9, :NPN8, :NPN9, :NPN10, :PNM1, :NPN11, :PNP10},
  Display( Width( 100 ) )
 )
);

自动化和脚本编写内容组织数据探索和可视化大规模定制回复：在图形生成器中编写列切换器宽度的脚本

例如，有几种了解如何影响事物的好方法（使用 gb 作为示例参考）：

 

 

gb << Show Properties;
gb << Show Tree STructure;
gb  << Get Xml; //use with XPath

另外，检查 JMP 脚本指南并使用脚本索引也会有很大帮助。

 

在 JMP 社区中还可以找到一些有关元素/显示操作的优秀主题。 几个例子：

 

在 JSL 中增强您的用户界面 ( US 2018 113 )

使用 XPath 浏览报告

 

回复：在图形生成器中编写列切换器宽度的脚本

这就成功了。我终于开始了解 JSL 的工作原理了。

回复：在图形生成器中编写列切换器宽度的脚本

我会以稍微不同的方式添加列切换器，以便您可以获得参考，然后使用 << Set Size 到该参考：

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
col_list3 = dt << get column names( Numeric );

For( i = N Items( col_list3 ), i > 0, i--,
 If( !Contains( col_list3[i], "PN" ),
  Remove From( col_list3, i )
 )
);

gb = dt << Graph Builder(
 Size( 534, 572 ),
 Show Control Panel( 0 ),
 Variables( X( :PNP1 ), Y( :NPN1 ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :lot_id ),
   Display( :lot_id, Size( 178, 221 ), Height( 221 ) )
  )
 ),
);

colswitcher = gb << Column Switcher(
 :NPN1,
 {:NPN1, :PNP2, :NPN2, :PNP3, :PNP4, :NPN3, :NPN4, :NPN5, :PNP5, :NPN6, :PNP6,
 :PNP7, :NPN7, :PNP8, :PNP9, :NPN8, :NPN9, :NPN10, :PNM1, :NPN11, :PNP10}
);

colswitcher << set size(300,300);

您还可以从右键单击 -> 编辑 -> 显示属性检查如何以这种方式引用列切换器。