Near neighbors mean calculation

Franck_R

Hi everyone,

 

I have to calculate the mean of neighbors dies/components on a microelectronic wafer for example on a 3x3 box like that:

The reference component is in the centre of a box and therefore surrounded by 8 components whose mean I want to calculate, for each row of the data table (then calculate the same thing for a 5x5 box and 16 neighbors...)

It will be used as a new feature for machine learning.

 

My code is:

dt = current data table();
<BR />// building the KD table
matrice = (dt:row << getvalues) || (dt:col << getvalues);

table = KDTable(matrice);

for( i=1, i<=nrows(dt),i++,
    // get the 3x3 neighbors
	neighbors = table << Knearestrows(8,i);
	neighbors_number = neighbors[1,1];
	// Select the neighbors and get their metrics values and calculate the mean<BR />    dt << select rows (neighbors_number );	
	mean_selection = Col Mean( If( Selected(), :metric, . ) );	
	:mean_metric[i] = mean_selection;
	dt << clear select
	
);

Has someone a smart way to do that calculation more efficiently?

thanks!

box_3x3_mean.jmp

XanGregg

I'm not sure how the efficiency compares, but here is an alternative for you to try out.

• Using begin/end data update() will help for any method
• Using Nearest Neighbor is clever (and maybe even more efficient) but be aware that it will always return the 8 nearest, even at the edges of the wafer where the neighbors will all be on one side.
• Matrix subscripting may be more efficient than Col Mean().

 

 

dt = current data table();
metrics = dt[0, "metric"];
rows = dt[0, "row"];
cols = dt[0, "col"];
d = 1;	// 1 => 3x3, 2 => 5x5

dt << Begin Data Update();
For Each Row(
	neighbors = Loc( :col - d <= cols <= :col + d & :row - d <= rows <= :row + d );
	mean all = Mean( metrics[neighbors] );
	nn = N Rows( neighbors );
	mean without center = (mean all * nn - :metric) / (nn - 1);
	:mm = mean without center;
);
dt << End Data Update();