363284_fr-FR

liliconcom

JSL - Trouver% de données manquantes

J'ai une table de données avec 3 colonnes

J'ai besoin de créer un tableau montrant le% des données manquantes dans la colonne HEIGHT regroupées par ID et SUB_ID. Dans le cas ci-dessus, le résultat devrait être:

 

Mais il est possible dans certains cas qu'il n'y ait aucune ligne avec des données manquantes. Dans ce cas, le pourcentage manquant doit être égal à 0.

 

J'ai besoin d'aide pour écrire un script JSL pour cela. J'apprécierai toute orientation. J'ai trois problèmes dans mon script ci-dessous:

 

1. Comment puis-je suivre la poignée / la référence à une table de données afin que je puisse la rappeler à tout moment. J'ai toujours utilisé "dt = CurrentDataTable" au début du script. Mais après avoir créé quelques tableaux récapitulatifs / tableaux de sous-ensembles, je perds la référence à la table d'origine et je ne sais pas comment l'actualiser.

2. J'ai besoin que cela fonctionne même s'il n'y a pas de lignes manquantes. À l'heure actuelle, le script s'arrête au milieu.

3. J'ai besoin de toutes les tables pour fermer sauf la table finale avec le pourcentage manquant.

// Read the original table 
dt = CurrentDataTable();
main_table = Data Table( dt ) << get name; // get the table name

// Create a summary table with no of rows grouped by ID and SUB_ID
dt_summary = dt<< Summary(Group(:ID, :SUB_ID), Freq("None"), Weight("None"), output table name( "Main Table Summary"));
:N Rows << Set Name( "Total No of Rows" );

// Create a subset of the original table with only the missing rows
Current Data Table(Data Table(main_table));
dt = CurrentDataTable();
dt_missing = dt << select where( Is Missing( :HEIGHT ) == 1 ) << Subset(Output Table Name("Missing Rows"));

If( !Is Empty( dt_missing ),
 dt_missing_summary = Data Table( dt_missing ) << Summary(
  Group( :ID, :SUB_ID ),Freq("None"), Weight("None"), output table name( "Missing Rows Table Summary"));
 :N Rows << Set Name( "No of Rows with Missing Data" );
  
 dt_missing_summary << Update(
  With( Data Table( dt_summary ) ),
  Match Columns( :ID = ID, :SUB_ID = :SUB_ID ),
  Add Columns from Update table( :Total No of Rows )
  );
  
 New Column( "PercentMissing",
  Numeric,
  "Continuous",
  Format( "Percent", 12, 2 ),
  Formula( :No of Rows with Missing Data / :Total No of Rows )
  );
 
 );
//Close( dt_missing, nosave );
//Close( dt_summary, nosave );

Merci

ScriptingRe: JSL - Trouver% de données manquantes

salut @rverma ,

 

Je vois que vous êtes en mesure de tirer parti du résumé dans les tableaux.Je peux produire la plupart de ce que vous faites dans cette section, puis ajouter une colonne avec une formule pour calculer le ratio (%).

Je pourrais faire le script comme celui-ci qui fonctionnera toujours s'il n'y a pas de données manquantes (addesses item 2):

sumdt = dt << Summary( Group( :ID, :SUB_ID ), N Missing( :HEIGHT ), Freq( "None" ), Weight( "None" ) );
sumdt << New Column( "Percent Missing",
 Numeric,
 Continuous,
 Format( Percent ),
 Formula( :"N Missing(HEIGHT)"n / :N Rows )
);

Ensuite, vous pourriez faire un sous-ensemble à ce sujet. Et fermez toujours les autres fenêtres.

C'est un début

Re: JSL - Trouver% de données manquantes

Tout d'abord, je suggère fortement de consulter le guide de script JMP: Guide de création de scripts JMP15 et Index de script trouvé à partir de Jmp / Help / Scripting Index. Ce sont de très bonnes sources pour les scripts JSL.

 

Pour effectuer cette tâche, vous n'aurez besoin d'aucun jsl:

1. Commençons par l'exemple de tableau que vous nous avez fourni avec deux valeurs manquantes

2. Créez un résumé de la table avec N manquant avec hauteur comme statistique et SUB_ID et ID comme groupe

3. Créez une nouvelle formule en sélectionnant N lignes et N colonnes manquantes (HAUTEUR)

4. Changez le format en Pourcentage à partir des propriétés de la colonne et renommez les colonnes si nécessaire

 

Sur la base de ces étapes, vous pouvez également utiliser assez facilement les fonctionnalités fournies par les JMP pour afficher les scripts nécessaires aux étapes de transformation de ce processus manuel en processus automatisé (de petites modifications doivent être apportées pour le rendre plus robuste).

 

Et pour vos questions 1 & 3:

1. Cela dépend beaucoup de la manière dont vous créez / ouvrez / récupérez vos tables de données. Si vous avez toujours le même nom, vous pouvez y faire référence, mais je n'aurais pas confiance à long terme car il est si facile de créer plusieurs tables de données avec le même nom et JMP ajoutera une indexation après les noms. Mais ceux-ci peuvent être référencés par Datatable (nameofdatatable).

3. Vous pouvez obtenir la liste des tables de données avec Get Data Table List (). Faites une boucle sur les tables de données et fermez celles qui ne sont pas nécessaires. Mais à mon avis, vous devriez toujours fermer la datatable dont vous n'aurez pas besoin dès que possible avec Close (référence à datatable, No save).

 

Exemple de script pour effectuer la tâche:

 

Names Default To Here(1);

//create example data and add reference to dt variable
dt = New Table("exampledata",
 Add Rows(8),
 Compress File When Saved(1),
 New Column("ID",
  Numeric,
  "Nominal",
  Format("Best", 12),
  Set Values([1, 1, 1, 1, 2, 2, 2, 2])
 ),
 New Column("SUB_ID",
  Character,
  "Nominal",
  Set Values({"A", "A", "B", "B", "A", "A", "B", "B"})
 ),
 New Column("HEIGHT",
  Numeric,
  "Continuous",
  Format("Best", 12),
  Set Values([10, 11, ., 9, ., 12, 8, 12])
 )
);


//note Link to original data table(0)
//dt_summary is reference to the new Summary table
dt_summary = dt << Summary(
 Group(:ID, :SUB_ID),
 N Missing(:HEIGHT),
 Freq("None"),
 Weight("None"),
 Link to original data table(0),
 output table name("Main Table Summary")
);

//close unnecessary datatable
Close(dt, no save);

//add new column with formula
dt_summary << New Column("Percent Missing",
 Numeric,
 "Continuous",
 Format("Percent", 12, 0),
 Formula(:Name("N Missing(HEIGHT)") / :"N Rows"),
);
//rename columns
Column(dt_summary, "N Rows") << Set Name("Total No of Rows");
Column(dt_summary, "N Missing(HEIGHT)") << Set Name("No of Rows with Missing Data");

 

 

Re: JSL - Trouver% de données manquantes

@jthi ,

 

Nous pensions dans le même sens en même temps, j'aime que votre réponse soit un peu plus complète que la mienne et que j'approuve les suggestions des points 1 et 3.

Re: JSL - Trouver% de données manquantes

1. Vous devez ajouter

   Names Default To Here( 1 );

   pour limiter les variables spécifiées dans votre script à ne pas être modifiées par des variables dans d'autres scripts du même nom, en modifiant les valeurs de votre script actuel
2. Il semble que vous ayez un malentendu sur la fonction Current Data Table ().Il peut être utilisé de 2 manières différentes et vous aidera à ne pas perdre la référence à votre table de données d'origine.La spécification

   dt = Current Data Table();

   vous avez utilisé correctement.Et quand plus tard dans votre script, vous voulez faire de la table de données d'origine la "table de données actuelle", il vous suffit de faire

   current data table(dt);

   Cela indiquera à JMP d'utiliser "dt" comme table de données actuelle.Ce que vous devez vous abstenir de faire est de réaffecter "dt" en le plaçant sur le côté gauche d'un "=".
3. Parfois, ce n'est pas une bonne chose de combiner des actions dans une seule déclaration.Ton

   dt_missing = dt << select where( Is Missing( :HEIGHT ) == 1 ) << Subset(Output Table Name("Missing Rows"));

   s'attend à sélectionner des lignes et à créer un sous-ensemble de la table dans une seule instruction.Le problème est qu'il échouera à vous donner ce que vous voulez s'il n'y a aucune valeur manquante de: Hauteur.Dans ma retouche de votre script (ci-dessous), la table de données dt a les lignes sélectionnées ou non, puis la vérification est faite pour voir si des lignes manquantes ont été trouvées, et si c'est le cas alors et seulement alors continuer le traitement

   dt << select where( Is Missing( :HEIGHT ) == 1 ); 
   
   If( N Rows( dt << get selected rows ) > 0,

4. La fonction Try () est très pratique pour exécuter des fonctions qui pourraient éventuellement échouer, et si elles le font, vous ne voulez pas que le script s'arrête de fonctionner.Les fonctions Close () que vous utilisez et idéales pour utiliser la fonction Try ()

   Try( Close( dt_missing, nosave ) );
   Try( Close( dt_summary, nosave ) );

J'espère que cela vous sera utile ..... si vous avez d'autres questions, veuillez répondre

Names Default To Here( 1 );

// Read the original table 
dt = Current Data Table();
//main_table = Data Table( dt ) << get name; // get the table name

// Create a summary table with no of rows grouped by ID and SUB_ID
dt_summary = dt << Summary(
 Group( :ID, :SUB_ID ),
 Freq( "None" ),
 Weight( "None" ),
 output table name( "Main Table Summary" )
);
:N Rows << Set Name( "Total No of Rows" );

// Create a subset of the original table with only the missing rows
//Current Data Table(Data Table(main_table));
//dt = CurrentDataTable();
dt << select where( Is Missing( :HEIGHT ) == 1 ); 

If( N Rows( dt << get selected rows ) > 0,
 dt_missing = dt << Subset( Output Table Name( "Missing Rows" ), selected rows( 1 ) );
 dt_missing_summary = Data Table( dt_missing ) <<
 Summary(
  Group( :ID, :SUB_ID ),
  Freq( "None" ),
  Weight( "None" ),
  output table name( "Missing Rows Table Summary" )
 );
 :N Rows << Set Name( "No of Rows with Missing Data" );
  
 dt_missing_summary << Update(
  With( Data Table( dt_summary ) ),
  Match Columns( :ID = ID, :SUB_ID = :SUB_ID ),
  Add Columns from Update table( :Total No of Rows )
 );
  
 New Column( "PercentMissing",
  Numeric,
  "Continuous",
  Format( "Percent", 12, 2 ),
  Formula( :No of Rows with Missing Data / :Total No of Rows )
 );
 
);
Try( Close( dt_missing, nosave ) );
Try( Close( dt_summary, nosave ) );

Re: JSL - Trouver % de données manquantes

S'IL VOUS PLAÎT RELIRE si vous avez vu cela plus tôt. Il y avait une erreur.

 

L'utilisation de la fonction intégrée de JMP, Col N Missing ( ), simplifie cette tâche. Je vais montrer 2 approches.

 

SOLUTION #1 :

• Créez une colonne pour compter les manquants par groupe dans le premier tableau.
• Résumez le premier tableau.
• Modifiez le nom de la colonne N lignes (si vous le souhaitez) et créez une colonne de formules pour le rapport.

 

Names Default To Here( 1 );

//these 2 lines just create a table with overall missing rate of 35% for the weight varable.
dt = Open( "$Sample_Data\Car Physical Data.jmp" );
dt:weight[Loc( J( 116, 1, Random Binomial( 1, .35 ) ) == 0 )] = .;

//add a formula column to compute n missing rows.
dt << New Column( "Missing Rows", formula( Col N Missing( :weight, :country, :type ) ) );

//create summary table, rename N Rows column, and add a % missing formula column.
dtSum = dt << Summary( Group( :Country, :Type, :missing rows));
dtSum:N Rows << set name("Total Rows");
dtSum << new column ("Pct Missing", formula(:missing rows / :total rows));

 

SOLUTION #2 :

• Créez toutes les colonnes de formules dans le premier tableau, puis faites un résumé direct.
• Vous pouvez éventuellement supprimer la colonne N lignes du tableau récapitulatif.

** Le "gotcha" dans cette méthode se trouve dans la fonction Total Rows ( ). Vous devez commencer par un "1" pour le premier argument, pour servir de colonne fictive, car le premier argument ne peut pas être utilisé comme colonne de regroupement. Omettez le 1, et vous verrez que les nombres reflètent le nombre de lignes dans le groupe "type" uniquement... pas la combinaison du pays et du type.

 

Bravo et excuses pour l'erreur la première fois.

 

Names Default To Here( 1 );

//don't worry about these; these are just to get a table present with some missing values @ an
//overall missing rate of 35%
dt = Open( "$Sample_Data\Car Physical Data.jmp" );
dt:weight[Loc( J( 116, 1, Random Binomial( 1, .35 ) ) == 0 )] = .;

//create formula columns using built-in functions to get what you're after.
dt << New Column( "Missing Rows", formula( Col N Missing( :weight, :country, :type ) ) );
dt << New Column( "Total Rows", formula( Col Number( 1, :country, :type ) ) );
dt << New Column( "Group Pct Missing", formula( :missing rows / :total rows ) );

//view summary table.
dtSum = dt << Summary( Group( :Country, :Type, :missing rows, :total rows, :group pct missing));