345287_es-ES

liliconcom

El informe de la prueba de estabilidad de JMP no muestra ambos límites de especificación

Hola

Tengo una respuesta con límites de especificación de dos lados ingresados como Límites de especificación en Propiedades de columna, y marque la casilla en "Mostrar como líneas de referencia de gráfico". Cuando realizo un análisis de Confiabilidad y supervivencia-> Degradación-> Estabilidad, obtengo un tiempo de cruce más temprano de 13,99, donde se cruza la USL. Sin embargo, USL no se muestra en el gráfico de superposición, solo se muestra LSL.

Me gustaría ver ambos límites de especificación en el gráfico de superposición como en la figura a continuación (donde he cambiado manualmente el eje y)

¿Tiene un truco en el que puedo obligar a JMP a mostrar ambos límites de especificaciones en el gráfico? Estoy usando el gráfico en un script, donde recorro muchos parámetros, por lo que prefiero evitar cambiar el eje y manualmente.

Se adjuntan datos y guión. Estoy usando JMP 15.0.

 

Gracias,

Pedro

 

AnalíticaRe: informe de prueba de estabilidad JMP no muestra ambos límites de especificación

Así es como manejo estos artículos

names default to here(1);
dt = current data table();

deg = dt << Degradation(
 Y( :result ),
 Time( :Name( "Timepoint (M)" ) ),
 Label( :Batch ),
 Application( Stability Test ),
 Connect Data Markers( 1 ),
 Show Fitted Lines( 1 ),
 Show Spec Limits( 1 ),
 Show Median Curves( 0 ),
 Show Legend( 1 ),
 No Tab List( 0 ),
 Set Upper Spec Limit( 5.5 ),
 Set Lower Spec Limit( 4.5 ),
 Set Censoring Time( . ),
 Show Residual Plot( 0 ),
 Show Inverse Prediction Plot( 0 ),
 Show Curve Interval( 1 ),
 Inverse Prediction Interval( Confidence Interval ),
 Inverse Prediction Alpha( 0.025 ),
 Inverse Prediction Side( Lower One Sided ),
 SendToReport( Dispatch( {}, "Reports", OutlineBox, {Close( 1 )} ) )
);
specs = dt:result << get property("spec limits");
degr = deg << report;

if(degr[AxisBox(1)]<<GET max="">< specs["USL"], degr[AxisBox(1)]<<MAX></MAX></GET>

Re: informe de prueba de estabilidad JMP no muestra ambos límites de especificación

Esto parece un error. Póngase en contacto con el soporte técnico de JMP en support@jmp.com

Mientras tanto, una solución es usar JSL para ajustar el eje, si es aceptable en su flujo de trabajo.

Mira los siguientes códigos. Hacia el final, es una forma de ajustar el eje, codificando de forma rígida el rango del eje. Hay al menos otras dos formas, pero gradualmente se van complicando. Si este enfoque no funciona para su flujo de trabajo, explique. Y veremos qué podría funcionar.

 

Degradation(
 Y( :result ),
 Time( :Name("Timepoint (M)") ),
 Label( :Batch ),
 Application( Stability Test ),
 Connect Data Markers( 1 ),
 Show Fitted Lines( 1 ),
 Show Spec Limits( 1 ),
 Show Median Curves( 0 ),
 Show Legend( 1 ),
 No Tab List( 0 ),
 Set Upper Spec Limit( 5.5 ),
 Set Lower Spec Limit( 4.5 ),
 Set Censoring Time( . ),
 Show Residual Plot( 0 ),
 Show Inverse Prediction Plot( 0 ),
 Show Curve Interval( 1 ),
 Inverse Prediction Interval( Confidence Interval ),
 Inverse Prediction Alpha( 0.025 ),
 Inverse Prediction Side( Lower One Sided ),
 SendToReport(
  Dispatch( {}, "Reports", OutlineBox, {Close( 1 )} ),
  Dispatch(
   {"Overlay"},
   "2",
   ScaleBox,
   {Min( 4 ), Max( 6 ), Inc( 0.2 ), Minor Ticks( 1 )}
  )
 )
)

Re: informe de prueba de estabilidad JMP no muestra ambos límites de especificación

Gracias. Buen trabajo. Funciona perfectamente en mi guión.

Pedro

Re: informe de prueba de estabilidad de JMP que no muestra ambos límites de especificación

Muy parecido a la solución de txnelson:

 

Names Default To Here(1);
dt = Current Data Table();
deg = Degradation(
 Y(:result),
 Time(:Name("Timepoint (M)")),
 Label(:Batch),
 Application(Stability Test),
 Connect Data Markers(1),
 Show Fitted Lines(1),
 Show Spec Limits(1),
 Show Median Curves(0),
 Show Legend(1),
 No Tab List(0),
 Set Upper Spec Limit(5.5),
 Set Lower Spec Limit(4.5),
 Set Censoring Time(.),
 Show Residual Plot(0),
 Show Inverse Prediction Plot(0),
 Show Curve Interval(1),
 Inverse Prediction Interval(Confidence Interval),
 Inverse Prediction Alpha(0.025),
 Inverse Prediction Side(Lower One Sided),
 SendToReport(Dispatch({}, "Reports", OutlineBox, {Close(1)}))
);

//get upper spec limits from result column column properties
uslValue = (Column(dt, "result") << Get Property("Spec Limits"))["USL"];
//scaling to make limit visible
uslScaleFactor = 1.01;
//Degradation as report
rep = deg << Report;
//access y-axis
reportYAxis = rep[axisbox(1)];
//current max value
currentYMax = reportYAxis << Get Max;
//set as max of either old max or USL
reportYAxis << Max(Max(currentYMax, uslValue*uslScaleFactor));