357835_it-IT

liliconcom

Limite delle specifiche filtrate in un grafico di controllo per diverse funzionalità

Ciao,
Spero che puoi aiutarmi. Sono ancora molto nuovo su JSL. Ho il seguente problema:
Ho un tavolo come questo:
Dati sulle caratteristiche USL
Un numero1 Spec A
Un numero2 Spec A
Un numero3 Spec A
B numero4 Spec B
B numero 5 Spec B
B numero6 Spec B

La funzione dovrebbe essere selezionata con il filtro dati. Quindi i dati dovrebbero essere visualizzati in un grafico di controllo, soprattutto per una funzione. Allo stesso tempo, ovviamente, dovrebbe essere visualizzato anche il limite delle specifiche per ciascuna funzione nel grafico.
Come lo inserisco in uno script? Riesco a visualizzare solo i dati con il limite delle specifiche per una funzione nel grafico. Se seleziono l'altra funzione nel filtro, viene mantenuto il primo limite delle specifiche.
La soluzione è probabilmente banale, ma non riesco a capirla.

Grazie per l'aiuto!

ScriptingOggetto: Limite delle specifiche filtrate in un grafico di controllo per diverse funzionalità

Sono sicuro che Jim sarà in grado di aiutarti con una sceneggiatura, ma devo chiederti perché vuoi le specifiche. limiti su una carta di controllo? Spec. i limiti sono derivati (o stabiliti) indipendentemente dall'effettiva variabilità del processo. Confondere i limiti di controllo e le specifiche. i limiti renderanno più difficile capire cosa sta succedendo nel processo. Se si utilizza il grafico di tipo Shewhart, i grafici di controllo hanno lo scopo di comprendere la consistenza / stabilità della variazione all'interno del sottogruppo (grafico intervallo) e quindi confrontare l'interno con il mezzo (grafico Xbar). Stai tracciando medie e tipicamente specifiche. riguardano gli individui, non le medie. Specifiche. hanno lo scopo di stabilire i limiti di forma, adattamento e funzione. Se vuoi ottenere una stima della variabilità (Rbar / d2) e creare una distribuzione, puoi aggiungere le specifiche. alla distribuzione.

Oggetto: Limite delle specifiche filtrate in un grafico di controllo per diverse funzionalità

La maggior parte delle volte, se si desidera avere limiti di specifica in JMP, suggerirei di dividere i dati e utilizzare le proprietà della colonna. C'è anche un motivo per cui devi utilizzare il filtro dei dati (con i dati divisi utilizzeresti il selettore di colonne)?

Oggetto: Limite delle specifiche filtrate in un grafico di controllo per diverse funzionalità

Dai un'occhiata al seguente script,

crea una tabella e all'interno c'è uno script che può eseguire ciò che desideri.

Divide le caratteristiche in colonne e imposta l'USL.

 

Penso lo stesso di @jthi , avere dati con intervalli (o specifiche) diversi in colonne separate lo rende più semplice.

 

New Table( "test-split",
 Add Rows( 9 ),
 New Script(
  "__split_usl",
  cdt = Current Data Table();
  Summarize( cdt, spec_lst = by( :Feature ), usl_lst = Mean( :USL ) );
  sdt = cdt << Data Table( "test-split" ) <<
  Split(
   Split By( :Feature ),
   Split( :data ),
   Remaining Columns( Drop All ),
   Sort by Column Property,
   Output table( "Split Table with USL" )
  );
  For( i = 1, i <= N Items( spec_lst ), i++,
   Eval(
    Eval Expr(
     Column( sdt, spec_lst[i] ) <<
     Set Property(
      "Spec Limits",
      {USL( Expr( usl_lst[i] ) ), Show Limits( 1 )}
     )
    )
   )
  );
 ),
 New Column( "Feature",
  Character,
  "Nominal",
  Set Values( {"A", "A", "A", "B", "B", "B", "C", "C", "C"} )
 ),
 New Column( "data",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [1, 2, 3, 4, 5, 6, 7, 8, 9] )
 ),
 New Column( "USL",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Selected,
  Set Values( [3, 3, 3, 6, 6, 6, 9, 9, 9] )
 )
);