353271_zh-TW

liliconcom

更改分發的匯總統計格式 - JSL

嗨，我認為這應該是一個快速的方法，但我堅持下去：如何立即更改分佈報告的所有摘要統計的格式？

 

按照我的意願進行格式化後，自動生成的腳本顯示為發行版的每個條目單獨更改它，如下所示：

 SendToReport(
  Dispatch(
   {},
   "Distributions",
   OutlineBox,
   {Set Title( "Summary Data Distribution" )}
  ),
  Dispatch(
   {"20 Hz (dB re: 1 kHz)"},
   "1",
   ScaleBox,
   {Min( -10 ), Max( -1 ), Inc( 0.1 ), Minor Ticks( 1 )}
  ),

但我想立即將其應用於所有這些，以顯著減少代碼。我嘗試向報告發送設定的格式和其他一些內容，但沒有成功。

 

謝謝！

 

時間

大規模定制回复：更改分發的匯總統計格式 - JSL

完美，這效果很好，而且看起來這在其他情況下可能會很有用！非常感謝。

 

托德

回复：更改分發的匯總統計格式 - JSL

稍微擴展一下@馬克貝利的解決方案，將最後一行更改為此會將此格式僅應用於名為“摘要統計”的輪廓框中的項目：

 

(dist rep << XPath("//OutlineBox[text()='Summary Statistics']//NumberColBox")) << Set Format( "Fixed Dec", 15, 8 );

回复：更改分發的匯總統計格式 - JSL

嘗試這個替代方案。

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dist = dt << Distribution( Y( :weight ) );

dist rep = dist << Report;

(dist rep << XPath("//NumberColBox")) << Set Format( "Fixed Dec", 15, 8 );

請注意，這個簡單的腳本假設每個數字列框都應該更改。

回复：更改分發的匯總統計格式 - JSL

在這裡您可以看到我使用以下內容自定義了摘要統計信息：

SummaryDist << Customize Summary Statistics( 
 Std Err Mean( 0 ),
 Upper Mean Confidence Interval( 0 ),
 Lower Mean Confidence Interval( 0 ),
 Minimum( 1 ),
 Maximum( 1 ),
 Trimmed Mean( 1 )
);

然後我使用您的代碼將 20 Hz Y 數據列更改為小數點後兩位：

SummaryDistRep["SummaryStatistics"][NumberColBox(1)] << Set Format("Fixed Dec", 15,2);

但 20 kHz 和靈敏度的其餘 y 列的格式尚未更改。

回复：更改分發的匯總統計格式 - JSL

嘿馬克，

 

如果我最初的問題不清楚，我深表歉意。我還意識到我沒有復制原始帖子中代碼的重要部分。

 

您提供的代碼片段適用於單個 Y 列，但我想要做的是使用一行代碼而不是多行代碼來更改發行版中包含的所有 Y 列的格式。因此，基本上，我不想指定“NumberColBox(X)”來更改第 X Y 列，而是只想指定“NumberColBox”之類的內容來更改所有 Y 列。

 

這更有意義嗎？

回复：更改分發的匯總統計格式 - JSL

這裡的最後一行可能是您正在尋找的內容：

 

Names default to here(1);

dt = Open("$Sample_Data/iris.jmp");

dist = dt << Distribution(
 Continuous Distribution( Column( :Sepal length ) ),
 Continuous Distribution( Column( :Sepal width ) ),
 Continuous Distribution( Column( :Petal length ) ),
 Continuous Distribution( Column( :Petal width ) ),
 Nominal Distribution( Column( :Species ) )
);

//use this to help create XPath queries
dist << Get XML; 

//rename some outline boxes
(dist << XPath("//OutlineBox[@helpKey='Distrib Freq']")) << Set title("Freq");
(dist << XPath("//OutlineBox[@helpKey='Distrib Quantiles']")) << Set title("Quant");

//Find all scale boxes from continuous distributions and change the scales
(dist << XPath("//OutlineBox[@helpKey='DistribC']//ScaleBox[@ID='1']")) << {Min( 0 ), Max( 8 ), Inc( 0.5 ), Minor Ticks( 0 )};

回复：更改分發的匯總統計格式 - JSL

我不確定我是否真的理解這個請求，但就這樣吧。

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dist = dt << Distribution( Y( :weight ) );

dist rep = dist << Report;

dist rep["Summary Statistics"][NumberColBox(1)] << Set Format( "Fixed Dec", 15, 8 );