347711_de-DE

liliconcom

Benutzerdefinierte Hintergrundfarbe zur Anzeige von Quadranten im Graph Builder

Hallo,

Wie passe ich die Hintergrundfarbe in Graph Builder an, um 4 verschiedene Quadranten anzuzeigen (z. B. Quadrant 1 hat eine andere Farbe als Quadrant 2, der eine andere Farbe hat als Quadrant 3 usw.)?

Danke schön!!

MassenanpassungBetreff: Benutzerdefinierte Hintergrundfarbe zur Anzeige von Quadranten im Diagramm-Generator

Vielen herzlichen Dank für Ihre Hilfe!!! Ich weiß das sehr zu schätzen!!!

Betreff: Benutzerdefinierte Hintergrundfarbe zur Anzeige von Quadranten im Graph Builder

JMP ermöglicht das Hinzufügen grafischer Grundelemente zu allen grafischen Ausgaben innerhalb des Systems. So erstellen Sie die folgende Grafik

Klicken Sie einfach mit der rechten Maustaste auf das native Diagramm und wählen Sie „Anpassen“. Es öffnet sich ein Fenster, in dem Sie dem Diagramm ein Skript hinzufügen können.

Anschließend können Sie das geänderte Diagramm nehmen und ein Diagramm speichern, das wie folgt aussieht:

Names Default To Here( 1 );
dt = open("$SAMPLE_DATA/big class.jmp");

Graph Builder(
	Size( 528, 456 ),
	Show Control Panel( 0 ),
	Variables( X( :weight ), Y( :height ) ),
	Elements( Points( X, Y, Legend( 5 ) ) ),
	SendToReport(
		Dispatch(
			{},
			"weight",
			ScaleBox,
			{Add Ref Line( 110, "Solid", "Black", "", 1 )}
		),
		Dispatch(
			{},
			"height",
			ScaleBox,
			{Add Ref Line( 60, "Solid", "Black", "", 1 )}
		),
		Dispatch(
			{},
			"Graph Builder",
			FrameBox,
			{Add Graphics Script(
				2,
				Description( "" ),
				Transparency( 0.5 );
				Fill Color( {1, 1, .5} );
				left = Current Report()[axisbox( 1 )] << getmin;
				top = Current Report()[axisbox( 2 )] << getmax;
				right = Current Report()[axisbox( 1 )] << getmax;
				bottom = Current Report()[axisbox( 2 )] << getmin;
				Fill Color( {1, 1, .5} );
				Rect( left, top, 110, 60, fill = 1 );
				Fill Color( "red" );
				Rect( 110, top, right, 60, fill = 1 );
				Fill Color( "green" );
				Rect( left, 60, 110, bottom, fill = 1 );
				Fill Color( "orange" );
				Rect( 110, 60, right, bottom, fill = 1 );
			), Grid Line Order( 1 ), Reference Line Order( 3 ),
			DispatchSeg(
				TopSeg( 1 ),
				{Set Script(
					Transparency( 0.5 );
					Fill Color( {1, 1, .5} );
					left = Current Report()[axisbox( 1 )] << getmin;
					top = Current Report()[axisbox( 2 )] << getmax;
					right = Current Report()[axisbox( 1 )] << getmax;
					bottom = Current Report()[axisbox( 2 )] << getmin;
					Fill Color( {1, 1, .5} );
					Rect( left, top, 110, 60, fill = 1 );
					Fill Color( "red" );
					Rect( 110, top, right, 60, fill = 1 );
					Fill Color( "green" );
					Rect( left, 60, 110, bottom, fill = 1 );
					Fill Color( "orange" );
					Rect( 110, 60, right, bottom, fill = 1 );
				)}
			)}
		)
	)
);

Es gibt jedoch eine einfachere Form, die für die meisten Programmierer praktischer ist

Names Default To Here( 1 );
dt = open("$SAMPLE_DATA/big class.jmp");

gb = dt << Graph Builder(
	Size( 528, 456 ),
	Show Control Panel( 0 ),
	Variables( X( :weight ), Y( :height ) ),
	Elements( Points( X, Y, Legend( 5 ) ) )
	);
report(gb)[FrameBox(1)] << add graphics script(
	Transparency( 0.5 );
				Fill Color( {1, 1, .5} );
				left = Current Report()[axisbox( 1 )] << getmin;
				top = Current Report()[axisbox( 2 )] << getmax;
				right = Current Report()[axisbox( 1 )] << getmax;
				bottom = Current Report()[axisbox( 2 )] << getmin;
				Fill Color( {1, 1, .5} );
				Rect( left, top, 110, 60, fill = 1 );
				Fill Color( "red" );
				Rect( 110, top, right, 60, fill = 1 );
				Fill Color( "green" );
				Rect( left, 60, 110, bottom, fill = 1 );
				Fill Color( "orange" );
				Rect( 110, 60, right, bottom, fill = 1 );
);

Betreff: Benutzerdefinierte Hintergrundfarbe zur Anzeige von Quadranten im Graph Builder

Hallo,

Interessant ist die Möglichkeit, bestimmte Teile des Diagramms mit einer Farbe markieren zu können.

Gibt es eine Chance, dass Sie dies ohne Skripting tun könnten?

Ich habe es nur teilweise mit überlappenden Referenzlinien gemacht (was ich vermeiden möchte) – siehe beigefügten Screenshot.

Einen schönen Tag noch.

Betreff: Benutzerdefinierte Hintergrundfarbe zur Anzeige von Quadranten im Graph Builder

Es gibt verschiedene Möglichkeiten, Elemente zu Ihren Diagrammen hinzuzufügen.

Anmerkungen

Die Symbolleiste über dem JMP-Anzeigefenster enthält einige Symbole, die das Hinzufügen von Anmerkungselementen zu Diagrammen ermöglichen

Es können Text, Pfeile und Linien, Polygone und Kreise hinzugefügt werden. Sie werden oben auf der Grafikanzeige hinzugefügt.

Sie können auch mit der rechten Maustaste auf das Diagramm klicken und „Anpassen“ wählen, um Elemente mithilfe grafischer Grundelemente hinzuzufügen. Obwohl diese JSL verwenden, sind sie sehr einfach zu verwenden und ermöglichen das Hinzufügen von farbigen Bereichen, Text, Linien usw. und können auf jeder Ebene der Anzeige positioniert werden.

Betreff: Benutzerdefinierte Hintergrundfarbe zur Anzeige von Quadranten im Graph Builder

Vielen Dank für Ihre Antwort. Das sind ausgezeichnete Tipps und beide sind sinnvoll.