354331_es-ES

liliconcom

script para agregar dos columnas

Estoy intentando agregar dos columnas.

dos de la columna tienen nombre abcd y efgh

La siguiente línea funciona:

dt_tab << New Column( newcolumn, formula( :name( "abcd" ) + :name( "efgh" ) ) );

pero el siguiente código arroja un error

name1 = "abcd";
name2 ="efgh";

dt_tab << New Column( name1 || "3", formula(:name(name1) + :name(name2)));

¿Por qué el segundo método no funciona?

Automatización y secuencias de comandosRe: secuencia de comandos para agregar dos columnas

La razón por la que esto no funciona es que ni la función: Name () ni el elemento Formula () no analizan el contenido de la función antes de la ejecución.Necesita crear el JSL exacto antes de la ejecución

name1 = "abcd";
name2 = "efgh";

Eval(
 Substitute(
   Expr(
    dt_tab << New Column( name1 || "3",
     formula( Column( __name1__ ) ) + Column( __name2__ )
    )
   ),
  Expr( __name1__ ), name1,
  Expr( __name2__ ), name2
 )
);

 

Re: script para agregar dos columnas

Mi error... Había colocado un ")" mal y debería haber utilizado la función As Column(), no la función Column()

Names Default To Here( 1 );
dt_tab = New Table( "Example",
	Add Rows( 4 ),
	New Column( "abcd", 

		Numeric,
		"Continuous",
		Format( "Best", 12 ),
		Set Values( [1, 2, 3, 4] )
	),
	New Column( "efgh",
		Numeric,
		"Continuous",
		Format( "Best", 12 ),
		Set Values( [5, 6, 7, 8] )
	)
);

name1 = "abcd";
name2 = "efgh";

Eval(
	Substitute(
			Expr(
				dt_tab <<
				New Column( name1 || "3",
					formula(
						As Column( __name1__ )
						+As Column( __name2__ )
					)
				)
			),
		Expr( __name1__ ), name1,
		Expr( __name2__ ), name2
	)
);