357835_zh-TW

liliconcom

控製圖中針對多個特徵的過濾規格限

你好，
我希望你能幫助我。我對 JSL 還很陌生。我有以下問題：
我有一張這樣的桌子：
要素資料 USL
編號1 規格A
編號2 規格A
編號3 規格A
B號4 規格B
B號5規格B
B號6 規格B

應使用數據過濾器來選擇該功能。然後，資料應該顯示在控製圖中，特別是對於某個特徵。同時，當然，圖表中也應顯示每個功能的規格限制。
我怎樣才能將其放入腳本中？我僅設法在圖表中顯示針對一個功能的規格限制的數據。如果我在過濾器中選擇其他功能，則第一個規格限制將被保留。
解決方案可能很簡單，但我無法想出辦法。

感謝您的幫忙！

自動化和腳本品質與工藝工程回复：控製圖中已過濾的規格限制，包含多個功能

大多數時候，如果您希望在JMP中有規範限制，我建議拆分數據並使用列屬性。 還有一個原因為什麼您必須使用數據過濾器（如果使用拆分數據，則將使用列切換器）？

回覆：控製圖中多個功能的過濾規格限制

您應該考慮使用流程篩選平台。您可以將特徵指定為分組變數。

根據分組列而不同的流程規格限制 - JMP 使用者社區

回覆：控製圖中針對多個特徵的過濾規格限值

看看下面的腳本，

它會建立一個表，裡面是一個可以執行您想要的操作的腳本。

它將特徵分成幾列並設定 USL。

我和@jthi的想法一樣，在不同的欄位中擁有不同範圍（或規格）的資料會更容易。

New Table( "test-split",
	Add Rows( 9 ),
	New Script(
		"__split_usl",
		cdt = Current Data Table();
		Summarize( cdt, spec_lst = by( :Feature ), usl_lst = Mean( :USL ) );
		sdt = cdt << Data Table( "test-split" ) <<
		Split(
			Split By( :Feature ),
			Split( :data ),
			Remaining Columns( Drop All ),
			Sort by Column Property,
			Output table( "Split Table with USL" )
		);
		For( i = 1, i <= N Items( spec_lst ), i++,
			Eval(
				Eval Expr(
					Column( sdt, spec_lst[i] ) <<
					Set Property(
						"Spec Limits",
						{USL( Expr( usl_lst[i] ) ), Show Limits( 1 )}
					)
				)
			)
		);
	),
	New Column( "Feature",
		Character,
		"Nominal",
		Set Values( {"A", "A", "A", "B", "B", "B", "C", "C", "C"} )
	),
	New Column( "data",
		Numeric,
		"Continuous",
		Format( "Best", 12 ),
		Set Values( [1, 2, 3, 4, 5, 6, 7, 8, 9] )
	),
	New Column( "USL",
		Numeric,
		"Continuous",
		Format( "Best", 12 ),
		Set Selected,
		Set Values( [3, 3, 3, 6, 6, 6, 9, 9, 9] )
	)
);