347226_fr-FR

liliconcom

Renommer des colonnes à l'aide d'un tableau associatif

Salut, j'essaie d'utiliser un tableau associatif pour renommer un tas de colonnes. J'ai utilisé les données Big Class comme exemple. J'apprécierai de l'aide pour corriger mon script.

Names Default To Here( 1 );
dt = Data Table ("Big Class.jmp");
//Use and array to rename the Big Class table columns to "spanish"
newColNames = Associative Array();
newColNames["name"] = "nombre";
newColNames["age"] = "edad";
newColNames["sex"] = "sexo";
newColNames["height"] = "altura";
newColNames["weight"] = "peso";

uno = newColNames << Get Keys(); //for testing

newN = newColNames << Get Values({"name"}); //for testing

oriNames = dt << Get Column Names(); // in case there are variation on the number/name of columns

For( i=1, 1 <= N Items(oriNames), i++,
key = oriNames[i];

 Column(dt, key ) << set name (newColNames<<GET values=""></GET>

Tableau de donnéesScriptRe : Renommer des colonnes à l'aide d'un tableau associatif

@ian_jmp

Merci beaucoup pour votre aide. Leçons importantes : vérifiez vos i et "Get Values" et "Get Value".

Cordialement,

AL

Re : Renommer des colonnes à l'aide d'un tableau associatif

@ian_jmp J'ai mis beaucoup trop de temps à voir le "1" !

dt = Open( "$sample_data/Big Class.jmp" );
//Use and array to rename the Big Class table columns to "spanish"
newColNames = Associative Array();
newColNames["name"] = "nombre";
newColNames["age"] = "edad";
newColNames["sex"] = "sexo";
newColNames["height"] = "altura";
newColNames["weight"] = "peso";

uno = newColNames << Get Keys(); //for testing

newN = newColNames << Get Values( {"age"} ); //for testing

oriNames = dt << Get Column Names( "string" ); // in case there are variation on the number/name of columns

For( i = 1, i <= N Items( oriNames ), i++,
 key = oriNames[i];
 Column( dt, key ) << set name( newColNames[key] );
);

Re : Renommer des colonnes à l'aide d'un tableau associatif

Vous étiez très proche :

Names Default To Here( 1 );

dt = Open("$SAMPLE_DATA/Big Class.jmp");

//Use and array to rename the Big Class table columns to "spanish"
newColNames = Associative Array();
newColNames["name"] = "nombre";
newColNames["age"] = "edad";
newColNames["sex"] = "sexo";
newColNames["height"] = "altura";
newColNames["weight"] = "peso";

oriNames = dt << Get Column Names("String");  // in case there are variation on the number/name of columns

For( i=1, i <= N Items(oriNames), i++,
 key = oriNames[i];
 Column(dt, key ) << set name ( newColNames << Get Value (key) );
);