357554_it-IT

liliconcom

Conduzione di un "chi-plot" in JMP

Sto tentando di valutare l'indipendenza di alcune variabili continue in un set di dati e vorrei eseguire quello che ho visto tipicamente denominato "chi-plot" di due variabili continue.Esiste un grafico equivalente in JMP che può essere utilizzato?

AnalyticsGraficaRi: Conduzione di un "chi-plot" in JMP

Per prima cosa, pubblica una foto della trama che desideri.

 

In secondo luogo, vedere Analisi> Metodi multivariati> Multivariata per una piattaforma per esplorare le relazioni con due variabili alla volta.

Ri: Conduzione di un "chi-plot" in JMP

Ecco un esempio di un chi-plot ...

 

Questo è un metodo per valutare rapidamente se due variabili continue sono indipendenti.Se sono indipendenti, si diffonderanno casualmente intorno a 0.Non ho visto alcun metodo nella piattaforma multivariata di JMP che valuterà rapidamente l'assunzione di indipendenza di due variabili continue nel modo.Esiste un modo in JMP per eseguire questo tipo di valutazione dell'indipendenza delle variabili?

 

 

Ri: Conduzione di un "chi-plot" in JMP

Si prega di vedere questo riferimento . Questa procedura non è attualmente disponibile in JMP.

Ri: Conduzione di un "chi-plot" in JMP

Ahimè.Esiste una sorta di test di indipendenza equivalente su variabili continue che JMP può eseguire?

Ri: Conduzione di un "chi-plot" in JMP

Esistono diversi modi per verificare la multicollinearità. Mark ha già suggerito Metodi multivariati> Multivariata. Quando esegui questa piattaforma puoi ottenere coefficienti di correlazione di Pearson (così come altri) e anche valori anomali di Mahalanobis e ottenere bei grafici a dispersione. È inoltre possibile ottenere VIF dalle tabelle delle stime dei parametri.

Ri: Conduzione di un "chi-plot" in JMP

Ho usato questo riferimento perché era l'unico che ho trovato che includeva i dettagli necessari:

 

"Marchu, Victor AA, Francisco AR Rojas e Francisco Louzada,
"Il diagramma del chi e il suo intervallo di confidenza asintotico per l'analisi dei bivariati
Dipendenza: un'applicazione per i tassi medi di intelligenza e ateismo
across Nations Data ", Journal of Data Science 10 (2012), 711-722."

 

Ho scritto questo script e verificato le equazioni, ma i grafici non mi sembrano giusti, quindi non sono andato oltre.

 

Names Default to Here( 1 );

// get data columns for Y and X roles
dt = Current Data Table();
If( Is Empty( dt ),
 Throw( "No data table open" );
);

dialog = New Window( "Chi-Plot", << Modal,
 H List Box(
  dt clb = Col List Box( All ),
  Line Up Box( N Col( 2 ),
   Button Box( "Y",
    item = dt clb << Get Selected;
    y clb << Append( item );
    If( N Items( x clb << Get Items ) > 0,
     ok bb << Enable( 1 ),
     ok bb << Enable( 0 )
    );
   ),
   y clb = Col List Box(
    Min Items( 1 ), Max Items( 1 ),
    << Set Analysis Type( Continuous )
   ),
   Button Box( "X",
    item = dt clb << Get Selected;
    x clb << Append( item );
    If( N Items( y clb << Get Items ) > 0,
     ok bb << Enable( 1 ),
     ok bb << Enable( 0 )
    );
   ),
   x clb = Col List Box(),
   Button Box( "Remove",
    y clb << Remove All;
    x clb << Remove All;
    ok bb << Enable( 0 );
   ),
   Text Box( "")
  )
 ),
 H List Box(
  ok bb = Button Box( "OK",
   y col = Column( (y clb << Get Items)[1] );
   x col = Column( (x clb << Get Items)[1] ),
   << Enable( 0 )
  ),
  Button Box( "Cancel")
 )
);

// unload dialog
If( dialog["Button"] == -1,
 Throw( "User cancelled" );
);

// utility to user alerts
alert# = Function( { msg },
 New Window( "Alert", << Modal,
  Text Box(
   "     " || msg || "     ",
          << Justify Text( "center" ),
          << Set Font Size( 12 )
  ),
  Text Box( " " )
 );
);

// sample size and scaling
n = N Row( dt );
scale = 1 / (n-1);

// data vectors
y = y col << Get As Matrix;
x = x col << Get As Matrix;

// cumulative indicators
F = G = H = J( n, 1, . );

// chi-plot coordinates
χ = λ = J( n, 1, . );

For Each Row(
 If( Not( Excluded( Row State() ) ),
  i = Row();
  // compute cumulative indicators for current row
  F[i] = scale * Summation( j = 1, n, If( j != i, x[j] <= x[i], 0 ) );
  G[i] = scale * Summation( j = 1, n, If( j != i, y[j] <= y[i], 0 ) );
  H[i] = scale * Summation( j = 1, n, If( j != i, x[j] <= x[i] & y[j] <= y[i], 0 ) );
  // computer chi-plot coordinates for current row
  χ[i] = (H[i] - (F[i] * G[i])) / Sqrt( F[i] * (1-F[i]) * G[i] * (1-G[i]) );
  sign = ((F[i]-0.5) * (G[i]-0.5));
  λ[i] = 4 * sign * Maximum( (F[i]-0.5)^2, (G[i]-0.5)^2 );
 );
);

// add coordinates to data table
χ col = dt << New Column( "χ", Numeric, Continuous, Values( χ ) );
λ col = dt << New Column( "λ", Numeric, Continuous, Values( λ ) );

// add table script for Chi-Plot
dt << New Script( "Chi-Plot",
 Current Data Table() << Graph Builder(
  Size( 600, 400 ),
  Show Control Panel( 0 ),
  Show Legend( 0 ),
  Variables( X( :λ ), Y( :χ ) ),
  Elements( Points( X, Y, Legend( 3 ) ) ),
  SendToReport(
   Dispatch(
    {},
    "λ",
    ScaleBox,
    {Min( -1 ), Max( 1 ), Inc( 0.2 ), Minor Ticks( 0 )}
   ),
   Dispatch(
    {},
    "χ",
    ScaleBox,
    {Min( -1 ), Max( 1 ), Inc( 0.2 ), Minor Ticks( 0 )}
   ),
   Dispatch( {}, "graph title", TextEditBox, {Set Text( "Chi-Plot" )} )
  )
 );
);

// launch Chi-Plot
gb = dt << Graph Builder(
 Size( 600, 400 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Variables( X( :λ ), Y( :χ ) ),
 Elements( Points( X, Y, Legend( 3 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "λ",
   ScaleBox,
   {Min( -1 ), Max( 1 ), Inc( 0.2 ), Minor Ticks( 0 )}
  ),
  Dispatch(
   {},
   "χ",
   ScaleBox,
   {Min( -1 ), Max( 1 ), Inc( 0.2 ), Minor Ticks( 0 )}
  ),
  Dispatch( {}, "graph title", TextEditBox, {Set Text( "Chi-Plot" )} )
 )
);