344911_ja-JP

liliconcom

ループ？複数の列と、分析間で名前を変更する列名（日付）を使用して、作業から欠落しているデータをカウントします。

このコミュニティが私を助けてくれることを願っています。 最終日以降の連続した日数を示す列を追加したいと思います。

また、7列の結果が0.02を超える日数を数える列を追加したいと思います。

一連のifステートメントを使用して両方の解決策を見つけましたが、おそらくループを使用して、よりエレガントな方法で実行できるかどうかを知りたいと思います。

最後に、表の日付は週ごとに変わるので、この式が列名から独立していることを望みます。 これは可能ですか？

私のソリューションには、似たようなデータテーブルを添付しました。

前もって感謝します

/ Markku

スクリプティングRe：ループ？複数の列と、分析間で名前を変更する列名（日付）を使用して、作業から欠落しているデータをカウントします。

これが私が思いついた代替式です

If( Row() == 1,
 start = 2;
 end = 8;
);
count = end;
While( Is Missing( Column( count )[Row()] ) == 1 & count >= start, count-- );
end - count;

Re：ループ？複数の列と、分析間で名前を変更する列名（日付）を使用して、作業から欠落しているデータをカウントします。

私のソリューションは、おそらく必要以上に少し複雑です（example_newテーブルの作成に添付された完全なスクリプト）。 このソリューションでは、対象の列に「Max（something」という名前が付けられている必要があります（「Max（」列が7つ以上ある場合でも機能するはずです）。

 

これらの両方の数式列は、データの変更を再計算する機能を失い、データテーブルでデータが変更された場合は、テーブルの赤い三角形から「手動で」再実行する必要があります。

 

列の式：

//modified idea based on of @txnelson solution
tempCol = dt << New Column("# last days missing_community", Numeric, Nominal,
 Formula(
  Local({
   //get information on column names
   dt = Current Data Table(),
   colNames = dt << Get Column Names(String)
   },
   //get list of column names with only Max( in name
   For(i = N Items(colNames), i > 0, i--,
    If(!Contains(colNames[i], "Max("),
     Remove From(colNames, i);
    )
   );
   //get values on rows
   //this might make a mistake if columns before Max( have are missing values
   matLength = N Items(colNames) + 1;
   rowValues = dt[Row(), 0][1::matLength];
   count = 0;
   //calculate missing values from the end of matrix and stop on first found value
   While(Is Missing(rowValues[matLength]), count++; matLength--);
   count;
  )
 )
);

dt << New Column("#days higher than 0,02_community", Numeric, Nominal,
 Formula(
  Local({
   //get information on column names
   dt = Current Data Table(),
   colNames = dt << Get Column Names(String)
   },
   //get values on row and set values of colums without Max( in name to 0
   rowVals = dt[Row(), 0];
   For(i = N Items(colNames), i > 0, i--,
    If(!Contains(colNames[i], "Max("),
     rowVals[i] = 0;
    )
   );
   //create matrix with 0 and 1 based on if value is over 0.02
   rowVals_over = rowVals > 0.02;
   //get sum of previous matris to calculate Max( columns with values over 0.02
   Sum(rowVals_over);
  );
 )
);

 

 

 

Re：ループ？複数の列と、分析間で名前を変更する列名（日付）を使用して、作業から欠落しているデータをカウントします。

親愛な@Markku 、

 

また、動的スクリプトを作成し、それらを列式に解析するのにも苦労しています。 過去に私はあなたと同様の状況にあり、反復測定の数（あなたの場合はバッチが毎日繰り返される）が1つの観測（バッチ）から別の観測（バッチ）に変わる可能性がありました。

私の解決策はあなたのニーズに対して少しラフに見えるかもしれませんが、私はそれがうまくいくはずだと思います。

使用する前に、さまざまなシナリオに対して堅牢であるかどうかを確認してください。

データテーブルを開いた状態でこのスクリプトを実行し、結果を調べます。

Names Default To Here( 1 );
dt = Current Data Table();

// get list of columns 
Cols = dt << get column names ( Continuous );
maxlist = {};

For( i = 1, i <= N Items( cols ), i++,
 If( Contains( cols[i], "Max" ),
  Insert Into( maxlist, cols[i] )
 )
);


dt2 = dt << Stack(
 columns(maxlist ),
 Source Label Column( "Time" ),
 Stacked Data Column( "Data" )
);

dt2 << Sort(
 By( :Batch#, :Time ),
 Order( Ascending, Descending ),
 replace table
);


dt2 <<NEW column=""> :Index2  ) << delete rows ();

dt3 = dt2 << Summary(
 Group( :Batch# ),
 Freq( "None" ),
 Weight( "None" ),
 Link to original data table( 0 ),

);

close (dt2, no save);

dt3:N Rows << set name ("No of last days missing");

dt << new column ("No of last days missing", set each value (0));

dt << Update(
 With( dt3 ),
 Match Columns( :Batch# = :Batch# )
);

close (dt3, no save);

//
dt5 =  dt << Stack(
 columns(maxlist ),
 Source Label Column( "Time" ),
 Stacked Data Column( "Data" )
);

dt5 << select where (ismissing (:Data)) << delete rows;
dt5 << select where (:Data<=0.02) << delete rows;

dt6 = dt5 << Summary(
 Group( :Batch# ),
 Freq( "None" ),
 Weight( "None" ),
 Link to original data table( 0 )
);

close (dt5, no save);

dt6:N Rows << set name ("Days over 0.02");

dt << new column("Days over 0.02", set each value(0));
dt<< Update(
 With( dt6 ),
 Match Columns( :Batch# = :Batch# )
);

close (dt6, no save);
 

<BR /></NEW>

それが機能するかどうかをお知らせください、

ロン