345584_de-DE

liliconcom

Ruft Spaltennamen ab, die einen bestimmten Wert haben

Hallo,

 

Ich habe gerade angefangen, jmp bei der Arbeit zu verwenden und zu versuchen, JSL zu lernen. Ich versuche, ein Skript zu schreiben, um die Spaltennamen zu erhalten, bei denen der Zeilenwert = 1 ist. Zum Beispiel zeigt die Tabelle Werte von 0 und 1 unter verschiedenen IMCX-Spalten und ich möchte herausfinden, welche Spalte in jeder Zeile den Wert = 1 hat und unter einer neuen Spalte namens IMC speichern. In der ersten Zeile hat Spalte IMC 4 1, daher gebe ich IMC4 manuell unter IMC ein. Die Tabellen enthalten mehr als 5000 Zeilen. Danke für die Hilfe.

 

 

DatentabelleBetreff: Spaltennamen abrufen, die einen bestimmten Wert haben

Sie können so etwas tun:

 

Die Formel in der Spalte Ergebnis lautet wie folgt:

If( :A == 0,
 "",
 Char( Column Name( 1 ) )
) || If( :B == 0,
 "",
 Char( Column Name( 2 ) )
) || If( :C == 0,
 "",
 Char( Column Name( 3 ) )
) || If(  == 0,
 "",
 Char( Column Name( 4 ) )
)

ich benutze verketten Schlüsselwort, um jede Spalte zu überprüfen, um festzustellen, ob es sich um eine 1 handelt.

Lassen Sie mich wissen, ob es für Sie funktioniert!

Betreff: Spaltennamen abrufen, die einen bestimmten Wert haben

Hier ist eine Möglichkeit, dies zu tun

Names Default To Here( 1 );

// Create a sample data table
dt = New Table( "Example",
 Add Rows( 2 ),
 New Column( "IMCO", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC1", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IIMC2", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC3", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC4", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [1, 0] ) ),
 New Column( "IMC5", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC6", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 1] ), Set Display Width( 46 ) ),
 New Column( "IMC7", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC8", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC9", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC10", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC11", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "RESIDUAL", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [32.3201037, 20.54947] ) ),
 New Column( "TEST", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., .] ) )
);

// Generate a list of columns to be processed
colNamesList = dt << get column names(string);
remove from (colNamesList,13,2);

// Find the maximum( the ones ) for the columns in question
dtSum = dt<< Summary(
 Max(colNamesList),
 Freq( "None" ),
 Weight( "None" ),
 statistics column name format( "column" ),
 Link to original data table( 0 )
);

// Stack all of the summarized columns
dtStack = dtSum << Stack(
 columns(
  colNamesList
 ),
 Source Label Column( "IMC" ),
 Stacked Data Column( "Data" )
);

close( dtSum, nosave );

// Delete all data that do not have 1 
dtStack << select where(:Data !=1 );
dtStack << delete rows;

// Delete the unwanted columns from the summary table
dtStack << delete columns( {N Rows, data} );

// If there are more rows than in the original table, add rows
if( n rows( dt ) < N Rows( dtStack ),
 dt << add rows( N Rows( dtStack ) - N Rows( dt ) )
);

// Add the column names for the columns found with 1's in their data
dt << Update( With( dtStack ) );

close( dtStack, nosave );

Hier ist ein zweiter Weg, dies zu tun:

Names Default To Here( 1 );

// Create a sample data table
dt = New Table( "Example",
 Add Rows( 2 ),
 New Column( "IMCO", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC1", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IIMC2", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC3", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC4", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [1, 0] ) ),
 New Column( "IMC5", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC6", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 1] ), Set Display Width( 46 ) ),
 New Column( "IMC7", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC8", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC9", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC10", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC11", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "RESIDUAL", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [32.3201037, 20.54947] ) ),
 New Column( "TEST", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., .] ) )
);

foundNamesList = {};

For( i = 5, i <= N Items( colNamesList ), i++,
theRows = dt << get rows where(as Column( colNamesList[i]) == 1 );
 If( N rows( theRows)  > 0, Insert Into( foundNamesList, colNamesList[i] ) )
 );

dt << New Column( "IMC", character );

If( N Items( foundNamesList ) > 0,
 dt:IMC << set values( foundNamesList )
);

Betreff: Spaltennamen abrufen, die einen bestimmten Wert haben

Meine Lösung (unter Verwendung derselben Beispieldatentabelle wie bei txnelson):

Names Default To Here( 1 );

// Create a sample data table
dt = New Table( "Example",
 Add Rows( 2 ),
 New Column( "IMCO", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC1", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IIMC2", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC3", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC4", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [1, 0] ) ),
 New Column( "IMC5", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC6", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 1] ), Set Display Width( 46 ) ),
 New Column( "IMC7", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC8", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC9", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC10", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC11", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "RESIDUAL", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [32.3201037, 20.54947] ) ),
 New Column( "TEST", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., .] ) )
);

//get wanted columns. Assumes that IMC columns start from column 1 and all IMC columns are one after another
colNames = dt << Get Column Names("String");
For(i = N Items(colNames), i > 0 , i--,
 If(!Starts With(colNames[i], "IMC"),
  Remove From(colNames, i),
  break(); //we can break on first occurance
 );
);

//new column with IMC with value 1
dt << New Column("IMC", Character, 
 << Set Each Value(
  rowValues = dt[Row(), 0][1::N Items(colNames)]; //get values of row as matrix
  colIndex = Contains(rowValues, 1); //get index of
  If(colIndex > 0, //handle 
   colNames[colIndex], //get column name with the index
   ""; //when no 1 found use ""
  );
 );
);

Ich mag die erste Lösung @ txnelson angeboten aus zwei (drei) Gründen:

1. Es werden so viele Menüpunkte verwendet, die direkt von JMP gefunden wurden, und Sie könnten fast Schreiben Sie es ohne JSL-Kenntnisse, indem Sie es einfach aus datierbaren Quellen kopieren und einfügen
2. Es verwendet eine sehr JSL-ähnliche Syntax für alle << wähle wo und derartige
3. (Ich denke, dass diese Art von Workflow in der Lösung sehr JMP-ähnlich ist)

Betreff: Spaltennamen abrufen, die einen bestimmten Wert haben

Hinsichtlich " Ich habe gerade angefangen, jmp bei der Arbeit zu verwenden und zu versuchen, JSL zu lernen "(und wurde bereits angedeutet) Es gibt viele Möglichkeiten, die Arbeit zu erledigen.

 

In diesem Sinne finden Sie bitte noch eine weitere kleine Variation. Verwenden Sie "Hilfe> Bücher> Skripthandbuch", um herauszufinden, wie es funktioniert.

Names Default To Here( 1 );

// Create a sample data table
dt = New Table( "Example",
 Add Rows( 2 ),
 New Column( "IMCO", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC1", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [1, 0] ) ),
 New Column( "IIMC2", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC3", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 1] ) ),
 New Column( "IMC4", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [1, 0] ) ),
 New Column( "IMC5", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC6", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 1] ), Set Display Width( 46 ) ),
 New Column( "IMC7", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC8", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC9", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC10", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
 New Column( "IMC11", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [0, 0] ) ),
);

// Get a list of the column names
colList = dt << getColumnNames("String");

// Get the '0's and '1's into a matrix
mat = dt << getAsMatrix;

// Value to search for
searchVal = 1;

// Add an 'expression' column and loop rowise . . .
newCol = dt << NewColumn("Value "||Char(searchVal)||" found in Column:", Expression);
for (r=1, r<=NRow(dt), r++,
 newCol[r] = colList[Loc(mat[r, 0], searchVal)];
);

 

Betreff: Spaltennamen abrufen, die einen bestimmten Wert habenIch danke dir sehr. Es funktionierte!