347711_fr-FR

liliconcom

Couleur d'arrière-plan personnalisée pour afficher les quadrants dans Graph Builder

Salut,

 

Comment personnaliser la couleur d'arrière-plan dans Graph Builder pour afficher 4 quadrants différents (c'est-à-dire que le quadrant 1 est une couleur différente du quadrant 2 qui est une couleur différente du quadrant 3, etc.)?

 

Je vous remercie!!

 

 

GraphiqueRe: Couleur d'arrière-plan personnalisée pour afficher les quadrants dans Graph Builder

JMP permet d'ajouter des primitives graphiques à l'une des sorties graphiques du système.Donc pour produire le graphique ci-dessous

Il vous suffit de faire un clic droit sur le graphique natif et de sélectionner «Personnaliser».Il ouvre une fenêtre qui vous permet d'ajouter un script au graphique.

Vous pouvez ensuite prendre le graphique modifié et faire un Enregistrer le graphique qui ressemblera à:

Names Default To Here( 1 );
dt = open("$SAMPLE_DATA/big class.jmp");

Graph Builder(
 Size( 528, 456 ),
 Show Control Panel( 0 ),
 Variables( X( :weight ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 5 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "weight",
   ScaleBox,
   {Add Ref Line( 110, "Solid", "Black", "", 1 )}
  ),
  Dispatch(
   {},
   "height",
   ScaleBox,
   {Add Ref Line( 60, "Solid", "Black", "", 1 )}
  ),
  Dispatch(
   {},
   "Graph Builder",
   FrameBox,
   {Add Graphics Script(
    2,
    Description( "" ),
    Transparency( 0.5 );
    Fill Color( {1, 1, .5} );
    left = Current Report()[axisbox( 1 )] << getmin;
    top = Current Report()[axisbox( 2 )] << getmax;
    right = Current Report()[axisbox( 1 )] << getmax;
    bottom = Current Report()[axisbox( 2 )] << getmin;
    Fill Color( {1, 1, .5} );
    Rect( left, top, 110, 60, fill = 1 );
    Fill Color( "red" );
    Rect( 110, top, right, 60, fill = 1 );
    Fill Color( "green" );
    Rect( left, 60, 110, bottom, fill = 1 );
    Fill Color( "orange" );
    Rect( 110, 60, right, bottom, fill = 1 );
   ), Grid Line Order( 1 ), Reference Line Order( 3 ),
   DispatchSeg(
    TopSeg( 1 ),
    {Set Script(
     Transparency( 0.5 );
     Fill Color( {1, 1, .5} );
     left = Current Report()[axisbox( 1 )] << getmin;
     top = Current Report()[axisbox( 2 )] << getmax;
     right = Current Report()[axisbox( 1 )] << getmax;
     bottom = Current Report()[axisbox( 2 )] << getmin;
     Fill Color( {1, 1, .5} );
     Rect( left, top, 110, 60, fill = 1 );
     Fill Color( "red" );
     Rect( 110, top, right, 60, fill = 1 );
     Fill Color( "green" );
     Rect( left, 60, 110, bottom, fill = 1 );
     Fill Color( "orange" );
     Rect( 110, 60, right, bottom, fill = 1 );
    )}
   )}
  )
 )
);

Cependant, il existe une forme plus simple que la plupart des programmeurs trouvent plus pratique

Names Default To Here( 1 );
dt = open("$SAMPLE_DATA/big class.jmp");

gb = dt << Graph Builder(
 Size( 528, 456 ),
 Show Control Panel( 0 ),
 Variables( X( :weight ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 5 ) ) )
 );
report(gb)[FrameBox(1)] << add graphics script(
 Transparency( 0.5 );
    Fill Color( {1, 1, .5} );
    left = Current Report()[axisbox( 1 )] << getmin;
    top = Current Report()[axisbox( 2 )] << getmax;
    right = Current Report()[axisbox( 1 )] << getmax;
    bottom = Current Report()[axisbox( 2 )] << getmin;
    Fill Color( {1, 1, .5} );
    Rect( left, top, 110, 60, fill = 1 );
    Fill Color( "red" );
    Rect( 110, top, right, 60, fill = 1 );
    Fill Color( "green" );
    Rect( left, 60, 110, bottom, fill = 1 );
    Fill Color( "orange" );
    Rect( 110, 60, right, bottom, fill = 1 );
);