353271_ja-JP

liliconcom

要約統計量の分布形式の変更 - JSL

こんにちは、これは簡単なことだと思いますが、行き詰まっています。分布レポートのすべての概要統計の形式を一度に変更するにはどうすればよいですか?

 

希望どおりにフォーマットした後、自動生成されたスクリプトは、次のようにディストリビューションのすべてのエントリに対して個別に変更することを示します。

 SendToReport(
  Dispatch(
   {},
   "Distributions",
   OutlineBox,
   {Set Title( "Summary Data Distribution" )}
  ),
  Dispatch(
   {"20 Hz (dB re: 1 kHz)"},
   "1",
   ScaleBox,
   {Min( -10 ), Max( -1 ), Inc( 0.1 ), Minor Ticks( 1 )}
  ),

ただし、コードを大幅に削減するために、一度にすべてに適用したいと考えています。設定された形式をレポートに送信したり、その他いくつかのことを試してみましたが、どれも機能しませんでした。

 

ありがとう！

 

T

マスカスタマイゼーションRe: 要約統計量の分布形式の変更について - JSL

完璧です。これはうまく機能し、他のインスタンスでも役に立ちそうです。どうもありがとう。

 

トッド

Re: 要約統計量の分布形式の変更について - JSL

少しだけ拡大すると@Mark_Baileyの解決策として、最後の行をこれに変更すると、この書式設定は「概要統計」と呼ばれるアウトライン ボックス内の項目にのみ適用されます。

 

(dist rep << XPath("//OutlineBox[text()='Summary Statistics']//NumberColBox")) << Set Format( "Fixed Dec", 15, 8 );

Re: 要約統計量の分布形式の変更について - JSL

この代替案を試してください。

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dist = dt << Distribution( Y( :weight ) );

dist rep = dist << Report;

(dist rep << XPath("//NumberColBox")) << Set Format( "Fixed Dec", 15, 8 );

この単純なスクリプトは、すべての数値列ボックスを変更する必要があることを前提としていることに注意してください。

Re: 要約統計量の分布形式の変更について - JSL

ここでは、以下を使用して要約統計をカスタマイズしたことがわかります。

SummaryDist << Customize Summary Statistics( 
 Std Err Mean( 0 ),
 Upper Mean Confidence Interval( 0 ),
 Lower Mean Confidence Interval( 0 ),
 Minimum( 1 ),
 Maximum( 1 ),
 Trimmed Mean( 1 )
);

次に、コードを使用して、データの 20 Hz Y 列を小数点以下 2 桁に変更しました。

SummaryDistRep["SummaryStatistics"][NumberColBox(1)] << Set Format("Fixed Dec", 15,2);

ただし、20 kHz と感度の残りの y 列の形式は変更されていません。

Re: 要約統計量の分布形式の変更について - JSL

やあ、マーク、

 

私の最初の質問が明確でなかったら申し訳ありません。元の投稿のコードの重要な部分をコピーしていないことにも気づきました。

 

あなたが提供したコードスニペットは単一の Y 列に対してはうまく機能しますが、私がやりたかったのは、ディストリビューションに含まれるすべての Y 列の形式を、複数行ではなく 1 行のコードで変更することでした。したがって、基本的に「NumberColBox(X)」を指定して X 番目の Y 列を変更するのではなく、「NumberColBox」のようなものを指定してすべての Y 列を変更したいと思います。

 

それはもっと意味があるでしょうか？

Re: 要約統計量の分布形式の変更について - JSL

ここの最後の行があなたが探しているものかもしれません:

 

Names default to here(1);

dt = Open("$Sample_Data/iris.jmp");

dist = dt << Distribution(
 Continuous Distribution( Column( :Sepal length ) ),
 Continuous Distribution( Column( :Sepal width ) ),
 Continuous Distribution( Column( :Petal length ) ),
 Continuous Distribution( Column( :Petal width ) ),
 Nominal Distribution( Column( :Species ) )
);

//use this to help create XPath queries
dist << Get XML; 

//rename some outline boxes
(dist << XPath("//OutlineBox[@helpKey='Distrib Freq']")) << Set title("Freq");
(dist << XPath("//OutlineBox[@helpKey='Distrib Quantiles']")) << Set title("Quant");

//Find all scale boxes from continuous distributions and change the scales
(dist << XPath("//OutlineBox[@helpKey='DistribC']//ScaleBox[@ID='1']")) << {Min( 0 ), Max( 8 ), Inc( 0.5 ), Minor Ticks( 0 )};

Re: 要約統計量の分布形式の変更について - JSL

このリクエストを本当に理解しているかどうかはわかりませんが、ここで説明します。

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dist = dt << Distribution( Y( :weight ) );

dist rep = dist << Report;

dist rep["Summary Statistics"][NumberColBox(1)] << Set Format( "Fixed Dec", 15, 8 );