341703_de-DE

liliconcom

Wiederverwendung von Schriftarten, Schriftstilen und -größen

Gibt es eine Möglichkeit, Schriftstile wiederzuverwenden?

Angenommen, ich habe viele Diagramme und wende für jede Achsenbox Folgendes an:

Dispatch( {}, "X", ScaleBox, {Format( "Best", 12 ), Min( 0.5 ), Max( 0.6 ), Inc( 0.0005 ), Minor Ticks( 1 ), Label Row(
    {Set Font( "Agency FB" ), Set Font Size( 8 )}
   )} )

Dann entscheide ich, dass Größe 8 zu klein ist und jetzt muss ich zu jedem Ort, an dem ich es ablege, gehen und es ändern.

 

Irgendeine Art, etwas zu sagen wie:

myFontStyle = {Set Font( "Agency FB" ), Set Font Size( 8 )};

und dann einfach benutzen:

Label Row(myFontStyle)

Ich vermute, dass Sie das mit der Ausdrucksbewertung irgendwie tun könnten - aber ich verstehe diesen ganzen Deal mit Ausdrücken und Bewertungen einfach nicht. Irgendwelche Vorschläge?

SkriptingBetreff: Wiederverwendung von Schriftarten, Schriftstilen und -größen

Anstatt Dispatch zu verwenden, wird häufig empfohlen, Nachrichten direkt an die Waagenboxen zu senden.Sie können nach ihnen suchen und dann eine Liste mit Anweisungen an eine Liste mit Objekten senden, um alle Änderungen gleichzeitig vorzunehmen.Siehe dieses Beispiel:

 

names default to here(1);

dt = Open("$Sample_Data/Big Class.jmp");

gb = dt << Graph Builder(
 Size( 321, 1012 ),
 Show Control Panel( 0 ),
 Variables( X( :height ), Y( :weight ), Page( :age ) ),
 Elements( Points( X, Y, Legend( 22 ) ), Smoother( X, Y, Legend( 23 ) ) )
);

//use this to find charID:
gb << Get XML;

//Modify X Axes by first getting a list of scale boxes and then sending
//a list of messages to each.
(gb << XPath( "//ScaleBox[@charID='height']" )) << {
 Format( "Best", 12 ), 
 Min( 50 ),
 Max( 75 ), 
 Inc( 5 ), 
 Minor Ticks( 1 ),
 Label Row( {
  Set Font( "Agency FB" ), 
  Set Font Size( 8 )
 } )
};

//Modify Y Axes:
(gb << XPath( "//ScaleBox[@charID='weight']" )) << {
 Format( "Best", 12 ), 
 Min( 50 ),
 Max( 150 ), 
 Inc( 25 ), 
 Minor Ticks( 1 ),
 Label Row( {
  Set Font( "Agency FB" ), 
  Set Font Size( 8 )
 } )
};