349351_ja-JP

liliconcom

レポートとして保存MyReport.jrpでラインナップボックスが消える

3つのタブを持つウィンドウを作成するスクリプトがあります。最初のタブには、2つの列とループで作成された6つのグラフビルダーグラフを含むラインナップボックスがあります。

nw = New Window( "Win1", tbox = Tab Box(Tab Page Box("Age", vlb = Lineup Box( N Col( 2 )) )) );

ループによって生成されたすべてのグラフには、次のものが追加されます。

vlb << Append(   
    Graph Builder("graph stuff here");

最後に、すべてが期待どおりに行ごとに2つのグラフ（2つの列）に見えます。

しかし、それを「レポート」（埋め込みテーブル付き）として保存すると、ラインナップボックスがコードから消えます！

そして私は得る：

New Window( "Win1",
 Tab Box(
  Tab Page Box(
   "Age",
   Graph Builder("graph stuff here");

2列のグラフの元の配置を保持する方法はありますか？ これは財産ですか、それとも財産の欠如ですか私が使用している「ボックス」のタイプの？

いくつかの提案をお試しいただければ幸いです。

 

 

グラフィックススクリプティングRe：レポートとして保存MyReport.jrpでラインナップボックスが消える

これはバグだと思います。これをに送信することを検討してください。 support@jmp.com 。レポートとして保存せずに、[スクリプトの保存]> [スクリプトウィンドウ（すべてのオブジェクト）]を選択すると、ラインナップボックスの代わりにタブボックスも表示されることに注意してください。

 

当面の間、回避策は、レポートファイルの代わりにスクリプトファイルを配布することかもしれません。データテーブルで、列リストの上にある赤い三角形からコピーテーブルスクリプトを選択し、それをスクリプトに貼り付けることができます。'//！'を含めるスクリプトの最初の行で自動的に実行され、それを.jslファイルとして保存します（ファイルサイズはjrpファイルである必要があり、どちらもテーブルをテキストとして保存します）。

 

レポートのように機能させるには、テーブルを非表示または非公開として開き、ウィンドウが閉じたときに自動的に閉じることができます。

 

次に例を示します。これを.jslファイルとして保存します。

//!
Names default to here(1);

dt = New Table( "Subset of Big Class 2",
 Add Rows( 18 ),
 New Column(
  ["en" => "age", "ja" => "年齢", "x-id" => "S_age_Col", "zh-CN" => "年龄"],
  Numeric, "Ordinal", Format( "Fixed Dec", 5, 0 ),
  Set Values(
   [12, 12, 12, 13, 13, 13, 14, 14, 14, 15, 15, 15, 16, 16, 16, 17, 17, 17]
  ),
  Set Display Width( 0 )
 ),
 New Column(
  ["en" => "height",
  "ja" => "身長(インチ)",
  "x-id" => "S_height_Col",
  "zh-CN" => "身高"],
  Numeric, "Continuous", Format( "Fixed Dec", 5, 0 ),
  Set Values(
   [61, 66, 51, 61, 65, 58, 63, 63, 64, 62, 64, 67, 65, 60, 68, 62, 68, 70]
  ),
  Set Display Width( 0 )
 ),
 New Column(
  ["en" => "weight",
  "ja" => "体重(ポンド)",
  "x-id" => "S_Big_Class_weight_Col",
  "zh-CN" => "体重"],
  Numeric, "Continuous", Format( "Fixed Dec", 5, 0 ),
  Set Values(
   [123, 145, 79, 107, 98, 95, 84, 93, 99, 92, 112, 128, 112, 115, 128, 116,
   134, 172]
  ),
  Set Display Width( 0 )
 ),
 Invisible
);

nw = New Window( "Win1", tbox = Tab Box(Tab Page Box("Age", vlb = Lineup Box( N Col( 2 )) )) );

nw << On close( try( Close( dt, "nosave" ) ) );

ages = associative array(dt:age) << get keys;

for(i=1, i<= n items(ages), i++,
 Eval( Eval Expr( 
  vlb << Append(   
   Graph Builder(
    Size( 534, 456 ),
    Show Control Panel( 0 ),
    Variables(
     X( :height ),
     Y( :weight ),
     Overlay( Transform Column( "Is " || char( ages[i] ) , Nominal, Formula( :age == Expr( ages[i] ) ) ) )
    ),
    Elements( Points( X, Y, Legend( 7 ) ) ),
    SendToReport(
     Dispatch( {}, "graph title", TextEditBox, {Set Text( "Hight and Weight" )} )
    )
   )
  )
 ) )
);