354331_it-IT

liliconcom

script per aggiungere due colonne

sto cercando di aggiungere due colonne.

due colonne hanno il nome abcd e efgh

funziona la seguente linea:

dt_tab << New Column( newcolumn, formula( :name( "abcd" ) + :name( "efgh" ) ) );

ma il codice seguente genera un errore

name1 = "abcd";
name2 ="efgh";

dt_tab << New Column( name1 || "3", formula(:name(name1) + :name(name2)));

perché il 2° metodo non funziona?

Automazione e scriptingRi: script per aggiungere due colonne

Il motivo per cui questo non funziona è che né la funzione: Name () né l'elemento Formula () non analizzano il contenuto della funzione prima dell'esecuzione.È necessario creare il JSL esatto prima dell'esecuzione

name1 = "abcd";
name2 = "efgh";

Eval(
 Substitute(
   Expr(
    dt_tab << New Column( name1 || "3",
     formula( Column( __name1__ ) ) + Column( __name2__ )
    )
   ),
  Expr( __name1__ ), name1,
  Expr( __name2__ ), name2
 )
);

 

Re: script per aggiungere due colonne

Il mio errore... avevo inserito male un ")" e avrei dovuto usare la funzione As Column(), non la funzione Column()

Names Default To Here( 1 );
dt_tab = New Table( "Example",
	Add Rows( 4 ),
	New Column( "abcd", 

		Numeric,
		"Continuous",
		Format( "Best", 12 ),
		Set Values( [1, 2, 3, 4] )
	),
	New Column( "efgh",
		Numeric,
		"Continuous",
		Format( "Best", 12 ),
		Set Values( [5, 6, 7, 8] )
	)
);

name1 = "abcd";
name2 = "efgh";

Eval(
	Substitute(
			Expr(
				dt_tab <<
				New Column( name1 || "3",
					formula(
						As Column( __name1__ )
						+As Column( __name2__ )
					)
				)
			),
		Expr( __name1__ ), name1,
		Expr( __name2__ ), name2
	)
);