347711_zh-CN

liliconcom

自定义背景颜色以在图形生成器中显示象限

你好，

如何在图形生成器中自定义背景颜色以显示 4 个不同的象限（即象限 1 的颜色与象限 2 的颜色不同，象限 2 的颜色与象限 3 的颜色不同，等等）？

谢谢你！！

大规模定制回复：自定义背景颜色以在图形生成器中显示象限

你好，

能够用颜色标记图表的某些部分很有趣。

您是否有机会无需编写脚本即可做到这一点？

我只部分使用了重叠的参考线（我想避免） - 请参阅所附的屏幕截图。

祝你今天过得愉快。

回复：自定义背景颜色以在图形生成器中显示象限

您可以通过多种方式将项目添加到图表中。

注释

JMP 显示窗口上方的工具栏包含一些允许向图形添加注释项目的图标

可以添加文本、箭头和直线、多边形和圆形。它们被添加到图形显示的顶部。

您还可以右键单击图形并选择“自定义”，这允许使用图形基元添加项目。虽然它们使用 JSL，但它们使用起来非常简单，并且允许您添加彩色区域、文本、线条等，并且它们可以放置在显示器的任何级别。

回复：自定义背景颜色以在图形生成器中显示象限

JMP 允许将图形基元添加到系统内的任何图形输出。所以产生下面的图表

您只需右键单击本机图表并选择“自定义”。它会弹出一个窗口，允许您将脚本添加到图表中。

然后，您可以获取修改后的图表，并执行“保存图表”，如下所示：

Names Default To Here( 1 );
dt = open("$SAMPLE_DATA/big class.jmp");

Graph Builder(
	Size( 528, 456 ),
	Show Control Panel( 0 ),
	Variables( X( :weight ), Y( :height ) ),
	Elements( Points( X, Y, Legend( 5 ) ) ),
	SendToReport(
		Dispatch(
			{},
			"weight",
			ScaleBox,
			{Add Ref Line( 110, "Solid", "Black", "", 1 )}
		),
		Dispatch(
			{},
			"height",
			ScaleBox,
			{Add Ref Line( 60, "Solid", "Black", "", 1 )}
		),
		Dispatch(
			{},
			"Graph Builder",
			FrameBox,
			{Add Graphics Script(
				2,
				Description( "" ),
				Transparency( 0.5 );
				Fill Color( {1, 1, .5} );
				left = Current Report()[axisbox( 1 )] << getmin;
				top = Current Report()[axisbox( 2 )] << getmax;
				right = Current Report()[axisbox( 1 )] << getmax;
				bottom = Current Report()[axisbox( 2 )] << getmin;
				Fill Color( {1, 1, .5} );
				Rect( left, top, 110, 60, fill = 1 );
				Fill Color( "red" );
				Rect( 110, top, right, 60, fill = 1 );
				Fill Color( "green" );
				Rect( left, 60, 110, bottom, fill = 1 );
				Fill Color( "orange" );
				Rect( 110, 60, right, bottom, fill = 1 );
			), Grid Line Order( 1 ), Reference Line Order( 3 ),
			DispatchSeg(
				TopSeg( 1 ),
				{Set Script(
					Transparency( 0.5 );
					Fill Color( {1, 1, .5} );
					left = Current Report()[axisbox( 1 )] << getmin;
					top = Current Report()[axisbox( 2 )] << getmax;
					right = Current Report()[axisbox( 1 )] << getmax;
					bottom = Current Report()[axisbox( 2 )] << getmin;
					Fill Color( {1, 1, .5} );
					Rect( left, top, 110, 60, fill = 1 );
					Fill Color( "red" );
					Rect( 110, top, right, 60, fill = 1 );
					Fill Color( "green" );
					Rect( left, 60, 110, bottom, fill = 1 );
					Fill Color( "orange" );
					Rect( 110, 60, right, bottom, fill = 1 );
				)}
			)}
		)
	)
);

然而，有一种更简单的形式，大多数程序员认为更方便

Names Default To Here( 1 );
dt = open("$SAMPLE_DATA/big class.jmp");

gb = dt << Graph Builder(
	Size( 528, 456 ),
	Show Control Panel( 0 ),
	Variables( X( :weight ), Y( :height ) ),
	Elements( Points( X, Y, Legend( 5 ) ) )
	);
report(gb)[FrameBox(1)] << add graphics script(
	Transparency( 0.5 );
				Fill Color( {1, 1, .5} );
				left = Current Report()[axisbox( 1 )] << getmin;
				top = Current Report()[axisbox( 2 )] << getmax;
				right = Current Report()[axisbox( 1 )] << getmax;
				bottom = Current Report()[axisbox( 2 )] << getmin;
				Fill Color( {1, 1, .5} );
				Rect( left, top, 110, 60, fill = 1 );
				Fill Color( "red" );
				Rect( 110, top, right, 60, fill = 1 );
				Fill Color( "green" );
				Rect( left, 60, 110, bottom, fill = 1 );
				Fill Color( "orange" );
				Rect( 110, 60, right, bottom, fill = 1 );
);

回复：自定义背景颜色以在图形生成器中显示象限

非常感谢您的回复。这些都是极好的建议，而且都很有意义。

回复：在图表生成器中自定义象限背景颜色

非常感谢您的帮助！！！我感激不尽！！！