347711_ko-KR

liliconcom

그래프 빌더에서 사분면을 표시하는 사용자 정의 배경색

안녕,

 

4 개의 다른 사분면을 표시하도록 Graph Builder에서 배경색을 사용자 정의하려면 어떻게해야합니까 (즉, 사분면 1은 사분면 3과 다른 색상 인 사분면 2와 다른 색상입니다)?

 

감사합니다!!

 

 

제도법Re : Graph Builder에서 사분면을 표시하는 사용자 정의 배경색

JMP를 사용하면 시스템 내의 모든 그래픽 출력에 그래픽 프리미티브를 추가 할 수 있습니다.따라서 아래 그래프를 생성하려면

네이티브 그래프를 마우스 오른쪽 버튼으로 클릭하고 "사용자 지정"을 선택하면됩니다.그래프에 스크립트를 추가 할 수있는 창이 나타납니다.

그런 다음 수정 된 그래프를 가져 와서 다음과 같은 그래프 저장을 수행 할 수 있습니다.

Names Default To Here( 1 );
dt = open("$SAMPLE_DATA/big class.jmp");

Graph Builder(
 Size( 528, 456 ),
 Show Control Panel( 0 ),
 Variables( X( :weight ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 5 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "weight",
   ScaleBox,
   {Add Ref Line( 110, "Solid", "Black", "", 1 )}
  ),
  Dispatch(
   {},
   "height",
   ScaleBox,
   {Add Ref Line( 60, "Solid", "Black", "", 1 )}
  ),
  Dispatch(
   {},
   "Graph Builder",
   FrameBox,
   {Add Graphics Script(
    2,
    Description( "" ),
    Transparency( 0.5 );
    Fill Color( {1, 1, .5} );
    left = Current Report()[axisbox( 1 )] << getmin;
    top = Current Report()[axisbox( 2 )] << getmax;
    right = Current Report()[axisbox( 1 )] << getmax;
    bottom = Current Report()[axisbox( 2 )] << getmin;
    Fill Color( {1, 1, .5} );
    Rect( left, top, 110, 60, fill = 1 );
    Fill Color( "red" );
    Rect( 110, top, right, 60, fill = 1 );
    Fill Color( "green" );
    Rect( left, 60, 110, bottom, fill = 1 );
    Fill Color( "orange" );
    Rect( 110, 60, right, bottom, fill = 1 );
   ), Grid Line Order( 1 ), Reference Line Order( 3 ),
   DispatchSeg(
    TopSeg( 1 ),
    {Set Script(
     Transparency( 0.5 );
     Fill Color( {1, 1, .5} );
     left = Current Report()[axisbox( 1 )] << getmin;
     top = Current Report()[axisbox( 2 )] << getmax;
     right = Current Report()[axisbox( 1 )] << getmax;
     bottom = Current Report()[axisbox( 2 )] << getmin;
     Fill Color( {1, 1, .5} );
     Rect( left, top, 110, 60, fill = 1 );
     Fill Color( "red" );
     Rect( 110, top, right, 60, fill = 1 );
     Fill Color( "green" );
     Rect( left, 60, 110, bottom, fill = 1 );
     Fill Color( "orange" );
     Rect( 110, 60, right, bottom, fill = 1 );
    )}
   )}
  )
 )
);

그러나 대부분의 프로그래머가 더 편리하다고 생각하는 더 간단한 형식이 있습니다.

Names Default To Here( 1 );
dt = open("$SAMPLE_DATA/big class.jmp");

gb = dt << Graph Builder(
 Size( 528, 456 ),
 Show Control Panel( 0 ),
 Variables( X( :weight ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 5 ) ) )
 );
report(gb)[FrameBox(1)] << add graphics script(
 Transparency( 0.5 );
    Fill Color( {1, 1, .5} );
    left = Current Report()[axisbox( 1 )] << getmin;
    top = Current Report()[axisbox( 2 )] << getmax;
    right = Current Report()[axisbox( 1 )] << getmax;
    bottom = Current Report()[axisbox( 2 )] << getmin;
    Fill Color( {1, 1, .5} );
    Rect( left, top, 110, 60, fill = 1 );
    Fill Color( "red" );
    Rect( 110, top, right, 60, fill = 1 );
    Fill Color( "green" );
    Rect( left, 60, 110, bottom, fill = 1 );
    Fill Color( "orange" );
    Rect( 110, 60, right, bottom, fill = 1 );
);