356131_fr-FR

liliconcom

Besoin d'aide pour convertir un format de date de caractère en numérique dans JMP 15

Salut,

 

Ma feuille Excel a le format de date suivant : mercredi 18 novembre 2020, 12:45:00. Lors de l'importation dans JMP 15, il est lu comme un caractère.

• Pouvez-vous s'il vous plaît partager une méthode pour convertir la date de son format de caractères en un format numérique continu (par exemple, aaaa-mm-jj hh:mm) ? J'ai joint un fichier JMP pour votre référence.
• Existe-t-il un moyen d'appliquer le format de date correct (numérique) lors de l'importation ?

Merci d'avance.

Tableau de donnéesRe : Besoin d'aide pour convertir un format de date de caractère en numérique dans JMP 15

Voici une autre possibilité utilisant regex, probablement l'implémentation la plus courte serait la version 2 ci-dessous, en utilisant en plus informat() dans une formule. Une fois que vous avez lu les informations de la chaîne de date, il existe de nombreuses façons de les convertir en une date numérique.

Si vous avez la date sous forme numérique dans Excel, il serait préférable de changer de format dans Excel pour que JMP puisse lire.

regex est génial, j'adore ça!

 

Names Default To Here( 1 );

// AA for conversion of month
month_AA = Associative Array(
 {"January", "February", "March", "April", "May", "June", "July", "August", "September", "October", "November", "December"},
 {"01", "02", "03", "04", "05", "06", "07", "08", "09", "10", "11", "12"}
);

date_str = "Wednesday, November 18, 2020, 12:45:00 PM";
date_str = "Friday, November 20, 2020, 8:10:00 AM";
regex_str = "(\w+), (\w+) (\d+), (\d+), (\d+):(\d+):(\d+) (PM|AM)";

// 1st version generating a list and building string thereof 
date_component_lst = Regex Match( date_str, regex_str );
date_component_lst[6] = char(num(date_component_lst[6]) + match(date_component_lst[9], "AM", 0, "PM", 12));
date_str1 = date_component_lst[5] || "-" || month_AA[date_component_lst[3]] || "-" || date_component_lst[4] || "T" || date_component_lst[6] || ":"
 || date_component_lst[7] || ":" || date_component_lst[8];

// 2nd version generating a string, to be used by "Parse Date ()" do directly convert it into a date
date_str2 = Regex( date_str, regex_str, "\3 \2 \4 \5:\6:\7 \8" );

Re : Besoin d'aide pour convertir un format de date de caractère en numérique dans JMP 15

Voici une méthode de force brute pour obtenir ce que vous voulez.J'ai joint le tableau de données complet.

If( Row() == 1,
 monthList = {"January", "February", "March", "April", "May", "June", "July", "August", "September", "October", "November",
 "December"}
);
myDate = Date MDY(
 Contains( monthList, Word( 2, :Name( "Current Date Format (character)" ), ", " ) ),
 Num( Word( 3, :Name( "Current Date Format (character)" ), ", " ) ),
 Num( Word( 4, :Name( "Current Date Format (character)" ), ", " ) )
);
If(
 Word( -1, :Name( "Current Date Format (character)" ), ", " ) == "PM" & Num(
  Word( 5, :Name( "Current Date Format (character)" ), ",: " )
 ) < 12,
 myDate = myDate + Num( Word( 5, :Name( "Current Date Format (character)" ), ",: " ) ) * 3600 + 3600 * 12,
 myDate = myDate + Num( Word( 5, :Name( "Current Date Format (character)" ), ",: " ) ) * 3600
);
myDate = myDate + Num( Word( 6, :Name( "Current Date Format (character)" ), ",: " ) ) * 60 + Num(
 Word( 7, :Name( "Current Date Format (character)" ), ",: " )
);