347711_es-ES

liliconcom

Color de fondo personalizado para mostrar cuadrantes en Graph Builder

Hola,

 

¿Cómo puedo personalizar el color de fondo en Graph Builder para mostrar 4 cuadrantes diferentes (es decir, el cuadrante 1 es de un color diferente al cuadrante 2, que es de un color diferente al del cuadrante 3, etc.)?

 

¡¡Gracias!!

 

 

GráficosRe: color de fondo personalizado para mostrar cuadrantes en Graph Builder

JMP permite agregar primitivas gráficas a cualquiera de las salidas gráficas dentro del sistema.Entonces para producir el siguiente gráfico

Simplemente haga clic derecho en el gráfico nativo y seleccione "Personalizar".Aparece una ventana que le permite agregar un script al gráfico.

A continuación, puede tomar el gráfico modificado y guardar un gráfico que se verá así:

Names Default To Here( 1 );
dt = open("$SAMPLE_DATA/big class.jmp");

Graph Builder(
 Size( 528, 456 ),
 Show Control Panel( 0 ),
 Variables( X( :weight ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 5 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "weight",
   ScaleBox,
   {Add Ref Line( 110, "Solid", "Black", "", 1 )}
  ),
  Dispatch(
   {},
   "height",
   ScaleBox,
   {Add Ref Line( 60, "Solid", "Black", "", 1 )}
  ),
  Dispatch(
   {},
   "Graph Builder",
   FrameBox,
   {Add Graphics Script(
    2,
    Description( "" ),
    Transparency( 0.5 );
    Fill Color( {1, 1, .5} );
    left = Current Report()[axisbox( 1 )] << getmin;
    top = Current Report()[axisbox( 2 )] << getmax;
    right = Current Report()[axisbox( 1 )] << getmax;
    bottom = Current Report()[axisbox( 2 )] << getmin;
    Fill Color( {1, 1, .5} );
    Rect( left, top, 110, 60, fill = 1 );
    Fill Color( "red" );
    Rect( 110, top, right, 60, fill = 1 );
    Fill Color( "green" );
    Rect( left, 60, 110, bottom, fill = 1 );
    Fill Color( "orange" );
    Rect( 110, 60, right, bottom, fill = 1 );
   ), Grid Line Order( 1 ), Reference Line Order( 3 ),
   DispatchSeg(
    TopSeg( 1 ),
    {Set Script(
     Transparency( 0.5 );
     Fill Color( {1, 1, .5} );
     left = Current Report()[axisbox( 1 )] << getmin;
     top = Current Report()[axisbox( 2 )] << getmax;
     right = Current Report()[axisbox( 1 )] << getmax;
     bottom = Current Report()[axisbox( 2 )] << getmin;
     Fill Color( {1, 1, .5} );
     Rect( left, top, 110, 60, fill = 1 );
     Fill Color( "red" );
     Rect( 110, top, right, 60, fill = 1 );
     Fill Color( "green" );
     Rect( left, 60, 110, bottom, fill = 1 );
     Fill Color( "orange" );
     Rect( 110, 60, right, bottom, fill = 1 );
    )}
   )}
  )
 )
);

Sin embargo, existe una forma más simple que la mayoría de los programadores encuentran más conveniente

Names Default To Here( 1 );
dt = open("$SAMPLE_DATA/big class.jmp");

gb = dt << Graph Builder(
 Size( 528, 456 ),
 Show Control Panel( 0 ),
 Variables( X( :weight ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 5 ) ) )
 );
report(gb)[FrameBox(1)] << add graphics script(
 Transparency( 0.5 );
    Fill Color( {1, 1, .5} );
    left = Current Report()[axisbox( 1 )] << getmin;
    top = Current Report()[axisbox( 2 )] << getmax;
    right = Current Report()[axisbox( 1 )] << getmax;
    bottom = Current Report()[axisbox( 2 )] << getmin;
    Fill Color( {1, 1, .5} );
    Rect( left, top, 110, 60, fill = 1 );
    Fill Color( "red" );
    Rect( 110, top, right, 60, fill = 1 );
    Fill Color( "green" );
    Rect( left, 60, 110, bottom, fill = 1 );
    Fill Color( "orange" );
    Rect( 110, 60, right, bottom, fill = 1 );
);