364350_zh-CN

liliconcom

在Graph Builder中编写列切换器的宽度脚本

我使用列切换器编写了一些视觉效果脚本，发现它们默认的尺寸比我期望的要大。我从另一个类似的帖子中获得了JSL的示例脚本列切换器使用变量但尝试更改列切换器的宽度。我添加了一个本地数据过滤器，因为我知道可以使用“ Display（）”来操纵这些对象的大小。您可能会注意到，我已将其添加到下面的列切换器中。

能做到吗？

我要问的是，一旦发布到JMP Live，用户将无法更改此宽度。

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
col_list3 = dt << get column names( Numeric );

For( i = N Items( col_list3 ), i > 0, i--,
 If( !Contains( col_list3[i], "PN" ),
  Remove From( col_list3, i )
 )
);

Graph Builder(
 Size( 534, 572 ),
 Show Control Panel( 0 ),
 Variables( X( :PNP1 ), Y( :NPN1 ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :lot_id ),
   Display( :lot_id, Size( 178, 221 ), Height( 221 ) )
  )
 ),
 Column Switcher(
  :NPN1,
  {:NPN1, :PNP2, :NPN2, :PNP3, :PNP4, :NPN3, :NPN4, :NPN5, :PNP5, :NPN6, :PNP6,
  :PNP7, :NPN7, :PNP8, :PNP9, :NPN8, :NPN9, :NPN10, :PNM1, :NPN11, :PNP10},
  Display( Width( 100 ) )
 )
);

图形学脚本编写回复：在图形生成器中编写列切换器的宽度脚本

我将以稍微不同的方式添加列切换器，以便您可以获取引用，然后使用<<设置该引用的大小：

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
col_list3 = dt << get column names( Numeric );

For( i = N Items( col_list3 ), i > 0, i--,
 If( !Contains( col_list3[i], "PN" ),
  Remove From( col_list3, i )
 )
);

gb = dt << Graph Builder(
 Size( 534, 572 ),
 Show Control Panel( 0 ),
 Variables( X( :PNP1 ), Y( :NPN1 ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :lot_id ),
   Display( :lot_id, Size( 178, 221 ), Height( 221 ) )
  )
 ),
);

colswitcher = gb << Column Switcher(
 :NPN1,
 {:NPN1, :PNP2, :NPN2, :PNP3, :PNP4, :NPN3, :NPN4, :NPN5, :PNP5, :NPN6, :PNP6,
 :PNP7, :NPN7, :PNP8, :PNP9, :NPN8, :NPN9, :NPN10, :PNM1, :NPN11, :PNP10}
);

colswitcher << set size(300,300);

您还可以从右键单击->编辑->显示属性中检查如何以这种方式引用列切换器。

回复：在图形生成器中编写列切换器的宽度脚本

做到了。最后，我开始全神贯注于JSL的工作原理。