JSL-欠落データの％を検索3列のデータテーブルがあります
IDとSUB_IDでグループ化されたHEIGHT列に欠落データの割合を示すテーブルを作成する必要があります。 上記の場合、結果は次のようになります。
ただし、データが欠落している行がない場合もあります。 その場合、欠落率は0である必要があります。
このためのJSLスクリプトを書くのに助けが必要です。 ご指導いただければ幸いです。 以下のスクリプトには3つの問題があります。
1.データテーブルへのハンドル/参照を追跡して、いつでも呼び出すことができるようにするにはどうすればよいですか。 スクリプトの最初では、常に「dt = CurrentDataTable」を使用しています。 しかし、いくつかのサマリーテーブル/サブセットテーブルを作成した後、元のテーブルへの参照を失い、それを最新にする方法がわかりません。
2.欠落している行がない場合でも、これが機能する必要があります。 現在、スクリプトは途中で停止します。
3.パーセントが欠落している最後のテーブルを除いて、すべてのテーブルを閉じる必要があります。
// Read the original table
dt = CurrentDataTable();
main_table = Data Table( dt ) << get name; // get the table name
// Create a summary table with no of rows grouped by ID and SUB_ID
dt_summary = dt<< Summary(Group(:ID, :SUB_ID), Freq("None"), Weight("None"), output table name( "Main Table Summary"));
:N Rows << Set Name( "Total No of Rows" );
// Create a subset of the original table with only the missing rows
Current Data Table(Data Table(main_table));
dt = CurrentDataTable();
dt_missing = dt << select where( Is Missing( :HEIGHT ) == 1 ) << Subset(Output Table Name("Missing Rows"));
If( !Is Empty( dt_missing ),
dt_missing_summary = Data Table( dt_missing ) << Summary(
Group( :ID, :SUB_ID ),Freq("None"), Weight("None"), output table name( "Missing Rows Table Summary"));
:N Rows << Set Name( "No of Rows with Missing Data" );
dt_missing_summary << Update(
With( Data Table( dt_summary ) ),
Match Columns( :ID = ID, :SUB_ID = :SUB_ID ),
Add Columns from Update table( :Total No of Rows )
);
New Column( "PercentMissing",
Numeric,
"Continuous",
Format( "Percent", 12, 2 ),
Formula( :No of Rows with Missing Data / :Total No of Rows )
);
);
//Close( dt_missing, nosave );
//Close( dt_summary, nosave );ありがとう
スクリプティングRe：JSL-欠測データの％を検索こんにちは@rverma 、
表内の要約を利用できるようです。そのセクションで行っていることのほとんどを作成してから、比率（％）を計算する式を含む列を追加できます。
欠測データがない場合でも機能するこのようなスクリプトを作成できます（項目2を追加）：
sumdt = dt << Summary( Group( :ID, :SUB_ID ), N Missing( :HEIGHT ), Freq( "None" ), Weight( "None" ) );
sumdt << New Column( "Percent Missing",
Numeric,
Continuous,
Format( Percent ),
Formula( :"N Missing(HEIGHT)"n / :N Rows )
);
次に、これをサブセット化できます。 それでも他のウィンドウを閉じます。
その始まり
Re：JSL-欠測データの％を検索まず、JMPスクリプティングガイドを確認することを強くお勧めします。 JMP15スクリプトガイドおよびJmp / Help / ScriptingIndexから見つかったScriptingIndex。 これらは、JSLスクリプトの非常に優れたソースです。
このタスクを実行するには、jslは必要ありません。
1.2つの欠落値を提供したサンプルテーブルから始めましょう
2.統計として高さ、グループとしてSUB_IDとIDを使用してNが欠落しているテーブルの要約を作成します
3. N行とN行方不明（高さ）列を選択して、新しい数式を作成します
4.形式を[列のプロパティ]から[パーセント]に変更し、必要に応じて列の名前を変更します
これらの手順に基づいて、JMPが提供する機能をかなり簡単に使用して、この手動プロセスを自動プロセスに変更する手順に必要なスクリプトを表示することもできます（より堅牢にするために小さな変更を行う必要があります）。
そしてあなたの質問のために1＆3：
1.データテーブルを作成/開く/取得する方法に大きく依存します。 常に同じ名前を持っている場合はそれを参照できますが、同じ名前で複数のデータテーブルを作成するのは非常に簡単であり、JMPは名前の後にインデックスを追加するため、長期的には信頼できません。 ただし、これらはDatatable（nameofdatatable）で参照できます。
3. Get Data Table List（）を使用して、データテーブルのリストを取得できます。 データテーブルをループし、不要なテーブルを閉じます。 しかし、私の意見では、Close（datatableへの参照、保存なし）を使用して、必要のないデータテーブルをできるだけ早く閉じる必要があります。
タスクを実行するためのスクリプトの例：
Names Default To Here(1);
//create example data and add reference to dt variable
dt = New Table("exampledata",
Add Rows(8),
Compress File When Saved(1),
New Column("ID",
Numeric,
"Nominal",
Format("Best", 12),
Set Values([1, 1, 1, 1, 2, 2, 2, 2])
),
New Column("SUB_ID",
Character,
"Nominal",
Set Values({"A", "A", "B", "B", "A", "A", "B", "B"})
),
New Column("HEIGHT",
Numeric,
"Continuous",
Format("Best", 12),
Set Values([10, 11, ., 9, ., 12, 8, 12])
)
);
//note Link to original data table(0)
//dt_summary is reference to the new Summary table
dt_summary = dt << Summary(
Group(:ID, :SUB_ID),
N Missing(:HEIGHT),
Freq("None"),
Weight("None"),
Link to original data table(0),
output table name("Main Table Summary")
);
//close unnecessary datatable
Close(dt, no save);
//add new column with formula
dt_summary << New Column("Percent Missing",
Numeric,
"Continuous",
Format("Percent", 12, 0),
Formula(:Name("N Missing(HEIGHT)") / :"N Rows"),
);
//rename columns
Column(dt_summary, "N Rows") << Set Name("Total No of Rows");
Column(dt_summary, "N Missing(HEIGHT)") << Set Name("No of Rows with Missing Data");
Re：JSL-欠測データの％を検索@jthi 、
私たちは同時に同じ方針に沿って考えていました。あなたの答えが私のものよりも少し完全であり、項目1と3の提案に同意するのが好きです。
Re：JSL-欠測データの％を検索- 追加する必要があります
Names Default To Here( 1 );
スクリプトで指定された変数が同じ名前の他のスクリプトの変数によって変更されないように制限し、現在のスクリプトの値を変更します
- Current Data Table（）関数について誤解しているようです。これは2つの異なる方法で使用でき、元のデータテーブルへの参照を失わないようにするのに役立ちます。仕様
dt = Current Data Table();
あなたはきちんと使っています。そして、スクリプトの後半で、元のデータテーブルを「現在のデータテーブル」にしたい場合は、必要なのはcurrent data table(dt);
これにより、JMPは現在のデータテーブルとして「dt」を使用するようになります。「dt」を「=」の左側に配置して再割り当てすることは、控える必要があります。
- アクションを1つのステートメントにまとめることが適切でない場合があります。きみの
dt_missing = dt << select where( Is Missing( :HEIGHT ) == 1 ) << Subset(Output Table Name("Missing Rows"));行を選択し、テーブルをすべて1つのステートメントでサブセット化することを期待しています。問題は、：Heightの値が欠落していない場合、必要なものを提供できないことです。スクリプトの私のリワーク（下記）では、dtデータテーブルで行が選択されているかどうかが確認され、欠落している行が見つかったかどうかが確認されます。見つかった場合は、処理を続行します。dt << select where( Is Missing( :HEIGHT ) == 1 );
If( N Rows( dt << get selected rows ) > 0,
- Try（）関数は、失敗する可能性のある関数を実行する場合に非常に便利です。失敗した場合は、スクリプトの実行を停止しないでください。使用しているClose（）関数は、Try（）関数の使用に最適です。
Try( Close( dt_missing, nosave ) );
Try( Close( dt_summary, nosave ) );
これがお役に立てば幸いです.....さらに質問がある場合は、返信してください
Names Default To Here( 1 );
// Read the original table
dt = Current Data Table();
//main_table = Data Table( dt ) << get name; // get the table name
// Create a summary table with no of rows grouped by ID and SUB_ID
dt_summary = dt << Summary(
Group( :ID, :SUB_ID ),
Freq( "None" ),
Weight( "None" ),
output table name( "Main Table Summary" )
);
:N Rows << Set Name( "Total No of Rows" );
// Create a subset of the original table with only the missing rows
//Current Data Table(Data Table(main_table));
//dt = CurrentDataTable();
dt << select where( Is Missing( :HEIGHT ) == 1 );
If( N Rows( dt << get selected rows ) > 0,
dt_missing = dt << Subset( Output Table Name( "Missing Rows" ), selected rows( 1 ) );
dt_missing_summary = Data Table( dt_missing ) <<
Summary(
Group( :ID, :SUB_ID ),
Freq( "None" ),
Weight( "None" ),
output table name( "Missing Rows Table Summary" )
);
:N Rows << Set Name( "No of Rows with Missing Data" );
dt_missing_summary << Update(
With( Data Table( dt_summary ) ),
Match Columns( :ID = ID, :SUB_ID = :SUB_ID ),
Add Columns from Update table( :Total No of Rows )
);
New Column( "PercentMissing",
Numeric,
"Continuous",
Format( "Percent", 12, 2 ),
Formula( :No of Rows with Missing Data / :Total No of Rows )
);
);
Try( Close( dt_missing, nosave ) );
Try( Close( dt_summary, nosave ) );
Re：JSL-欠測データの％を検索以前にこれを見た場合は、もう一度お読みください。 間違いがありました。
JMPの組み込み関数であるColN Missing（）を使用すると、このタスクが簡略化されます。 2つのアプローチを紹介します。
解決策＃1：
- 最初のテーブルのグループごとに欠落をカウントする列を作成します。
- 最初の表を要約します。
- （必要に応じて）N行列の名前を変更し、比率の数式列を作成します。
Names Default To Here( 1 );
//these 2 lines just create a table with overall missing rate of 35% for the weight varable.
dt = Open( "$Sample_Data\Car Physical Data.jmp" );
dt:weight[Loc( J( 116, 1, Random Binomial( 1, .35 ) ) == 0 )] = .;
//add a formula column to compute n missing rows.
dt << New Column( "Missing Rows", formula( Col N Missing( :weight, :country, :type ) ) );
//create summary table, rename N Rows column, and add a % missing formula column.
dtSum = dt << Summary( Group( :Country, :Type, :missing rows));
dtSum:N Rows << set name("Total Rows");
dtSum << new column ("Pct Missing", formula(:missing rows / :total rows));
解決策＃2：
- 最初のテーブルにすべての数式列を作成してから、簡単な要約を作成します。
- 必要に応じて、[概要]テーブルから[N行]列を削除します。
**このメソッドの「落とし穴」は、Total Rows（）関数にあります。 最初の引数はグループ化列として使用できないため、ダミー列として機能させるには、最初の引数を「1」でリードする必要があります。 1を省略すると、カウントが「タイプ」グループの行数のみを反映していることがわかります...国とタイプの組み合わせではありません。
乾杯、そして初めてのエラーについてお詫びします。
Names Default To Here( 1 );
//don't worry about these; these are just to get a table present with some missing values @ an
//overall missing rate of 35%
dt = Open( "$Sample_Data\Car Physical Data.jmp" );
dt:weight[Loc( J( 116, 1, Random Binomial( 1, .35 ) ) == 0 )] = .;
//create formula columns using built-in functions to get what you're after.
dt << New Column( "Missing Rows", formula( Col N Missing( :weight, :country, :type ) ) );
dt << New Column( "Total Rows", formula( Col Number( 1, :country, :type ) ) );
dt << New Column( "Group Pct Missing", formula( :missing rows / :total rows ) );
//view summary table.
dtSum = dt << Summary( Group( :Country, :Type, :missing rows, :total rows, :group pct missing));
