357554_zh-CN

liliconcom

在JMP中进行“ chi-plot”

我正在尝试评估数据集中某些连续变量的独立性，并希望执行我通常看到的两个连续变量的“ chi-plot”。JMP中是否可以使用等效图？

分析工具图形回复：在JMP中进行“ chi-plot”

首先，请张贴您想要的地块的图片。

 

其次，请参阅“分析”>“多变量方法”>“多变量”，该平台可一次探索与两个变量的关系。

回复：在JMP中进行“ chi-plot”

这是一个示例图...

 

这是一种快速评估两个连续变量是否独立的方法。如果它们是独立的，则它们将随机散布在0附近。在JMP的多变量平台中，我还没有看到任何可以快速评估两个连续变量的独立性假设的方法。JMP中是否有一种方法可以执行这种变量独立性评估？

 

 

回复：在JMP中进行“ chi-plot”

请看这个参考。 目前，此过程在JMP中不可用。

回复：在JMP中进行“ chi-plot”

唉。JMP可以对连续变量进行某种形式的独立性等效测试吗？

回复：在JMP中进行“ chi-plot”

有多种方法可以测试多重共线性。 马克已经建议使用“多元方法”>“多元”。 当您运行此平台时，您可以获取Pearson相关系数（以及其他系数）以及Mahalanobis异常值，并获得良好的散点图。 您还可以从参数估计表中获取VIF。

回复：在JMP中进行“ chi-plot”

我使用此参考是因为它是我发现的唯一包含必要细节的参考：

 

“ Marchu，Victor AA， 弗朗西斯科·AR·罗哈斯（Francisco AR Rojas）和弗朗西斯科·卢萨达（Francisco Louzada）
“用于分析双变量的Chi图及其渐近置信区间
依赖性：对平均智力和无神论率的应用
跨国家数据”，数据科学杂志10（2012），711-722。

 

我写了这个脚本并验证了等式，但是这些图对我而言并不正确，因此我没有做任何进一步的介绍。

 

Names Default to Here( 1 );

// get data columns for Y and X roles
dt = Current Data Table();
If( Is Empty( dt ),
 Throw( "No data table open" );
);

dialog = New Window( "Chi-Plot", << Modal,
 H List Box(
  dt clb = Col List Box( All ),
  Line Up Box( N Col( 2 ),
   Button Box( "Y",
    item = dt clb << Get Selected;
    y clb << Append( item );
    If( N Items( x clb << Get Items ) > 0,
     ok bb << Enable( 1 ),
     ok bb << Enable( 0 )
    );
   ),
   y clb = Col List Box(
    Min Items( 1 ), Max Items( 1 ),
    << Set Analysis Type( Continuous )
   ),
   Button Box( "X",
    item = dt clb << Get Selected;
    x clb << Append( item );
    If( N Items( y clb << Get Items ) > 0,
     ok bb << Enable( 1 ),
     ok bb << Enable( 0 )
    );
   ),
   x clb = Col List Box(),
   Button Box( "Remove",
    y clb << Remove All;
    x clb << Remove All;
    ok bb << Enable( 0 );
   ),
   Text Box( "")
  )
 ),
 H List Box(
  ok bb = Button Box( "OK",
   y col = Column( (y clb << Get Items)[1] );
   x col = Column( (x clb << Get Items)[1] ),
   << Enable( 0 )
  ),
  Button Box( "Cancel")
 )
);

// unload dialog
If( dialog["Button"] == -1,
 Throw( "User cancelled" );
);

// utility to user alerts
alert# = Function( { msg },
 New Window( "Alert", << Modal,
  Text Box(
   "     " || msg || "     ",
          << Justify Text( "center" ),
          << Set Font Size( 12 )
  ),
  Text Box( " " )
 );
);

// sample size and scaling
n = N Row( dt );
scale = 1 / (n-1);

// data vectors
y = y col << Get As Matrix;
x = x col << Get As Matrix;

// cumulative indicators
F = G = H = J( n, 1, . );

// chi-plot coordinates
χ = λ = J( n, 1, . );

For Each Row(
 If( Not( Excluded( Row State() ) ),
  i = Row();
  // compute cumulative indicators for current row
  F[i] = scale * Summation( j = 1, n, If( j != i, x[j] <= x[i], 0 ) );
  G[i] = scale * Summation( j = 1, n, If( j != i, y[j] <= y[i], 0 ) );
  H[i] = scale * Summation( j = 1, n, If( j != i, x[j] <= x[i] & y[j] <= y[i], 0 ) );
  // computer chi-plot coordinates for current row
  χ[i] = (H[i] - (F[i] * G[i])) / Sqrt( F[i] * (1-F[i]) * G[i] * (1-G[i]) );
  sign = ((F[i]-0.5) * (G[i]-0.5));
  λ[i] = 4 * sign * Maximum( (F[i]-0.5)^2, (G[i]-0.5)^2 );
 );
);

// add coordinates to data table
χ col = dt << New Column( "χ", Numeric, Continuous, Values( χ ) );
λ col = dt << New Column( "λ", Numeric, Continuous, Values( λ ) );

// add table script for Chi-Plot
dt << New Script( "Chi-Plot",
 Current Data Table() << Graph Builder(
  Size( 600, 400 ),
  Show Control Panel( 0 ),
  Show Legend( 0 ),
  Variables( X( :λ ), Y( :χ ) ),
  Elements( Points( X, Y, Legend( 3 ) ) ),
  SendToReport(
   Dispatch(
    {},
    "λ",
    ScaleBox,
    {Min( -1 ), Max( 1 ), Inc( 0.2 ), Minor Ticks( 0 )}
   ),
   Dispatch(
    {},
    "χ",
    ScaleBox,
    {Min( -1 ), Max( 1 ), Inc( 0.2 ), Minor Ticks( 0 )}
   ),
   Dispatch( {}, "graph title", TextEditBox, {Set Text( "Chi-Plot" )} )
  )
 );
);

// launch Chi-Plot
gb = dt << Graph Builder(
 Size( 600, 400 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Variables( X( :λ ), Y( :χ ) ),
 Elements( Points( X, Y, Legend( 3 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "λ",
   ScaleBox,
   {Min( -1 ), Max( 1 ), Inc( 0.2 ), Minor Ticks( 0 )}
  ),
  Dispatch(
   {},
   "χ",
   ScaleBox,
   {Min( -1 ), Max( 1 ), Inc( 0.2 ), Minor Ticks( 0 )}
  ),
  Dispatch( {}, "graph title", TextEditBox, {Set Text( "Chi-Plot" )} )
 )
);