347711_zh-CN

liliconcom

自定义背景色以在Graph Builder中显示象限

你好

 

如何在Graph Builder中自定义背景色以显示4个不同的象限（即，象限1与象限2的颜色不同，象限2与象限3的颜色不同，等等）？

 

谢谢！！

 

 

图形回复：自定义背景色以在“图形生成器”中显示象限

JMP允许将图形基元添加到系统内的任何图形输出中。所以要产生下图

您只需右键单击本机图形，然后选择“自定义”。它会弹出一个窗口，允许您向图形添加脚本。

然后，您可以获取修改后的图形，并执行如下所示的“保存图形”：

Names Default To Here( 1 );
dt = open("$SAMPLE_DATA/big class.jmp");

Graph Builder(
 Size( 528, 456 ),
 Show Control Panel( 0 ),
 Variables( X( :weight ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 5 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "weight",
   ScaleBox,
   {Add Ref Line( 110, "Solid", "Black", "", 1 )}
  ),
  Dispatch(
   {},
   "height",
   ScaleBox,
   {Add Ref Line( 60, "Solid", "Black", "", 1 )}
  ),
  Dispatch(
   {},
   "Graph Builder",
   FrameBox,
   {Add Graphics Script(
    2,
    Description( "" ),
    Transparency( 0.5 );
    Fill Color( {1, 1, .5} );
    left = Current Report()[axisbox( 1 )] << getmin;
    top = Current Report()[axisbox( 2 )] << getmax;
    right = Current Report()[axisbox( 1 )] << getmax;
    bottom = Current Report()[axisbox( 2 )] << getmin;
    Fill Color( {1, 1, .5} );
    Rect( left, top, 110, 60, fill = 1 );
    Fill Color( "red" );
    Rect( 110, top, right, 60, fill = 1 );
    Fill Color( "green" );
    Rect( left, 60, 110, bottom, fill = 1 );
    Fill Color( "orange" );
    Rect( 110, 60, right, bottom, fill = 1 );
   ), Grid Line Order( 1 ), Reference Line Order( 3 ),
   DispatchSeg(
    TopSeg( 1 ),
    {Set Script(
     Transparency( 0.5 );
     Fill Color( {1, 1, .5} );
     left = Current Report()[axisbox( 1 )] << getmin;
     top = Current Report()[axisbox( 2 )] << getmax;
     right = Current Report()[axisbox( 1 )] << getmax;
     bottom = Current Report()[axisbox( 2 )] << getmin;
     Fill Color( {1, 1, .5} );
     Rect( left, top, 110, 60, fill = 1 );
     Fill Color( "red" );
     Rect( 110, top, right, 60, fill = 1 );
     Fill Color( "green" );
     Rect( left, 60, 110, bottom, fill = 1 );
     Fill Color( "orange" );
     Rect( 110, 60, right, bottom, fill = 1 );
    )}
   )}
  )
 )
);

但是，有一种更简单的形式，大多数程序员都觉得更方便

Names Default To Here( 1 );
dt = open("$SAMPLE_DATA/big class.jmp");

gb = dt << Graph Builder(
 Size( 528, 456 ),
 Show Control Panel( 0 ),
 Variables( X( :weight ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 5 ) ) )
 );
report(gb)[FrameBox(1)] << add graphics script(
 Transparency( 0.5 );
    Fill Color( {1, 1, .5} );
    left = Current Report()[axisbox( 1 )] << getmin;
    top = Current Report()[axisbox( 2 )] << getmax;
    right = Current Report()[axisbox( 1 )] << getmax;
    bottom = Current Report()[axisbox( 2 )] << getmin;
    Fill Color( {1, 1, .5} );
    Rect( left, top, 110, 60, fill = 1 );
    Fill Color( "red" );
    Rect( 110, top, right, 60, fill = 1 );
    Fill Color( "green" );
    Rect( left, 60, 110, bottom, fill = 1 );
    Fill Color( "orange" );
    Rect( 110, 60, right, bottom, fill = 1 );
);