Wie speichere ich Variablenwerte in einem neuen Skript?Hallo,
Ich versuche, Metadaten in einer Tabelle zu speichern, damit ich beim nächsten Öffnen der Datei einige Variablen verwenden kann, die ich beim Erstellen der Tabelle verwendet habe.
Ich verstehe, dass derzeit nur Zeichenfolgen als Metadaten in der Tabelle gespeichert werden können.
Die andere Option, die ich ausprobiert habe, besteht darin, ein neues Skript in der Tabelle zu speichern, das die von mir benötigten Variablen enthält.
Das Problem ist, dass ich nicht verstehe, wie man das „Speicherskript“ so verwendet, dass der Wert der Variablen anstelle des Variablennamens hinzugefügt wird.
Ich habe zum Beispiel Folgendes versucht:
x = expr (a = [1,2,3]);
dt << New script ("test",char (x));was zu einem Skript mit - char(x) führt.
Ich habe jede mir einfallende expr/eval/parse-Kombination ausprobiert, aber keine davon hat geholfen.
Ich möchte nur, dass das neue Skript „test“ Folgendes enthält:
a = [1,2,3]
aber wenn ich das Skript schreibe, kenne ich natürlich nicht den tatsächlichen Wert von a.
Dank im Voraus
Ergebnisse teilen und kommunizierenBetreff: Wie speichere ich Variablenwerte in einem neuen Skript?Ich verwende gerne evalinsert und eval(parse()).
dt = New Table( "Untitled 8",
Add Rows( 2 ),
New Column( "Column 1", Character, "Nominal", Set Values( {"a", "b"} ) )
);
a1 = "a = [1, 2, 3]";
b1 = evalinsert("\[dt << new script("test", ^a1^)]\");
eval(parse(b1));Betreff: Wie speichere ich Variablenwerte in einem neuen Skript?Etwas anders, nicht unbedingt besser:
NamesDefaultToHere(1);
dt = NewTable("Test");
myScript =
Expr(
a = {1, 2, 3, 4};
Speak(a);
);
addScript =
Expr(
dt << NewScript(nTBD, sTBD)
);
SubstituteInto(
addScript,
Expr(nTBD), "My Script",
Expr(sTBD), EvalExpr(myScript)
);
addScript;
Betreff: Wie speichere ich Variablenwerte in einem neuen Skript?Vielen Dank für Ihre Hilfe.
Ich habe die Option „eval (eval expr(..“))“ verpasst.
Die Art und Weise, wie ich es letztendlich benutzte, war so:
a = {1,2,3};
Eval(Eval Expr(dt << New script ("test",
a = expr (a);
)));Auf diese Weise enthält das neue Testskript jetzt „a = {1,2,3};“, was ich wollte.
Danke noch einmal.
Betreff: Wie speichere ich Variablenwerte in einem neuen Skript?Hallo,
Funktioniert das, was Sie suchen?:
x = expr ("a = [1,2,3]");
eval(eval expr(dt << New script ("test",char (expr(parse(x))))));
