345802_de-DE

liliconcom

Wie speichere ich nur eine Teilmenge von Tabellen?

Nehmen wir an, wir haben eine Tabelle mit 3 Spalten (Beispiel unten). Ich erstelle eine Teilmenge von Tabellen anhand der Spalte „Stadtcode“, die alle drei Spalten enthält.

 

Postleitzahl	Registrationsnummer	Registrierungsdatum
032	0320537648	20201026
160	1600084082	20201020
281	2821162566	20201020
325	3250488500	20201024
420	4200618843	20201101
511	5110680174	20201027
720	7200054737	20200825

 

Ich möchte nur die Teildateien wie folgt als Textdateien speichern: Stadtcodewert.txt

 

Ich habe im Forum das folgende JSL-Skript gefunden, das beim Speichern der Dateien als Textdateien sehr hilfreich war. Das Problem besteht darin, dass die Dateien als Stadtcode = value.txt gespeichert werden

Die Hauptdatentabelle wird auch als Textdatei gespeichert, was ich nicht möchte.

 

 

//Save as txt file

openDTs = {};

For( i = 1, i <= N Table(), i++,

     Insert Into( openDTs, Data Table( i ) )

);

For( i = 1, i <= N Items( openDTs ), i++,

     one_name = openDTS[i] << get name;

     file_path = one_name || ".txt";

     openDTS[i] << Save(file_path);

);

 

Ich bin sowohl in JMP als auch in der Skripterstellung neu, daher bin ich für jede Idee sehr dankbar.

Automatisierung und SkripterstellungDatenmischung und -bereinigungBetreff: Wie speichere ich nur eine Teilmenge von Tabellen?

@txnelson Vielen Dank! Lief wie am Schnürchen.

Betreff: Wie speichere ich nur eine Teilmenge von Tabellen?

Unten finden Sie ein Skript, das die von Ihnen bereitgestellte Beispieldatentabelle erstellt.Anschließend werden die Teilmengen erstellt und jede Teilmenge als TXT-Datei gespeichert.

Um dieses Beispiel auszuführen, muss lediglich die Codezeile geändert werden

saveFolder = "C:\xxxxxxxxxxxxx\";

Geben Sie den tatsächlichen Pfad zum Ordner an, in dem die Dateien gespeichert werden sollen, und führen Sie dann den Code aus

Names Default To Here( 1 );

// Create the example data table
New Table( "Example",
 Add Rows( 7 ),
 New Column( "City code", Numeric, "Continuous", Format( "Best", 12 ), Set Selected, Set Values( [32, 160, 281, 325, 420, 511, 720] ) ),
 New Column( "Registration Number",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [320537648, 1600084082, 2821162566, 3250488500, 4200618843, 5110680174, 7200054737] )
 ),
 New Column( "Registration Date",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [20201026, 20201020, 20201020, 20201024, 20201101, 20201027, 20200825] )
 )
);


// Here is the real code.....just change the saveFolder =    to the actual folder you want to
// save the files to
dt = Current Data Table();

// Create the subsets
dtSub = dt << Subset( By( :City code ), 
 All rows, Selected columns only( 0 ), 
 columns( :Registration Number, :Registration Date ) );

saveFolder = "C:\xxxxxxxxxxxxx\";

For( i = 1, i <= N Items( dtSub ), i++,
 // Given the structure of the data tables created with a Subset using a By() clause
 //      City Code = 32
 // the Word() function retuns the "32" and it is added as the name of the file to save
 dtSub[i] << Save( saveFolder || Word( -1, dtSub[i] << get name, "=" ) || ".txt" )
);