How do I automate random sampling generation from different distribution types?

Djtjhin

Let's say I have a table with 5 rows & 2 columns. The first column is for distribution types (e.g. Normal, Lognormal, Weibull, etc) and the second column is for the respective parameters. I'd like to make a for loop which will create a new data table for each of the 5 rows, where in that new data table, a new column will be added with a random sampling function based on the parameters of the row. 

e.g. row 1 --> Normal, (0.1,0.02); Create a new data table with a column that has a formula of 

randomnormal(0.1,0.02)

My current challenge is that different distribution types require varying number of parameters. Appreciate some insights on how I should approach this.

temp.JPG

txnelson

Here is a simple example of how to do what you requested

Names Default To Here( 1 );
dt = New Table( "Sample",
	Add Rows( 5 ),
	New Column( "Types",
		Character,
		Set Values(
			{"Normal", "Lognormal", "Weibull", "Uniform", "Johnson Su"}
		),
		Set Display Width( 79 )
	),
	New Column( "Parameters",
		Character,
		Set Values(
			{"(0.1,0.02)", "(0.2,.005)", "(0.3,0.005)", "(0.1,0.5)",
			"(0.5, 1, 1, 1)"}
		),
		Set Display Width( 101 )
	)
);

For( i = 1, i <= N Rows( dt ), i++,
	Eval(
		Substitute(
				Expr(
					New Table( dt:Types[i],
						add rows( 20 ),
						New Column( "Random " || dt:Types[i],
							set each value( __formula__ )
						)
					)
				),
			Expr( __formula__ ),
				Parse( "Random " || dt:Types[i] || dt:Parameters[i] )
		)
	)
);

Please take the time to fully understand how the script works, and if you do not understand it, please respond back so the Community can provide you with the additional information you may need.