353122_de-DE

liliconcom

Teile außerhalb der Grenzen auswählen

Ich habe mehrere Spalten, für die ich Grenzen gesetzt habe. Wie kann ich die Zeilen auswählen, die außerhalb der Grenzen liegen?

AnalytikDatentabelleBetreff: Teile außerhalb der Grenzen auswählen

Ich gehe davon aus, dass Sie diese Auswahl mit einem Skript treffen möchten.  

Hier ist ein Skript zum Auswählen von Zeilen basierend auf den Zeilen außerhalb der Spezifikationsgrenzen für eine Variable

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

specs = dt:PNP1 << get property("spec limits");

dt << select where( dt:PNP1 <= specs["LSL"] | dt:PNP1 >= specs["USL"]);

Hier ist ein Skript für mehrere Spalten

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

//colNames = dt << get column names( continuous, string );
colNames = { "PNP1", "PNP3"};

For( i = 1, i <= N Items( colNames ), i++,
 specs = Column( dt, colNames[i] ) << get property( "spec limits" );
 If( Try( Is Missing( specs["LSL"] ) ) == 0 & Try( Is Missing( specs["USL"] ) ) == 0,
  found = dt << get rows where(
   as Column( dt, colNames[i] ) <= specs["LSL"] | as Column( dt, colNames[i] ) >= specs["USL"]
  );
  If( N Rows( found ) > 0,
   dt << select rows(found);
  );
 );
);

Betreff: Teile außerhalb der Grenzen auswählen

Sie können dies auch über die Process Capability-Plattform erreichen.

dt=Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
Process Capability(
 Process Variables( :NPN1, :PNP1, :PNP2 ),
 Moving Range Method( Average of Moving Ranges ),
 Overall Sigma Normalized Box Plots( 1 ),
 Select Out of Spec Values( 1 ),
 Goal Plot( 1 ),
 Capability Index Plot( 1 ),
 Process Performance Plot( 0 )
);

Betreff: Teile außerhalb der Grenzen auswählenDankeschön. Das funktioniert. Gibt es einen manuellen Weg anstelle eines Skripts? Wenn ich bereits mehrere Spalten ausgewählt und die Verteilung geplottet habe, gibt es eine manuelle Möglichkeit, fehlerhafte Teile auszuwählen?