안녕하세요,
그래프의 특정 부분을 색상으로 표시할 수 있다는 점이 흥미롭습니다.
스크립팅 없이 이것을 할 수 있는 기회가 있습니까??
나는 겹치는 참조선을 사용하여 부분적으로만 수행했습니다(피하고 싶습니다). 첨부된 스크린샷을 참조하세요.
좋은 하루 되세요.
그래프에 항목을 추가할 수 있는 몇 가지 방법이 있습니다.
주석
JMP 표시 창 위의 도구 모음에는 그래프에 주석 항목을 추가할 수 있는 몇 가지 아이콘이 포함되어 있습니다.
텍스트, 화살표, 선, 다각형, 원을 추가할 수 있습니다. 그래픽 디스플레이 상단에 추가됩니다.
그래프를 마우스 오른쪽 버튼으로 클릭하고 그래픽 기본 요소를 사용하여 항목을 추가할 수 있는 "사용자 정의"를 선택할 수도 있습니다. JSL을 사용하지만 사용이 매우 간단하고 색상 영역, 텍스트, 선 등을 추가할 수 있으며 디스플레이의 모든 수준에 배치할 수 있습니다.
JMP를 사용하면 시스템 내의 모든 그래픽 출력에 그래픽 기본 요소를 추가할 수 있습니다. 그래서 아래 그래프를 생성하려면
기본 그래프를 마우스 오른쪽 버튼으로 클릭하고 "사용자 정의"를 선택하면 됩니다. 그래프에 스크립트를 추가할 수 있는 창이 나타납니다.
그런 다음 수정된 그래프를 가져와 다음과 같은 그래프 저장을 수행할 수 있습니다.
Names Default To Here( 1 );
dt = open("$SAMPLE_DATA/big class.jmp");
Graph Builder(
Size( 528, 456 ),
Show Control Panel( 0 ),
Variables( X( :weight ), Y( :height ) ),
Elements( Points( X, Y, Legend( 5 ) ) ),
SendToReport(
Dispatch(
{},
"weight",
ScaleBox,
{Add Ref Line( 110, "Solid", "Black", "", 1 )}
),
Dispatch(
{},
"height",
ScaleBox,
{Add Ref Line( 60, "Solid", "Black", "", 1 )}
),
Dispatch(
{},
"Graph Builder",
FrameBox,
{Add Graphics Script(
2,
Description( "" ),
Transparency( 0.5 );
Fill Color( {1, 1, .5} );
left = Current Report()[axisbox( 1 )] << getmin;
top = Current Report()[axisbox( 2 )] << getmax;
right = Current Report()[axisbox( 1 )] << getmax;
bottom = Current Report()[axisbox( 2 )] << getmin;
Fill Color( {1, 1, .5} );
Rect( left, top, 110, 60, fill = 1 );
Fill Color( "red" );
Rect( 110, top, right, 60, fill = 1 );
Fill Color( "green" );
Rect( left, 60, 110, bottom, fill = 1 );
Fill Color( "orange" );
Rect( 110, 60, right, bottom, fill = 1 );
), Grid Line Order( 1 ), Reference Line Order( 3 ),
DispatchSeg(
TopSeg( 1 ),
{Set Script(
Transparency( 0.5 );
Fill Color( {1, 1, .5} );
left = Current Report()[axisbox( 1 )] << getmin;
top = Current Report()[axisbox( 2 )] << getmax;
right = Current Report()[axisbox( 1 )] << getmax;
bottom = Current Report()[axisbox( 2 )] << getmin;
Fill Color( {1, 1, .5} );
Rect( left, top, 110, 60, fill = 1 );
Fill Color( "red" );
Rect( 110, top, right, 60, fill = 1 );
Fill Color( "green" );
Rect( left, 60, 110, bottom, fill = 1 );
Fill Color( "orange" );
Rect( 110, 60, right, bottom, fill = 1 );
)}
)}
)
)
);
그러나 대부분의 프로그래머가 더 편리하다고 생각하는 더 간단한 형식이 있습니다.
Names Default To Here( 1 );
dt = open("$SAMPLE_DATA/big class.jmp");
gb = dt << Graph Builder(
Size( 528, 456 ),
Show Control Panel( 0 ),
Variables( X( :weight ), Y( :height ) ),
Elements( Points( X, Y, Legend( 5 ) ) )
);
report(gb)[FrameBox(1)] << add graphics script(
Transparency( 0.5 );
Fill Color( {1, 1, .5} );
left = Current Report()[axisbox( 1 )] << getmin;
top = Current Report()[axisbox( 2 )] << getmax;
right = Current Report()[axisbox( 1 )] << getmax;
bottom = Current Report()[axisbox( 2 )] << getmin;
Fill Color( {1, 1, .5} );
Rect( left, top, 110, 60, fill = 1 );
Fill Color( "red" );
Rect( 110, top, right, 60, fill = 1 );
Fill Color( "green" );
Rect( left, 60, 110, bottom, fill = 1 );
Fill Color( "orange" );
Rect( 110, 60, right, bottom, fill = 1 );
);
