353122_es-ES

liliconcom

seleccionar partes fuera de límites

Tengo varias columnas para las que he establecido límites. ¿Cómo puedo seleccionar las filas que están fuera de los límites?

AnalíticaTabla de datosRe: seleccionar partes fuera de límites

Supongo que desea hacer esta selección usando un script.  

Aquí hay un script para seleccionar filas en función de las filas fuera de los límites de especificación para una variable

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

specs = dt:PNP1 << get property("spec limits");

dt << select where( dt:PNP1 <= specs["LSL"] | dt:PNP1 >= specs["USL"]);

Aquí hay un script para múltiples columnas.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

//colNames = dt << get column names( continuous, string );
colNames = { "PNP1", "PNP3"};

For( i = 1, i <= N Items( colNames ), i++,
 specs = Column( dt, colNames[i] ) << get property( "spec limits" );
 If( Try( Is Missing( specs["LSL"] ) ) == 0 & Try( Is Missing( specs["USL"] ) ) == 0,
  found = dt << get rows where(
   as Column( dt, colNames[i] ) <= specs["LSL"] | as Column( dt, colNames[i] ) >= specs["USL"]
  );
  If( N Rows( found ) > 0,
   dt << select rows(found);
  );
 );
);

Re: seleccionar partes fuera de límites

También puede lograr esto a través de la plataforma Process Capability.

dt=Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
Process Capability(
 Process Variables( :NPN1, :PNP1, :PNP2 ),
 Moving Range Method( Average of Moving Ranges ),
 Overall Sigma Normalized Box Plots( 1 ),
 Select Out of Spec Values( 1 ),
 Goal Plot( 1 ),
 Capability Index Plot( 1 ),
 Process Performance Plot( 0 )
);

Re: seleccionar partes fuera de límitesGracias. Esto funciona. ¿Hay alguna forma manual en lugar de un script? Si ya seleccioné varias columnas y tracé la distribución, ¿hay alguna forma manual de seleccionar las partes defectuosas?