357554_es-ES

liliconcom

Realización de un "chi-plot" en JMP

Estoy intentando evaluar la independencia de algunas variables continuas en un conjunto de datos y me gustaría realizar lo que normalmente he visto denominado "chi-plot" de dos variables continuas.¿Existe una gráfica equivalente en JMP que se pueda utilizar?

AnalíticaGráficosRe: realizar un "chi-plot" en JMP

Primero, publique una imagen de la trama que desea.

 

En segundo lugar, consulte Análisis> Métodos multivariados> Multivariante para obtener una plataforma para explorar las relaciones con dos variables a la vez.

Re: realizar un "chi-plot" en JMP

Aquí hay un ejemplo de chi-plot ...

 

Este es un método para evaluar rápidamente si dos variables continuas son independientes.Si son independientes, se distribuirán aleatoriamente alrededor de 0.No he visto ningún método en la plataforma Multivariante de JMP que evalúe rápidamente el supuesto de independencia de dos variables continuas en el camino.¿Hay alguna forma en JMP de realizar este tipo de evaluación de la independencia de las variables?

 

 

Re: realizar un "chi-plot" en JMP

Por favor mira esto referencia . Este procedimiento no está disponible en JMP en este momento.

Re: realizar un "chi-plot" en JMP

Pobre de mí.¿Existe algún tipo de prueba equivalente de independencia sobre variables continuas que pueda realizar JMP?

Re: realizar un "chi-plot" en JMP

Hay varias formas de probar la multicolinealidad. Mark ya sugirió los Métodos multivariados> Multivariante. Cuando ejecuta esta plataforma, puede obtener coeficientes de correlación de Pearson (así como otros) y también valores atípicos de Mahalanobis y obtener buenos diagramas de dispersión. También puede obtener VIF de tablas de estimaciones de parámetros.

Re: Realización de un "chi-plot" en JMP

Usé esta referencia porque fue la única que encontré que incluía los detalles necesarios:

 

"Marchu, Victor AA, Francisco AR Rojas y Francisco Louzada,
"El Chi-Plot y su intervalo de confianza asintótico para analizar bivariantes
Dependencia: una aplicación a las tasas promedio de inteligencia y ateísmo
a través de los datos de las naciones ", Journal of Data Science 10 (2012), 711-722."

 

Escribí este guión y verifiqué las ecuaciones, pero los gráficos no me parecen correctos, así que no fui más lejos.

 

Names Default to Here( 1 );

// get data columns for Y and X roles
dt = Current Data Table();
If( Is Empty( dt ),
 Throw( "No data table open" );
);

dialog = New Window( "Chi-Plot", << Modal,
 H List Box(
  dt clb = Col List Box( All ),
  Line Up Box( N Col( 2 ),
   Button Box( "Y",
    item = dt clb << Get Selected;
    y clb << Append( item );
    If( N Items( x clb << Get Items ) > 0,
     ok bb << Enable( 1 ),
     ok bb << Enable( 0 )
    );
   ),
   y clb = Col List Box(
    Min Items( 1 ), Max Items( 1 ),
    << Set Analysis Type( Continuous )
   ),
   Button Box( "X",
    item = dt clb << Get Selected;
    x clb << Append( item );
    If( N Items( y clb << Get Items ) > 0,
     ok bb << Enable( 1 ),
     ok bb << Enable( 0 )
    );
   ),
   x clb = Col List Box(),
   Button Box( "Remove",
    y clb << Remove All;
    x clb << Remove All;
    ok bb << Enable( 0 );
   ),
   Text Box( "")
  )
 ),
 H List Box(
  ok bb = Button Box( "OK",
   y col = Column( (y clb << Get Items)[1] );
   x col = Column( (x clb << Get Items)[1] ),
   << Enable( 0 )
  ),
  Button Box( "Cancel")
 )
);

// unload dialog
If( dialog["Button"] == -1,
 Throw( "User cancelled" );
);

// utility to user alerts
alert# = Function( { msg },
 New Window( "Alert", << Modal,
  Text Box(
   "     " || msg || "     ",
          << Justify Text( "center" ),
          << Set Font Size( 12 )
  ),
  Text Box( " " )
 );
);

// sample size and scaling
n = N Row( dt );
scale = 1 / (n-1);

// data vectors
y = y col << Get As Matrix;
x = x col << Get As Matrix;

// cumulative indicators
F = G = H = J( n, 1, . );

// chi-plot coordinates
χ = λ = J( n, 1, . );

For Each Row(
 If( Not( Excluded( Row State() ) ),
  i = Row();
  // compute cumulative indicators for current row
  F[i] = scale * Summation( j = 1, n, If( j != i, x[j] <= x[i], 0 ) );
  G[i] = scale * Summation( j = 1, n, If( j != i, y[j] <= y[i], 0 ) );
  H[i] = scale * Summation( j = 1, n, If( j != i, x[j] <= x[i] & y[j] <= y[i], 0 ) );
  // computer chi-plot coordinates for current row
  χ[i] = (H[i] - (F[i] * G[i])) / Sqrt( F[i] * (1-F[i]) * G[i] * (1-G[i]) );
  sign = ((F[i]-0.5) * (G[i]-0.5));
  λ[i] = 4 * sign * Maximum( (F[i]-0.5)^2, (G[i]-0.5)^2 );
 );
);

// add coordinates to data table
χ col = dt << New Column( "χ", Numeric, Continuous, Values( χ ) );
λ col = dt << New Column( "λ", Numeric, Continuous, Values( λ ) );

// add table script for Chi-Plot
dt << New Script( "Chi-Plot",
 Current Data Table() << Graph Builder(
  Size( 600, 400 ),
  Show Control Panel( 0 ),
  Show Legend( 0 ),
  Variables( X( :λ ), Y( :χ ) ),
  Elements( Points( X, Y, Legend( 3 ) ) ),
  SendToReport(
   Dispatch(
    {},
    "λ",
    ScaleBox,
    {Min( -1 ), Max( 1 ), Inc( 0.2 ), Minor Ticks( 0 )}
   ),
   Dispatch(
    {},
    "χ",
    ScaleBox,
    {Min( -1 ), Max( 1 ), Inc( 0.2 ), Minor Ticks( 0 )}
   ),
   Dispatch( {}, "graph title", TextEditBox, {Set Text( "Chi-Plot" )} )
  )
 );
);

// launch Chi-Plot
gb = dt << Graph Builder(
 Size( 600, 400 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Variables( X( :λ ), Y( :χ ) ),
 Elements( Points( X, Y, Legend( 3 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "λ",
   ScaleBox,
   {Min( -1 ), Max( 1 ), Inc( 0.2 ), Minor Ticks( 0 )}
  ),
  Dispatch(
   {},
   "χ",
   ScaleBox,
   {Min( -1 ), Max( 1 ), Inc( 0.2 ), Minor Ticks( 0 )}
  ),
  Dispatch( {}, "graph title", TextEditBox, {Set Text( "Chi-Plot" )} )
 )
);