353122_zh-TW

liliconcom

選擇超出限制的零件

我有多個已設置限制的列。 如何選擇超出限制的行？

分析工具數據表回复：選擇超出限制的零件

我假設您想使用腳本進行此選擇。  

這是一個腳本，用於基於一個變量的規範限制之外的行來選擇行

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

specs = dt:PNP1 << get property("spec limits");

dt << select where( dt:PNP1 <= specs["LSL"] | dt:PNP1 >= specs["USL"]);

這是多列的腳本

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

//colNames = dt << get column names( continuous, string );
colNames = { "PNP1", "PNP3"};

For( i = 1, i <= N Items( colNames ), i++,
 specs = Column( dt, colNames[i] ) << get property( "spec limits" );
 If( Try( Is Missing( specs["LSL"] ) ) == 0 & Try( Is Missing( specs["USL"] ) ) == 0,
  found = dt << get rows where(
   as Column( dt, colNames[i] ) <= specs["LSL"] | as Column( dt, colNames[i] ) >= specs["USL"]
  );
  If( N Rows( found ) > 0,
   dt << select rows(found);
  );
 );
);

回复：選擇超出限制的零件

您也可以通過Process Capability平台完成此任務。

dt=Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
Process Capability(
 Process Variables( :NPN1, :PNP1, :PNP2 ),
 Moving Range Method( Average of Moving Ranges ),
 Overall Sigma Normalized Box Plots( 1 ),
 Select Out of Spec Values( 1 ),
 Goal Plot( 1 ),
 Capability Index Plot( 1 ),
 Process Performance Plot( 0 )
);

回复：選擇超出限制的零件謝謝。 這可行。 有什麼手動方法代替腳本嗎？如果我已經選擇了多列並繪製了分佈圖，是否有任何手動方法來選擇失效零件？