353122_it-IT

liliconcom

selezionare le parti fuori dai limiti

Ho più colonne per le quali ho impostato dei limiti. Come posso selezionare le righe fuori dai limiti?

AnalyticsTabella datiRi: seleziona parti fuori dai limiti

Suppongo che tu voglia fare questa selezione usando uno script.  

Ecco uno script per selezionare le righe in base alle righe al di fuori dei limiti delle specifiche per una variabile

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

specs = dt:PNP1 << get property("spec limits");

dt << select where( dt:PNP1 <= specs["LSL"] | dt:PNP1 >= specs["USL"]);

Ecco lo script per più colonne

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

//colNames = dt << get column names( continuous, string );
colNames = { "PNP1", "PNP3"};

For( i = 1, i <= N Items( colNames ), i++,
 specs = Column( dt, colNames[i] ) << get property( "spec limits" );
 If( Try( Is Missing( specs["LSL"] ) ) == 0 & Try( Is Missing( specs["USL"] ) ) == 0,
  found = dt << get rows where(
   as Column( dt, colNames[i] ) <= specs["LSL"] | as Column( dt, colNames[i] ) >= specs["USL"]
  );
  If( N Rows( found ) > 0,
   dt << select rows(found);
  );
 );
);

Ri: seleziona parti fuori dai limiti

Puoi anche farlo tramite la piattaforma Process Capability.

dt=Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
Process Capability(
 Process Variables( :NPN1, :PNP1, :PNP2 ),
 Moving Range Method( Average of Moving Ranges ),
 Overall Sigma Normalized Box Plots( 1 ),
 Select Out of Spec Values( 1 ),
 Goal Plot( 1 ),
 Capability Index Plot( 1 ),
 Process Performance Plot( 0 )
);

Ri: seleziona parti fuori dai limitiGrazie. Funziona. Esiste un modo manuale invece dello script? se ho già selezionato più colonne e tracciato la distribuzione, esiste un modo manuale per selezionare le parti difettose?