364350_de-DE

liliconcom

Skripting für die Breite des Spaltenumschalters in Graph Builder

Ich schreibe mehrere Grafiken mit Spaltenumschaltern und stelle fest, dass sie standardmäßig eine größere Größe haben, als ich erwarten würde.Ich habe das Beispiel JSL aus einem anderen ähnlichen Beitrag genommen Scripting-Column-Switcher-using-Variable versuchte aber, die Breite des Spaltenumschalters zu ändern.Ich habe einen lokalen Datenfilter hinzugefügt, da ich weiß, dass man die Größe dieser Objekte mit "Display ()" ändern kann.Möglicherweise stellen Sie fest, dass ich dies dem Spaltenumschalter unten hinzugefügt habe.

Kann das erreicht werden?

Ich frage, da Benutzer diese Breite nach dem Posten in JMP Live nicht mehr ändern können.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
col_list3 = dt << get column names( Numeric );

For( i = N Items( col_list3 ), i > 0, i--,
 If( !Contains( col_list3[i], "PN" ),
  Remove From( col_list3, i )
 )
);

Graph Builder(
 Size( 534, 572 ),
 Show Control Panel( 0 ),
 Variables( X( :PNP1 ), Y( :NPN1 ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :lot_id ),
   Display( :lot_id, Size( 178, 221 ), Height( 221 ) )
  )
 ),
 Column Switcher(
  :NPN1,
  {:NPN1, :PNP2, :NPN2, :PNP3, :PNP4, :NPN3, :NPN4, :NPN5, :PNP5, :NPN6, :PNP6,
  :PNP7, :NPN7, :PNP8, :PNP9, :NPN8, :NPN9, :NPN10, :PNM1, :NPN11, :PNP10},
  Display( Width( 100 ) )
 )
);

GrafikSkriptingBetreff: Skripting der Breite des Spaltenumschalters in Graph Builder

Ich würde den Spaltenumschalter auf eine etwas andere Art und Weise hinzufügen, damit Sie eine Referenz erhalten und dann << Größe auf diese Referenz setzen können:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
col_list3 = dt << get column names( Numeric );

For( i = N Items( col_list3 ), i > 0, i--,
 If( !Contains( col_list3[i], "PN" ),
  Remove From( col_list3, i )
 )
);

gb = dt << Graph Builder(
 Size( 534, 572 ),
 Show Control Panel( 0 ),
 Variables( X( :PNP1 ), Y( :NPN1 ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :lot_id ),
   Display( :lot_id, Size( 178, 221 ), Height( 221 ) )
  )
 ),
);

colswitcher = gb << Column Switcher(
 :NPN1,
 {:NPN1, :PNP2, :NPN2, :PNP3, :PNP4, :NPN3, :NPN4, :NPN5, :PNP5, :NPN6, :PNP6,
 :PNP7, :NPN7, :PNP8, :PNP9, :NPN8, :NPN9, :NPN10, :PNM1, :NPN11, :PNP10}
);

colswitcher << set size(300,300);

Sie können auch über Rechtsklick -> Bearbeiten -> Eigenschaften anzeigen überprüfen, wie auf diese Weise auf Column Switcher verwiesen wird.

Betreff: Skripting der Breite des Spaltenumschalters in Graph Builder

Das hat funktioniert.Endlich fange ich an, mich mit der Funktionsweise von JSL zu beschäftigen.